tools/cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 install(DIRECTORY "${CMAKE_BINARY_DIR}/doc/html/" DESTINATION ${CMAKE_INSTALL_DOCDIR}/html/ OPTIONAL)
   7
   8 # binaries
   9 if(enable_smpi)
  10   install(PROGRAMS
  11     ${CMAKE_BINARY_DIR}/bin/smpicc
  12     ${CMAKE_BINARY_DIR}/bin/smpicxx
  13     ${CMAKE_BINARY_DIR}/bin/smpirun
  14     DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  15   if(SMPI_FORTRAN)
  16     install(PROGRAMS
  17       ${CMAKE_BINARY_DIR}/bin/smpif90
  18       ${CMAKE_BINARY_DIR}/bin/smpiff
  19       DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  20     install(PROGRAMS
  21       ${CMAKE_BINARY_DIR}/include/smpi/mpi.mod
  22       DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/smpi/)
  23   endif()
  24 endif()
  25
  26 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  27
  28 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  29   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  30   RENAME simgrid-colorizer)
  31
  32 add_custom_target(simgrid-colorizer ALL
  33   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  34   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize)
  35
  36 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  37   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  38   RENAME simgrid_update_xml)
  39
  40 add_custom_target(simgrid_update_xml ALL
  41   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  42   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml)
  43
  44 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py
  45   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  46   RENAME simgrid_convert_TI_traces)
  47
  48 add_custom_target(simgrid_convert_TI_traces ALL
  49     COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces"
  50     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces)
  51
  52 # libraries
  53 install(TARGETS simgrid DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  54
  55 # pkg-config files
  56 configure_file("${CMAKE_HOME_DIRECTORY}/tools/pkg-config/simgrid.pc.in"
  57   "${PROJECT_BINARY_DIR}/simgrid.pc" @ONLY)
  58 install(FILES "${PROJECT_BINARY_DIR}/simgrid.pc" DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
  59
  60 # include files
  61 foreach(file ${headers_to_install} ${generated_headers_to_install})
  62   get_filename_component(location ${file} PATH)
  63   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  64   string(REGEX REPLACE "^include/" "" location "${location}")
  65   string(REGEX REPLACE "^include$" "" location "${location}")
  66   # message("installing '${file}' into '${CMAKE_INSTALL_INCLUDEDIR}/${location}'")
  67   install(FILES ${file} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${location})
  68 endforeach()
  69
  70 # example files
  71 foreach(file ${examples_to_install})
  72   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  73   get_filename_component(location ${file} PATH)
  74   # message("DOC installing 'examples/${file}' into '${CMAKE_INSTALL_DOCDIR}/examples/${location}'")
  75   install(FILES "examples/${file}"
  76     DESTINATION ${CMAKE_INSTALL_DOCDIR}/examples/${location})
  77 endforeach(file ${examples_to_install})
  78
  79 ################################################################
  80 ## Build a sane "make dist" target to build a source package ###
  81 ##    containing only the files that I explicitly state      ###
  82 ##   (instead of any cruft laying on my disk as CPack does)  ###
  83 ################################################################
  84
  85 # This is the complete list of what will be added to the source archive
  86 set(source_to_pack
  87   ${headers_to_install}
  88   ${source_of_generated_headers}
  89   ${MC_SRC_BASE}
  90   ${MC_SRC}
  91   ${MC_SIMGRID_MC_SRC}
  92   ${MSG_SRC}
  93   ${S4U_SRC}
  94   ${NS3_SRC}
  95   ${PLUGINS_SRC}
  96   ${DAG_SRC}
  97   ${SIMGRID_SRC}
  98   ${SIMIX_SRC}
  99   ${SMPI_SRC}
 100   ${SURF_SRC}
 101   ${TRACING_SRC}
 102   ${XBT_RL_SRC}
 103   ${XBT_SRC}
 104   ${STHREAD_SRC}
 105   ${EXTRA_DIST}
 106   ${CMAKE_SOURCE_FILES}
 107   ${CMAKEFILES_TXT}
 108   ${DOC_IMG}
 109   ${DOC_SOURCES}
 110   ${DOC_TOOLS}
 111   ${PLATFORMS_EXAMPLES}
 112   ${README_files}
 113   ${bin_files}
 114   ${examples_src}
 115   ${tesh_files}
 116   ${teshsuite_src}
 117   ${tools_src}
 118   ${txt_files}
 119   ${xml_files}
 120   )
 121 list(SORT source_to_pack)
 122 list(REMOVE_DUPLICATES source_to_pack)
 123
 124 ##########################################
 125 ### Fill in the "make dist-dir" target ###
 126 ##########################################
 127
 128 add_custom_target(dist-dir
 129   COMMENT "Generating the distribution directory"
 130   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 131   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 132   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 133   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 134   )
 135 add_dependencies(dist-dir maintainer_files)
 136
 137 set(dirs_in_tarball "")
 138 foreach(file ${source_to_pack})
 139   #message(${file})
 140   # This damn prefix is still set somewhere (seems to be in subdirs)
 141   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 142
 143   # Prepare the list of files to include in the python sdist, one per line
 144   set(PYTHON_SOURCES "${PYTHON_SOURCES}\ninclude ${file}")
 145
 146   # Create the directory on need
 147   get_filename_component(file_location ${file} PATH)
 148   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 149   if(NOT OPERATION)
 150     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 151     add_custom_command(
 152       TARGET dist-dir
 153       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/)
 154   endif()
 155
 156   # Actually copy the file
 157   add_custom_command(
 158     TARGET dist-dir
 159     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location})
 160 endforeach(file ${source_to_pack})
 161 configure_file("${CMAKE_HOME_DIRECTORY}/MANIFEST.in.in" "${CMAKE_BINARY_DIR}/MANIFEST.in" @ONLY IMMEDIATE)
 162 unset(PYTHON_SOURCES)
 163
 164
 165 add_custom_command(
 166   TARGET dist-dir
 167   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion)
 168
 169 ##########################################################
 170 ### Link all sources to the bindir if srcdir != bindir ###
 171 ##########################################################
 172 add_custom_target(hardlinks
 173    COMMENT "Making the source files available from the bindir"
 174 )
 175 if (NOT ${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
 176   foreach(file ${source_to_pack})
 177     #message(${file})
 178     # This damn prefix is still set somewhere (seems to be in subdirs)
 179     string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 180
 181     # Create the directory on need
 182     get_filename_component(file_location ${file} PATH)
 183     string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_bindir}")
 184     if(NOT OPERATION)
 185       set(dirs_in_tarball "${dirs_in_bindir};${file_location};")
 186       add_custom_command(
 187         TARGET hardlinks
 188         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/${file_location}/)
 189     endif()
 190
 191     # Actually copy the file
 192     add_custom_command(
 193       TARGET hardlinks
 194       COMMAND if test -f ${CMAKE_HOME_DIRECTORY}/${file} \; then rm -f ${CMAKE_BINARY_DIR}/${file}\; ln ${CMAKE_HOME_DIRECTORY}/${file} ${CMAKE_BINARY_DIR}/${file_location}\; fi
 195     )
 196   endforeach(file ${source_to_pack})
 197 endif()
 198
 199
 200 ######################################
 201 ### Fill in the "make dist" target ###
 202 ######################################
 203
 204 add_custom_target(dist
 205   COMMENT "Removing the distribution directory"
 206   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 207   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 208   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 209
 210 add_custom_command(
 211   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 212   COMMENT "Compressing the archive from the distribution directory"
 213   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 214   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 215   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 216 add_dependencies(dist dist-dir)
 217
 218 if(NOT enable_maintainer_mode)
 219   add_custom_target(echo-dist
 220     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 221     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 222     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------")
 223   add_dependencies(dist echo-dist)
 224 endif()
 225
 226 ###########################################
 227 ### Fill in the "make distcheck" target ###
 228 ###########################################
 229
 230 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 231
 232 # Allow to test the "make dist"
 233 add_custom_target(distcheck
 234   COMMAND ${CMAKE_COMMAND} -E echo "XXX Compare archive with git repository"
 235   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/internal/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 236
 237   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove old copy"
 238   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 239
 240   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 241   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 242
 243   COMMAND ${CMAKE_COMMAND} -E echo "XXX Create build and install subtrees"
 244   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 245   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 246
 247   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 248   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 249           ${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst -Denable_lto=OFF ..
 250
 251   COMMAND ${CMAKE_COMMAND} -E echo "XXX Check generated files -- please copy new version if they are different"
 252   COMMAND ${CMAKE_COMMAND} -E compare_files ${CMAKE_HOME_DIRECTORY}/MANIFEST.in ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build/MANIFEST.in
 253
 254   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 255   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4
 256
 257   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 258   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 259
 260   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build tests"
 261   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4 tests
 262
 263   COMMAND ${CMAKE_COMMAND} -E echo "XXX Run tests"
 264   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure -j 4
 265
 266   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 267   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 268   )
 269 add_dependencies(distcheck dist)
 270
 271 #######################################
 272 ### Fill in the "make check" target ###
 273 #######################################
 274
 275 if(enable_memcheck)
 276   add_custom_target(check COMMAND ctest -D ExperimentalMemCheck)
 277 else()
 278   add_custom_target(check COMMAND make test)
 279 endif()
 280 add_dependencies(check tests)
 281
 282 include(CPack)