examples/s4u/CMakeLists.txt

   1
   2 # Regular examples: with only one source and tested with all factories by default
   3 #################################################################################
   4 ### Define the examples' specificities
   5
   6 set(_app-bittorrent_sources app-bittorrent/s4u-bittorrent.cpp app-bittorrent/s4u-bittorrent.hpp
   7                             app-bittorrent/s4u-peer.cpp app-bittorrent/s4u-peer.hpp
   8                             app-bittorrent/s4u-tracker.cpp app-bittorrent/s4u-tracker.hpp)
   9 set(_dht-chord_sources    dht-chord/s4u-dht-chord.cpp dht-chord/s4u-dht-chord.hpp dht-chord/s4u-dht-chord-node.cpp)
  10 set(_dht-kademlia_sources dht-kademlia/s4u-dht-kademlia.cpp dht-kademlia/s4u-dht-kademlia.hpp
  11                           dht-kademlia/node.cpp dht-kademlia/node.hpp
  12                           dht-kademlia/routing_table.cpp dht-kademlia/routing_table.hpp
  13                           dht-kademlia/answer.cpp dht-kademlia/answer.hpp dht-kademlia/message.hpp)
  14
  15 set(_actor-stacksize_factories "raw;boost;ucontext") # Threads ignore modifications of the stack size
  16
  17 # The maestro-set example only works for threads and when not using windows.
  18 set(_maestro-set_factories "thread")
  19 if(WIN32)
  20   set(_maestro-set_disable 1)
  21 endif()
  22
  23 foreach (example mc-bugged1 mc-bugged2 mc-failing-assert mc-electric-fence)
  24   if(NOT SIMGRID_HAVE_MC)
  25     set(_${example}_disable 1)
  26   endif()
  27   set(_${example}_factories "ucontext;raw;boost")
  28 endforeach()
  29
  30 set(_mc-bugged1-liveness_disable 1)
  31 if(SIMGRID_HAVE_MC)
  32    add_executable       (s4u-mc-bugged1-liveness  EXCLUDE_FROM_ALL mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  33    target_link_libraries(s4u-mc-bugged1-liveness  simgrid)
  34    set_target_properties(s4u-mc-bugged1-liveness PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness)
  35    add_dependencies(tests s4u-mc-bugged1-liveness)
  36    set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  37    set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.tesh)
  38
  39   if(HAVE_C_STACK_CLEANER)
  40     add_executable       (s4u-mc-bugged1-liveness-cleaner-on  EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  41     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-on  simgrid)
  42     set_target_properties(s4u-mc-bugged1-liveness-cleaner-on  PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fstack-cleaner")
  43     add_dependencies(tests s4u-mc-bugged1-liveness-cleaner-on)
  44
  45     add_executable       (s4u-mc-bugged1-liveness-cleaner-off EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  46     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-off simgrid)
  47     set_target_properties(s4u-mc-bugged1-liveness-cleaner-off PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fno-stack-cleaner")
  48     add_dependencies(tests s4u-mc-bugged1-liveness-cleaner-off)
  49   endif()
  50
  51 endif()
  52
  53 if(SIMGRID_HAVE_NS3)
  54   add_executable       (s4u-network-ns3 EXCLUDE_FROM_ALL network-ns3/s4u-network-ns3.cpp)
  55   target_link_libraries(s4u-network-ns3 simgrid)
  56   set_target_properties(s4u-network-ns3  PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/network-ns3)
  57   add_dependencies(tests s4u-network-ns3)
  58 endif()
  59
  60 # Deal with each example
  61
  62 foreach (example actor-create actor-daemon actor-exiting actor-join actor-kill
  63                  actor-lifetime actor-migrate actor-suspend actor-yield actor-stacksize
  64                  app-bittorrent app-chainsend app-pingpong app-token-ring
  65                  comm-ready comm-suspend comm-wait comm-waitany comm-waitall comm-waituntil
  66                  comm-dependent
  67                  cloud-capping cloud-migration cloud-simple
  68                  dht-chord dht-kademlia
  69                  energy-exec energy-boot energy-link energy-vm energy-exec-ptask energy-wifi
  70                  engine-filtering
  71                  exec-async exec-basic exec-dvfs exec-ptask exec-remote exec-waitany exec-waitfor exec-dependent
  72                  maestro-set
  73                  mc-bugged1 mc-bugged1-liveness mc-bugged2 mc-electric-fence mc-failing-assert
  74                  network-wifi
  75                  io-async io-file-system io-file-remote io-disk-raw io-dependent
  76                  platform-failures platform-profile platform-properties
  77                  plugin-host-load plugin-link-load
  78                  replay-comm replay-io
  79                  routing-get-clusters
  80                  synchro-barrier synchro-condition-variable synchro-condition-variable-waituntil synchro-mutex synchro-semaphore)
  81
  82   # Use default source file unless specified otherwise
  83   if(NOT DEFINED _${example}_sources)
  84     set(_${example}_sources ${example}/s4u-${example}.cpp)
  85   endif()
  86
  87   if(NOT DEFINED _${example}_disable)
  88     add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${_${example}_sources})
  89     add_dependencies     (tests s4u-${example})
  90     target_link_libraries(s4u-${example} simgrid)
  91     set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
  92
  93     # Use default factories unless specified otherwise
  94     if(NOT DEFINED _${example}_factories)
  95       set(_${example}_factories "thread;ucontext;raw;boost")
  96     endif()
  97 #    message("Factories of ${example}: ${_${example}_factories}")
  98
  99     ADD_TESH_FACTORIES(s4u-${example} "${_${example}_factories}"
 100                                       --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 101                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 102                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 103                                       ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 104   else()
 105     message(STATUS "Example ${example} disabled, thus not compiled.")
 106     unset(_${example}_disabled)
 107   endif()
 108
 109   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 110   foreach(file ${_${example}_sources})
 111     set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/${file})
 112   endforeach()
 113
 114   unset(_${example}_factories)
 115   unset(_${example}_sources)
 116 endforeach()
 117
 118
 119 # Specific examples
 120 ###################
 121
 122 # MASTERWORKERS EXAMPLE
 123 foreach(variant fun class)
 124   add_executable       (s4u-app-masterworkers-${variant} EXCLUDE_FROM_ALL app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 125   target_link_libraries(s4u-app-masterworkers-${variant} simgrid)
 126   set_target_properties(s4u-app-masterworkers-${variant} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-masterworkers)
 127   add_dependencies(tests s4u-app-masterworkers-${variant})
 128
 129   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 130 endforeach()
 131 set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers.tesh)
 132
 133 # Model-checking liveness
 134 if(SIMGRID_HAVE_MC)
 135   IF(HAVE_UCONTEXT_CONTEXTS AND SIMGRID_PROCESSOR_x86_64) # liveness model-checking works only on 64bits (for now ...)
 136     ADD_TESH(s4u-mc-bugged1-liveness-ucontext     --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness
 137                                                   --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 138                                                   --cd ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness
 139                                                   ${CMAKE_HOME_DIRECTORY}/examples/s4u/mc-bugged1-liveness/s4u-mc-bugged1-liveness.tesh)
 140
 141 # This example hit the 5' timeout on CI, disable it for now
 142 #    ADD_TESH(s4u-mc-bugged1-liveness-visited-ucontext --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness
 143 #                                                      --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 144 #                                                      --cd ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness
 145 #                                                       ${CMAKE_HOME_DIRECTORY}/examples/s4u/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh)
 146     IF(HAVE_C_STACK_CLEANER)
 147       # This test checks if the stack cleaner is making a difference:
 148       ADD_TEST(s4u-mc-bugged1-liveness-stack-cleaner ${CMAKE_HOME_DIRECTORY}/examples/s4u/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
 149                                                      ${CMAKE_HOME_DIRECTORY}/examples/s4u/mc-bugged1-liveness/
 150                                                      ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/)
 151     ENDIF()
 152   ENDIF()
 153
 154 #  if (enable_coverage)
 155 #    SET_TESTS_PROPERTIES(mc-bugged1-liveness-visited-ucontext PROPERTIES RUN_SERIAL "TRUE")
 156 #  endif()
 157 ENDIF()
 158
 159 # The tests the parallel variant of of DHTs
 160
 161 if(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_PROCESSOR STREQUAL "i386" AND CMAKE_SIZEOF_VOID_P EQUAL 8)
 162   # Thread-local storage (TLS) is needed for parallel execution, but it doesn't
 163   # play well with Ucontexts on 64bit SunOS (at least on x86_64).
 164   set(parallel-factories "thread;raw;boost")
 165 else()
 166   set(parallel-factories "thread;ucontext;raw;boost")
 167 endif()
 168
 169 foreach(example app-bittorrent app-masterworkers
 170                 dht-chord dht-kademlia
 171                 )
 172   ADD_TESH_FACTORIES(s4u-${example}-parallel "${parallel-factories}" --cfg contexts/nthreads:4 ${CONTEXTS_SYNCHRO}
 173                                              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 174                                              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 175                                              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 176                                              ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 177 endforeach()
 178
 179 # ns3-tests
 180 if(SIMGRID_HAVE_NS3)
 181   ADD_TESH_FACTORIES(s4u-network-ns3 "thread;ucontext;raw;boost"
 182                                      --setenv srcdir=${CMAKE_HOME_DIRECTORY}/examples/s4u
 183                                      --setenv bindir=${CMAKE_BINARY_DIR}/examples/s4u
 184                                      --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 185                                      ${CMAKE_HOME_DIRECTORY}/examples/s4u/network-ns3/s4u-network-ns3.tesh)
 186 endif()
 187 # Examples not accepting factories
 188 ##################################
 189
 190 foreach (example trace-platform)
 191   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 192   target_link_libraries(s4u-${example} simgrid)
 193   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 194   add_dependencies(tests s4u-${example})
 195
 196   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 197   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 198
 199   ADD_TESH(s4u-${example} --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 200                           --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 201                           ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 202 endforeach()
 203
 204 if (NOT enable_memcheck AND NOT WIN32)
 205   ADD_TESH(simix-breakpoint --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/app-pingpong
 206                             --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 207                             ${CMAKE_CURRENT_SOURCE_DIR}/app-pingpong/simix-breakpoint.tesh)
 208 endif()
 209
 210 # Add all extra files to the archive
 211 ####################################
 212
 213 set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/s4u-network-ns3.cpp              PARENT_SCOPE)
 214 set(tesh_files    ${tesh_files}   ${CMAKE_CURRENT_SOURCE_DIR}/app-pingpong/simix-breakpoint.tesh
 215                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh
 216                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/s4u-network-ns3.tesh             PARENT_SCOPE)
 217 set(xml_files     ${xml_files}    ${CMAKE_CURRENT_SOURCE_DIR}/actor-create/s4u-actor-create_d.xml
 218                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-lifetime/s4u-actor-lifetime_d.xml
 219                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-yield/s4u-actor-yield_d.xml
 220                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent_d.xml
 221                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers_d.xml
 222                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-suspend/s4u-comm-suspend_d.xml
 223                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-wait/s4u-comm-wait_d.xml
 224                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-waitany/s4u-comm-waitany_d.xml
 225                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-waitall/s4u-comm-waitall_d.xml
 226                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-ready/s4u-comm-ready_d.xml
 227                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-waituntil/s4u-comm-waituntil_d.xml
 228                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord_d.xml
 229                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia_d.xml
 230                                   ${CMAKE_CURRENT_SOURCE_DIR}/energy-boot/platform_boot.xml
 231                                   ${CMAKE_CURRENT_SOURCE_DIR}/io-file-remote/s4u-io-file-remote_d.xml
 232                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-properties/s4u-platform-properties_d.xml
 233                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-failures/s4u-platform-failures_d.xml
 234                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split_d.xml
 235                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm_d.xml
 236                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io_d.xml
 237                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3hosts_2links_d.xml
 238                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links-timer_d.xml
 239                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links_d.xml
 240                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/crosstraffic_d.xml
 241                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/dogbone_d.xml
 242                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/onelink_d.xml
 243                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/one_cluster_d.xml                PARENT_SCOPE)
 244 set(bin_files     ${bin_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/generate.py
 245                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
 246                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/promela_bugged1_liveness PARENT_SCOPE)
 247 set(txt_files     ${txt_files}    ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p0.txt
 248                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p1.txt
 249                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm.txt
 250                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io.txt                  PARENT_SCOPE)
 251