buildtools/Cmake/MakeLib.cmake

   1 ### Make Libs
   2
   3 ###############################
   4 # Declare the library content #
   5 ###############################
   6 # If we want supernovae, rewrite the libs' content to use it
   7 include(${CMAKE_HOME_DIRECTORY}/buildtools/Cmake/Supernovae.cmake)
   8
   9 # Actually declare our libraries
  10
  11 add_library(simgrid SHARED ${simgrid_sources})
  12 set_target_properties(simgrid PROPERTIES VERSION ${libsimgrid_version})
  13
  14 if(enable_lib_static)
  15   add_library(simgrid_static STATIC ${simgrid_sources})
  16 endif()
  17
  18 if(enable_smpi)
  19   add_library(smpi SHARED ${SMPI_SRC})
  20   set_target_properties(smpi PROPERTIES VERSION ${libsmpi_version})
  21   if(enable_lib_static)
  22     add_library(smpi_static STATIC ${SMPI_SRC})
  23   endif()
  24 endif()
  25
  26 if(enable_java)
  27   add_library(SG_java SHARED ${JMSG_C_SRC})
  28   set_target_properties(SG_java PROPERTIES VERSION ${libSG_java_version})
  29   get_target_property(COMMON_INCLUDES SG_java INCLUDE_DIRECTORIES)
  30   set_target_properties(SG_java PROPERTIES
  31     INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  32   add_dependencies(SG_java simgrid)
  33
  34   if(WIN32)
  35     get_target_property(SIMGRID_LIB_NAME_NAME SG_java LIBRARY_OUTPUT_NAME)
  36     set_target_properties(SG_java PROPERTIES
  37       LINK_FLAGS "-Wl,--subsystem,windows,--kill-at ${SIMGRID_LIB_NAME}"
  38       PREFIX "")
  39     find_path(PEXPORTS_PATH NAMES pexports.exe PATHS NO_DEFAULT_PATHS)
  40     message(STATUS "pexports: ${PEXPORTS_PATH}")
  41     if(PEXPORTS_PATH)
  42       add_custom_command(TARGET SG_java POST_BUILD
  43         COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/SG_java.dll > ${CMAKE_BINARY_DIR}/SG_java.def)
  44     endif(PEXPORTS_PATH)
  45   else()
  46     target_link_libraries(SG_java simgrid)
  47   endif()
  48
  49   set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  50   add_jar(SG_java_jar ${JMSG_JAVA_SRC})
  51
  52   set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  53   set(MANIFEST_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF")
  54
  55   if(CMAKE_SYSTEM_PROCESSOR MATCHES ".86")
  56     if(${ARCH_32_BITS})
  57       set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/x86/")
  58     else()
  59       set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/amd64/")
  60     endif()
  61   else()
  62     error("Unknown system type. Processor: ${CMAKE_SYSTEM_PROCESSOR}; System: ${CMAKE_SYSTEM_NAME}")
  63   endif()
  64   message("Native libraries bundled into: ${JSG_BUNDLE}")
  65
  66   add_custom_command(
  67     COMMENT "Finalize simgrid.jar..."
  68     OUTPUT ${SIMGRID_JAR}_finalized
  69     DEPENDS simgrid SG_java ${SIMGRID_JAR} ${MANIFEST_FILE}
  70             ${CMAKE_HOME_DIRECTORY}/COPYING
  71             ${CMAKE_HOME_DIRECTORY}/ChangeLog
  72             ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  73     WORKING_DIRECTORY "${CMAKE_BINARY_DIR}"
  74     COMMAND ${CMAKE_COMMAND} -E remove_directory "NATIVE"
  75     COMMAND ${CMAKE_COMMAND} -E make_directory "${JSG_BUNDLE}"
  76     COMMAND ${CMAKE_COMMAND} -E copy ./lib/libsimgrid.so "${JSG_BUNDLE}"
  77     COMMAND strip --strip-debug "${JSG_BUNDLE}/libsimgrid.so"
  78     COMMAND ${CMAKE_COMMAND} -E copy ./lib/libSG_java.so "${JSG_BUNDLE}"
  79     COMMAND strip --strip-debug "${JSG_BUNDLE}/libSG_java.so"
  80     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/COPYING" "${JSG_BUNDLE}"
  81     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/ChangeLog" "${JSG_BUNDLE}"
  82     COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java" "${JSG_BUNDLE}"
  83     COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} "NATIVE"
  84     COMMAND ${CMAKE_COMMAND} -E touch ${SIMGRID_JAR}_finalized
  85     )
  86   add_custom_target(SG_java_jar_finalize DEPENDS ${SIMGRID_JAR}_finalized)
  87   add_dependencies(SG_java_jar SG_java_jar_finalize)
  88 endif()
  89
  90 add_dependencies(simgrid maintainer_files)
  91
  92 # if supernovaeing, we need some depends to make sure that the source gets generated
  93 if (enable_supernovae)
  94   add_dependencies(simgrid ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_sg.c)
  95   if(enable_lib_static)
  96     add_dependencies(simgrid_static ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_sg.c)
  97   endif()
  98
  99   if(enable_smpi)
 100     add_dependencies(smpi ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_smpi.c)
 101     if(enable_lib_static)
 102       add_dependencies(smpi_static ${CMAKE_CURRENT_BINARY_DIR}/src/supernovae_smpi.c)
 103     endif()
 104   endif()
 105 endif()
 106
 107 # Compute the dependencies of SimGrid
 108 #####################################
 109 set(SIMGRID_DEP "-lm -lpcre")
 110
 111 if(pthread)
 112   if(${CONTEXT_THREADS})
 113     SET(SIMGRID_DEP "${SIMGRID_DEP} -pthread")
 114   endif()
 115 endif()
 116
 117 if(HAVE_LUA)
 118   ADD_CUSTOM_TARGET(link_simgrid_lua ALL
 119     DEPENDS     simgrid
 120     ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE}
 121     ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE}
 122     ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE}
 123     )
 124   add_custom_command(
 125     OUTPUT      ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE}
 126     ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE}
 127     ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE}
 128     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE} # if it exists, creating the link fails. So cleanup before hand
 129     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/examples/lua/
 130     COMMAND ${CMAKE_COMMAND} -E create_symlink ${CMAKE_BINARY_DIR}/lib/libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/examples/lua/simgrid.${LIB_EXE} #for test
 131
 132     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE} # if it exists, creating the link fails. So cleanup before hand
 133     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/examples/msg/masterslave/
 134     COMMAND ${CMAKE_COMMAND} -E create_symlink ${CMAKE_BINARY_DIR}/lib/libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/examples/msg/masterslave/simgrid.${LIB_EXE} #for test
 135
 136     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE} # if it exists, creating the link fails. So cleanup before hand
 137     COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/examples/simdag/
 138     COMMAND ${CMAKE_COMMAND} -E create_symlink ${CMAKE_BINARY_DIR}/lib/libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/examples/simdag/simgrid.${LIB_EXE} #for test
 139     )
 140   SET(SIMGRID_DEP "${SIMGRID_DEP} -l${LIB_LUA_NAME}")
 141 endif()
 142
 143 if(HAVE_GRAPHVIZ)
 144   if(HAVE_CGRAPH_LIB)
 145     SET(SIMGRID_DEP "${SIMGRID_DEP} -lcgraph")
 146   else()
 147     if(HAVE_AGRAPH_LIB)
 148       SET(SIMGRID_DEP "${SIMGRID_DEP} -lagraph -lcdt")
 149     endif()
 150   endif()
 151 endif()
 152
 153 if(HAVE_GTNETS)
 154   SET(SIMGRID_DEP "${SIMGRID_DEP} -lgtnets")
 155 endif()
 156
 157 if(HAVE_MC)
 158   # The availability of libunwind was checked in CompleteInFiles.cmake
 159   #   (that includes FindLibunwind.cmake), so simply load it now.
 160
 161   # This supposes that the host machine is either an AMD or a X86.
 162   # This is deeply wrong, and should be fixed by manually loading -lunwind-PLAT (FIXME)
 163   if(PROCESSOR_x86_64)
 164     SET(SIMGRID_DEP "${SIMGRID_DEP} -lunwind-x86_64")
 165   else()
 166     SET(SIMGRID_DEP "${SIMGRID_DEP} -lunwind-x86")
 167   endif()
 168 endif()
 169
 170 if(MMALLOC_WANT_OVERRIDE_LEGACY AND HAVE_GNU_LD)
 171   SET(SIMGRID_DEP "${SIMGRID_DEP} -ldl")
 172 endif()
 173
 174 if(HAVE_NS3)
 175   if(${NS3_VERSION} EQUAL 310)
 176     SET(SIMGRID_DEP "${SIMGRID_DEP} -lns3")
 177     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_NS3_3_10")
 178     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_NS3_3_10")
 179   else()
 180     SET(SIMGRID_DEP "${SIMGRID_DEP} -lns3-core -lns3-csma -lns3-point-to-point -lns3-internet -lns3-applications")
 181   endif()
 182 endif()
 183
 184 if(HAVE_POSIX_GETTIME)
 185   SET(SIMGRID_DEP "${SIMGRID_DEP} -lrt")
 186 endif()
 187
 188 target_link_libraries(simgrid   ${SIMGRID_DEP})
 189
 190 # Compute the dependencies of SMPI
 191 ##################################
 192 set(SMPI_DEP "")
 193 if(APPLE)
 194   set(SMPI_DEP "-Wl,-U -Wl,_smpi_simulated_main")
 195 endif()
 196 if(enable_smpi)
 197   target_link_libraries(smpi    simgrid ${SMPI_DEP})
 198 endif()
 199
 200 # Pass dependencies to static libs
 201 ##################################
 202 if(enable_lib_static)
 203   target_link_libraries(simgrid_static  ${SIMGRID_DEP})
 204   add_dependencies(simgrid_static maintainer_files)
 205   set_target_properties(simgrid_static PROPERTIES OUTPUT_NAME simgrid)
 206   if(enable_smpi)
 207     target_link_libraries(smpi_static   simgrid ${SMPI_DEP})
 208     set_target_properties(smpi_static PROPERTIES OUTPUT_NAME smpi)
 209   endif()
 210 endif()
 211
 212 # Dependencies from maintainer mode
 213 ###################################
 214 if(enable_maintainer_mode AND BISON_EXE AND LEX_EXE)
 215   add_dependencies(simgrid automaton_generated_src)
 216 endif()