Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
Kill unused function.
[simgrid.git] / teshsuite / s4u / CMakeLists.txt
1 # Specify the source files of multi-files tests
2 set(activity-lifecycle_sources ../catch_simgrid.cpp)
3 foreach(x sleep exec comm comm_direct test-wait)
4   set(activity-lifecycle_sources ${activity-lifecycle_sources} activity-lifecycle/testing_${x}.cpp)
5 endforeach()
6
7 foreach(x actor actor-autorestart actor-suspend
8         activity-lifecycle
9         comm-get-sender comm-pt2pt comm-fault-scenarios wait-all-for wait-any-for
10         cloud-interrupt-migration cloud-two-execs
11         monkey-masterworkers monkey-semaphore
12         concurrent_rw
13         dag-incomplete-simulation dependencies
14         host-on-off host-on-off-actors host-on-off-recv host-multicore-speed-file
15         io-set-bw io-stream
16         basic-link-test basic-parsing-test evaluate-get-route-time evaluate-parse-time is-router
17         storage_client_server listen_async pid
18         trace-integration
19         seal-platform
20               vm-live-migration vm-suicide issue71)
21
22   if(NOT DEFINED ${x}_sources)
23       set(${x}_sources ${x}/${x}.cpp)
24   endif()
25
26   add_executable       (${x}  EXCLUDE_FROM_ALL ${${x}_sources})
27   target_link_libraries(${x}  simgrid)
28   set_target_properties(${x}  PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${x})
29   add_dependencies(tests ${x})
30
31   foreach(file ${${x}_sources})
32     set(teshsuite_src  ${teshsuite_src} ${CMAKE_CURRENT_SOURCE_DIR}/${file})
33   endforeach()
34
35   unset(${x}_sources)
36 endforeach()
37 set_property(TARGET activity-lifecycle APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}") # for <catch.hpp> and catch_simgrid
38
39
40 ## Add the tests.
41 ## Some need to be run with all factories, some don't need tesh to run
42 foreach(x actor actor-autorestart actor-suspend activity-lifecycle comm-get-sender wait-all-for wait-any-for
43         cloud-interrupt-migration cloud-two-execs concurrent_rw dag-incomplete-simulation dependencies io-set-bw io-stream
44               vm-live-migration vm-suicide)
45   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.tesh)
46   ADD_TESH_FACTORIES(tesh-s4u-${x} "*" --setenv bindir=${CMAKE_BINARY_DIR}/teshsuite/s4u/${x} --setenv srcdir=${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x} --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms --cd ${CMAKE_BINARY_DIR}/teshsuite/s4u/${x} ${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x}/${x}.tesh)
47 endforeach()
48
49 foreach(x basic-link-test basic-parsing-test host-on-off host-on-off-actors host-on-off-recv comm-fault-scenarios host-multicore-speed-file is-router listen_async
50         monkey-masterworkers monkey-semaphore
51         pid storage_client_server trace-integration seal-platform issue71)
52   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.tesh)
53   ADD_TESH(tesh-s4u-${x}
54            --setenv bindir=${CMAKE_BINARY_DIR}/teshsuite/s4u/${x}
55            --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${x}
56            --setenv rootdir=${CMAKE_HOME_DIRECTORY}
57            --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
58            --cd ${CMAKE_BINARY_DIR}/teshsuite/s4u/${x}
59            ${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x}/${x}.tesh)
60 endforeach()
61
62 # Python tesh tests
63 foreach(x monkey-masterworkers)
64   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.py.tesh)
65   set(teshsuite_src ${teshsuite_src} ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.py)
66
67   if(enable_python)
68     ADD_TESH(tesh-python-${x}
69              --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${x}
70              --setenv pythoncmd=${PYTHON_EXECUTABLE}
71              --setenv LD_LIBRARY_PATH=${TESH_LIBRARY_PATH}
72              --setenv PYTHONPATH=${CMAKE_BINARY_DIR}/lib
73              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
74              --cd ${CMAKE_BINARY_DIR}/teshsuite/s4u/${x}
75              ${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x}/${x}.py.tesh)
76
77   endif()
78 endforeach()
79
80
81 # Monkey tests are launched directly, not with tesh
82 set(_monkey-semaphore_disable_python 1) # Semaphore not exposed to python
83 foreach(x  monkey-masterworkers monkey-semaphore)
84   ADD_TEST(monkey-s4u-${x} "${PYTHON_EXECUTABLE}" ${CMAKE_HOME_DIRECTORY}/tools/simgrid-monkey -- ${VALGRIND_WRAPPER_UNBOXED} ${CMAKE_BINARY_DIR}/teshsuite/s4u/${x}/${x})
85   if(enable_python)
86     if(NOT DEFINED _${x}_disable_python)
87       ADD_TEST(monkey-python-${x} "${PYTHON_EXECUTABLE}" ${CMAKE_HOME_DIRECTORY}/tools/simgrid-monkey "${PYTHON_EXECUTABLE}" ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.py)
88       set_tests_properties(monkey-python-${x} PROPERTIES ENVIRONMENT "PYTHONPATH=${CMAKE_BINARY_DIR}/lib")
89     endif()
90   endif()
91 endforeach()
92
93 # The output is not relevant
94 ADD_TEST(tesh-s4u-comm-pt2pt    ${CMAKE_BINARY_DIR}/teshsuite/s4u/comm-pt2pt/comm-pt2pt    ${CMAKE_HOME_DIRECTORY}/examples/platforms/cluster_backbone.xml)
95
96 if(enable_coverage)
97   foreach (example evaluate-get-route-time evaluate-parse-time)
98     ADD_TEST(cover-${example} ${CMAKE_CURRENT_BINARY_DIR}/${example}/${example} ${CMAKE_HOME_DIRECTORY}/examples/platforms/g5k.xml)
99   endforeach()
100 endif()
101
102 # NS-3 specific tests
103 if(SIMGRID_HAVE_NS3)
104   foreach(x ns3-simultaneous-send-rcv ns3-from-src-to-itself)
105     add_executable       (${x}  EXCLUDE_FROM_ALL ${x}/${x}.cpp)
106     target_link_libraries(${x}  simgrid)
107     set_target_properties(${x}  PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${x})
108     add_dependencies(tests ${x})
109     ADD_TESH(tesh-s4u-${x} --setenv srcdir=${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x} --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms --cd ${CMAKE_BINARY_DIR}/teshsuite/s4u/${x} ${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x}/${x}.tesh)
110   endforeach()
111 endif()
112
113 # BMF specific tesh tests
114 foreach(x cloud-two-execs concurrent_rw)
115   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}-bmf.tesh)
116
117   if(Eigen3_FOUND)
118     ADD_TESH(tesh-s4u-${x}-bmf
119              --setenv bindir=${CMAKE_BINARY_DIR}/teshsuite/s4u/${x}
120              --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${x}
121              --setenv rootdir=${CMAKE_HOME_DIRECTORY}
122              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
123              --cd ${CMAKE_BINARY_DIR}/teshsuite/s4u/${x}
124              ${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x}/${x}-bmf.tesh)
125
126   endif()
127 endforeach()
128
129 foreach(x ns3-simultaneous-send-rcv ns3-from-src-to-itself)
130   set(teshsuite_src ${teshsuite_src} ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.cpp)
131   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.tesh)
132 endforeach()
133
134 # test for code coverage
135 ADD_TEST(test-help-version ${VALGRIND_WRAPPER_UNBOXED} ${CMAKE_BINARY_DIR}/teshsuite/s4u/basic-parsing-test/basic-parsing-test
136   --version --help --help-aliases --help-models --help-tracing)
137 ADD_TEST(test-help-logs    ${VALGRIND_WRAPPER_UNBOXED} ${CMAKE_BINARY_DIR}/teshsuite/s4u/basic-parsing-test/basic-parsing-test
138   --help-logs --help-log-categories)
139
140 ADD_TESH(tesh-parser-bypass   --setenv bindir=${CMAKE_BINARY_DIR}/teshsuite/s4u/basic-parsing-test --cd ${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/basic-parsing-test --setenv srcdir=${CMAKE_HOME_DIRECTORY} basic-parsing-test-bypass.tesh)
141 ADD_TESH(tesh-parser-sym-full --setenv bindir=${CMAKE_BINARY_DIR}/teshsuite/s4u/basic-parsing-test --cd ${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/basic-parsing-test basic-parsing-test-sym-full.tesh)
142
143 ADD_TEST(tesh-parser-full-links01    ${CMAKE_BINARY_DIR}/teshsuite/s4u/basic-parsing-test/basic-parsing-test ${CMAKE_HOME_DIRECTORY}/teshsuite/platforms/two_clusters.xml FULL_LINK)
144 ADD_TEST(tesh-parser-full-links02    ${CMAKE_BINARY_DIR}/teshsuite/s4u/basic-parsing-test/basic-parsing-test ${CMAKE_HOME_DIRECTORY}/teshsuite/platforms/two_clusters_one_name.xml FULL_LINK)
145 ADD_TEST(tesh-parser-one-link-g5k    ${CMAKE_BINARY_DIR}/teshsuite/s4u/basic-parsing-test/basic-parsing-test ${CMAKE_HOME_DIRECTORY}/examples/platforms/g5k.xml ONE_LINK)
146
147 set(teshsuite_src ${teshsuite_src}  ${CMAKE_SOURCE_DIR}/src/include/catch_simgrid.hpp PARENT_SCOPE)
148 set(tesh_files    ${tesh_files}     ${CMAKE_CURRENT_SOURCE_DIR}/basic-parsing-test/basic-parsing-test-sym-full.tesh
149                                     ${CMAKE_CURRENT_SOURCE_DIR}/basic-parsing-test/basic-parsing-test-bypass.tesh PARENT_SCOPE)
150 set(xml_files     ${xml_files}      ${CMAKE_CURRENT_SOURCE_DIR}/activity-lifecycle/testing_platform.xml
151                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1.0-hbp1.0-hbp1.0.xml
152                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1.0-hbp3.0-hbp4.0.xml
153                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1.5-hbp1.5.xml
154                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1-c0s0-c0s1.xml
155                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1-c0s0-c1s0.xml
156                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1-c0s1-c0s2.xml
157                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1-c0s1-c2s2.xml
158                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1-c0s2-c1s0.xml
159                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1-c0s2-c1s1.xml
160                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1-c1s1-c1s2.xml
161                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp1-c1s1-c3s2.xml
162                                     ${CMAKE_CURRENT_SOURCE_DIR}/trace-integration/test-hbp2.5-hbp1.5.xml
163                                     ${CMAKE_CURRENT_SOURCE_DIR}/vm-live-migration/platform.xml
164                                     ${CMAKE_CURRENT_SOURCE_DIR}/issue71/platform_bad.xml
165                                     PARENT_SCOPE)