teshsuite/s4u/CMakeLists.txt

   1 foreach(x actor actor-autorestart
   2         activity-lifecycle
   3         comm-pt2pt wait-any-for
   4         cloud-interrupt-migration cloud-sharing
   5         concurrent_rw storage_client_server listen_async pid )
   6   add_executable       (${x}  EXCLUDE_FROM_ALL ${x}/${x}.cpp)
   7   target_link_libraries(${x}  simgrid)
   8   set_target_properties(${x}  PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${x})
   9   add_dependencies(tests ${x})
  10
  11   set(teshsuite_src ${teshsuite_src} ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.cpp)
  12 endforeach()
  13
  14 # Fix build rules for activity-lifecycle (multi-file)
  15 foreach(x sleep exec comm test-wait)
  16   target_sources(activity-lifecycle PRIVATE activity-lifecycle/testing_${x}.cpp)
  17   set(teshsuite_src ${teshsuite_src} ${CMAKE_CURRENT_SOURCE_DIR}/activity-lifecycle/testing_${x}.cpp)
  18 endforeach()
  19 set_property(TARGET activity-lifecycle APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}") # for <catch.hpp>
  20
  21 ## Add the tests.
  22 ## Some need to be run with all factories, some don't need tesh to run
  23 foreach(x actor actor-autorestart
  24         activity-lifecycle wait-any-for
  25         cloud-interrupt-migration concurrent_rw)
  26   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.tesh)
  27   ADD_TESH_FACTORIES(tesh-s4u-${x} "thread;ucontext;raw;boost" --setenv bindir=${CMAKE_BINARY_DIR}/teshsuite/s4u/${x} --setenv srcdir=${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x} --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms --cd ${CMAKE_BINARY_DIR}/teshsuite/s4u/${x} ${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x}/${x}.tesh)
  28 endforeach()
  29
  30 foreach(x listen_async pid storage_client_server cloud-sharing)
  31   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.tesh)
  32   ADD_TESH(tesh-s4u-${x} --setenv srcdir=${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x} --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms --cd ${CMAKE_BINARY_DIR}/teshsuite/s4u/${x} ${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x}/${x}.tesh)
  33 endforeach()
  34
  35 # The output is not relevant
  36 ADD_TEST(tesh-s4u-comm-pt2pt    ${CMAKE_BINARY_DIR}/teshsuite/s4u/comm-pt2pt/comm-pt2pt    ${CMAKE_HOME_DIRECTORY}/examples/platforms/cluster_backbone.xml)
  37
  38 # NS-3 specific tests
  39 if(SIMGRID_HAVE_NS3)
  40   foreach(x ns3-simultaneous-send-rcv)
  41     add_executable       (${x}  EXCLUDE_FROM_ALL ${x}/${x}.cpp)
  42     target_link_libraries(${x}  simgrid)
  43     set_target_properties(${x}  PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${x})
  44     add_dependencies(tests ${x})
  45     ADD_TESH(tesh-s4u-${x} --setenv srcdir=${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x} --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms --cd ${CMAKE_BINARY_DIR}/teshsuite/s4u/${x} ${CMAKE_HOME_DIRECTORY}/teshsuite/s4u/${x}/${x}.tesh)
  46   endforeach()
  47 endif()
  48
  49 foreach(x ns3-simultaneous-send-rcv)
  50   set(teshsuite_src ${teshsuite_src} ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.cpp)
  51   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${x}/${x}.tesh)
  52 endforeach()
  53
  54 set(teshsuite_src ${teshsuite_src}  ${CMAKE_CURRENT_SOURCE_DIR}/activity-lifecycle/activity-lifecycle.hpp PARENT_SCOPE)
  55 set(tesh_files    ${tesh_files}     PARENT_SCOPE)
  56 set(xml_files     ${xml_files}      ${CMAKE_CURRENT_SOURCE_DIR}/activity-lifecycle/testing_platform.xml PARENT_SCOPE)