buildtools/Cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6
   7 #### Generate the manpages
   8 if(NOT WIN32)
   9   if( NOT MANPAGE_DIR)
  10     set( MANPAGE_DIR ${CMAKE_BINARY_DIR}/manpages )
  11   endif()
  12
  13   add_custom_target(manpages ALL
  14     COMMAND ${CMAKE_COMMAND} -E make_directory ${MANPAGE_DIR}
  15     COMMAND pod2man ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl > ${MANPAGE_DIR}/simgrid_update_xml.1
  16     COMMENT "Generating manpages"
  17     )
  18   install(FILES ${MANPAGE_DIR}/simgrid_update_xml.1 ${CMAKE_HOME_DIRECTORY}/tools/tesh/tesh.1
  19     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/share/man/man1)
  20
  21 endif()
  22
  23 # binaries
  24 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/smpicc
  25   ${CMAKE_BINARY_DIR}/bin/smpif2c
  26   ${CMAKE_BINARY_DIR}/bin/smpiff
  27   ${CMAKE_BINARY_DIR}/bin/smpif90
  28   ${CMAKE_BINARY_DIR}/bin/smpirun
  29   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  30
  31 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh
  32   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  33
  34 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/graphicator
  35   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  36
  37 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  38   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  39   RENAME simgrid-colorizer)
  40
  41 add_custom_target(simgrid-colorizer ALL
  42   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  43   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize
  44   )
  45
  46 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  47   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  48   RENAME simgrid_update_xml)
  49
  50 add_custom_target(simgrid_update_xml ALL
  51   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  52   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml
  53   )
  54
  55 # libraries
  56 install(TARGETS simgrid
  57   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  58
  59 if(enable_smpi)
  60   install(TARGETS smpi
  61     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  62 endif()
  63
  64 if(enable_lib_static AND NOT WIN32)
  65   install(TARGETS simgrid_static
  66     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  67   if(enable_smpi)
  68     install(TARGETS smpi_static
  69       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  70   endif()
  71 endif()
  72
  73 # include files
  74 set(HEADERS
  75   ${headers_to_install}
  76   ${generated_headers_to_install}
  77   )
  78 foreach(file ${HEADERS})
  79   get_filename_component(location ${file} PATH)
  80   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  81   install(FILES ${file}
  82     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/${location})
  83 endforeach(file ${HEADERS})
  84
  85 # example files
  86 foreach(file ${examples_to_install})
  87   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  88   get_filename_component(location ${file} PATH)
  89   install(FILES "examples/${file}"
  90     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/examples/${location})
  91 endforeach(file ${examples_to_install})
  92
  93 # bindings cruft
  94
  95 if(HAVE_LUA)
  96   file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/lib/lua/5.1")
  97   add_custom_target(simgrid_lua ALL
  98     DEPENDS simgrid
  99     ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 100     )
 101   add_custom_command(
 102     OUTPUT ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 103     COMMAND ${CMAKE_COMMAND} -E create_symlink ../../libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 104     )
 105   install(FILES ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 106     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/lua/5.1
 107     )
 108 endif()
 109
 110 ###########################################
 111 ### Fill in the "make uninstall" target ###
 112 ###########################################
 113
 114 add_custom_target(uninstall
 115   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/doc/simgrid
 116   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall doc ok"
 117   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsimgrid*
 118   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsmpi*
 119   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid*
 120   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall lib ok"
 121   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicc
 122   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif2c
 123   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpiff
 124   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif90
 125   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpirun
 126   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/tesh
 127   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid-colorizer
 128   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid_update_xml
 129   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/graphicator
 130   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall bin ok"
 131   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/instr
 132   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/msg
 133   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simdag
 134   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/smpi
 135   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simix
 136   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/surf
 137   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/xbt
 138   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/mc
 139   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simgrid
 140   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid_config.h
 141   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/xbt.h
 142   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall include ok"
 143   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/simgrid_update_xml.1
 144     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/tesh.1
 145   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall man ok"
 146   WORKING_DIRECTORY "${CMAKE_INSTALL_PREFIX}"
 147   )
 148
 149 if(HAVE_LUA)
 150   add_custom_command(TARGET uninstall
 151     COMMAND ${CMAKE_COMMAND} -E echo "uninstall binding lua ok"
 152     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid.${LIB_EXE}
 153     WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}/"
 154     )
 155 endif()
 156
 157 ################################################################
 158 ## Build a sain "make dist" target to build a source package ###
 159 ##   containing only the files that I explicitely state      ###
 160 ##   (instead of any cruft laying on my disk as CPack does)  ###
 161 ################################################################
 162
 163 # This is the complete list of what will be added to the source archive
 164 set(source_to_pack
 165   ${headers_to_install}
 166   ${source_of_generated_headers}
 167   ${BINDINGS_SRC}
 168   ${GTNETS_SRC}
 169   ${JEDULE_SRC}
 170   ${LUA_SRC}
 171   ${MC_SRC}
 172   ${MSG_SRC}
 173   ${NS3_SRC}
 174   ${RNGSTREAM_SRC}
 175   ${SIMDAG_SRC}
 176   ${SIMGRID_SRC}
 177   ${SIMIX_SRC}
 178   ${SMPI_SRC}
 179   ${SURF_SRC}
 180   ${TRACING_SRC}
 181   ${XBT_RL_SRC}
 182   ${XBT_SRC}
 183   ${EXTRA_DIST}
 184   ${CMAKE_SOURCE_FILES}
 185   ${EXAMPLES_CMAKEFILES_TXT}
 186   ${TESHSUITE_CMAKEFILES_TXT}
 187   ${TESTSUITE_CMAKEFILES_TXT}
 188   ${TOOLS_CMAKEFILES_TXT}
 189   ${DOC_FIGS}
 190   ${DOC_IMG}
 191   ${DOC_SOURCES}
 192   ${DOC_TOOLS}
 193   ${PLATFORMS_EXAMPLES}
 194   ${README_files}
 195   ${bin_files}
 196   ${examples_src}
 197   ${tesh_files}
 198   ${teshsuite_src}
 199   ${testsuite_src}
 200   ${tools_src}
 201   ${txt_files}
 202   ${xml_files}
 203   )
 204
 205 ##########################################
 206 ### Fill in the "make dist-dir" target ###
 207 ##########################################
 208
 209 add_custom_target(dist-dir
 210   COMMENT "Generating the distribution directory"
 211   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 212   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 213   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 214   )
 215 add_dependencies(dist-dir simgrid_documentation)
 216 add_dependencies(dist-dir maintainer_files)
 217
 218 set(dirs_in_tarball "")
 219 foreach(file ${source_to_pack})
 220   #message(${file})
 221   # This damn prefix is still set somewhere (seems to be in subdirs)
 222   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 223
 224   # Create the directory on need
 225   get_filename_component(file_location ${file} PATH)
 226   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 227   if(NOT OPERATION)
 228     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 229     add_custom_command(
 230       TARGET dist-dir
 231       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/
 232       )
 233   endif()
 234
 235   # Actually copy the file
 236   add_custom_command(
 237     TARGET dist-dir
 238     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location}/
 239     )
 240 endforeach(file ${source_to_pack})
 241
 242 add_custom_command(
 243   TARGET dist-dir
 244   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/buildtools/Cmake/Scripts/Makefile.default ${PROJECT_NAME}-${release_version}/Makefile
 245   )
 246
 247 ######################################
 248 ### Fill in the "make dist" target ###
 249 ######################################
 250
 251 add_custom_target(dist
 252   COMMENT "Removing the distribution directory"
 253   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 254   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 255   )
 256
 257 add_custom_command(
 258   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 259   COMMENT "Compressing the archive from the distribution directory"
 260   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 261   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 262   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 263   )
 264 add_dependencies(dist dist-dir)
 265
 266 if(NOT enable_maintainer_mode)
 267   add_custom_target(echo-dist
 268     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 269     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 270     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 271     )
 272   add_dependencies(dist echo-dist)
 273 endif()
 274
 275 ###########################################
 276 ### Fill in the "make distcheck" target ###
 277 ###########################################
 278
 279 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 280
 281 # Allow to test the "make dist"
 282 add_custom_target(distcheck
 283   COMMAND ${CMAKE_COMMAND} -E echo "XXX remove old copy"
 284   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 285
 286   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 287   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 288
 289   COMMAND ${CMAKE_COMMAND} -E echo "XXX create build and install subtrees"
 290   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 291   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 292
 293   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 294   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 295   ${CMAKE_COMMAND}
 296   -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 297   ..
 298   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 299   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM}
 300
 301   COMMAND ${CMAKE_COMMAND} -E echo "XXX Test"
 302   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest || true
 303
 304   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 305   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 306   COMMAND ${CMAKE_COMMAND} -E create_symlink
 307   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgrid.so
 308   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgridtest.so
 309
 310   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 311   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 312   )
 313 add_dependencies(distcheck dist)
 314
 315 #######################################
 316 ### Fill in the "make check" target ###
 317 #######################################
 318
 319 if(enable_memcheck)
 320   add_custom_target(check
 321     COMMAND ctest -D ExperimentalMemCheck
 322     )
 323 else()
 324   add_custom_target(check
 325     COMMAND make test
 326     )
 327 endif()
 328
 329 #######################################
 330 ### Fill in the "make xxx-clean" target ###
 331 #######################################
 332
 333 add_custom_target(maintainer-clean
 334   COMMAND ${CMAKE_COMMAND} -E remove -f src/config_unit.c
 335   COMMAND ${CMAKE_COMMAND} -E remove -f src/cunit_unit.c
 336   COMMAND ${CMAKE_COMMAND} -E remove -f src/dict_unit.c
 337   COMMAND ${CMAKE_COMMAND} -E remove -f src/dynar_unit.c
 338   COMMAND ${CMAKE_COMMAND} -E remove -f src/ex_unit.c
 339   COMMAND ${CMAKE_COMMAND} -E remove -f src/set_unit.c
 340   COMMAND ${CMAKE_COMMAND} -E remove -f src/simgrid_units_main.c
 341   COMMAND ${CMAKE_COMMAND} -E remove -f src/swag_unit.c
 342   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_sha_unit.c
 343   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_str_unit.c
 344   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_strbuff_unit.c
 345   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_synchro_unit.c
 346   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 347   )
 348
 349 add_custom_target(supernovae-clean
 350   COMMAND ${CMAKE_COMMAND} -E remove -f src/supernovae_sg.c
 351   COMMAND ${CMAKE_COMMAND} -E remove -f src/supernovae_smpi.c
 352   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 353   )
 354
 355
 356 include(CPack)