tools/cmake/Flags.cmake

   1 ##
   2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
   3 ##
   4 ##   It is only used for gcc and clang. MSVC builds don't load this file.
   5 ##
   6 ##   These flags do break some classical CMake tests, so you don't
   7 ##   want to do so before the very end of the configuration.
   8 ##
   9 ##   Other compiler flags (C/C++ standard version) are tested and set
  10 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
  11
  12 set(warnCFLAGS "")
  13 set(optCFLAGS "")
  14 set(warnCXXFLAGS "")
  15
  16 if(enable_compile_warnings)
  17   set(warnCFLAGS "-fno-common -Wall -Wunused -Wmissing-declarations -Wpointer-arith -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
  18   if(CMAKE_COMPILER_IS_GNUCC)
  19     set(warnCFLAGS "${warnCFLAGS} -Wclobbered -Wformat-signedness -Wno-error=clobbered -Wno-unused-local-typedefs -Wno-error=attributes -Wno-error=maybe-uninitialized")
  20   endif()
  21   if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  22     # ignore remarks:
  23     # 191: type qualifier is meaningless on cast type
  24     # 1418: external function definition with no prior declaration
  25     # 2196: routine is both "inline" and "noinline"
  26     # 2651: attribute does not apply to any entity
  27     # 3179: deprecated conversion of string literal to char* (should be const char*)
  28     # set as warning:
  29     # 597: entity-kind "entity" will not be called for implicit or explicit conversions
  30     # 2330: argument of type "type" is incompatible with parameter of type "type" (dropping qualifiers)
  31     # 11003: no IR in object file xxxx; was the source file compiled with xxxx
  32     set(warnCFLAGS "${warnCFLAGS} -diag-disable=191,1418,2196,2651,3179 -diag-warning=597,2330,11003")
  33   endif()
  34
  35   set(warnCXXFLAGS "${warnCFLAGS} -Wall -Wextra -Wunused -Wmissing-declarations -Wpointer-arith -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
  36   if(CMAKE_COMPILER_IS_GNUCXX)
  37     set(warnCXXFLAGS "${warnCXXFLAGS} -Wclobbered -Wformat-signedness -Wno-error=clobbered -Wno-free-nonheap-object -Wno-unused-local-typedefs -Wno-error=attributes -Wno-error=maybe-uninitialized")
  38   endif()
  39   if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "8.0")
  40     # workaround for https://gcc.gnu.org/bugzilla/show_bug.cgi?id=81767
  41     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-error=unused-variable")
  42   endif()
  43   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  44     # don't care about class that become struct, avoid issue of empty C structs
  45     # size (coming from libunwind.h)
  46     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-mismatched-tags -Wno-extern-c-compat")
  47   endif()
  48
  49   # the one specific to C but refused by C++
  50   set(warnCFLAGS "${warnCFLAGS} -Wmissing-prototypes")
  51
  52   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC|PGI")
  53     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
  54   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Flang")
  55     # flang >= 7 has a bug with common and debug flags. Ignore cmake-added -g in this case.
  56     # https://github.com/flang-compiler/flang/issues/671
  57     set(CMAKE_Fortran_FLAGS "-Wall")
  58   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
  59     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -warn all")
  60   endif()
  61   set(CMAKE_JAVA_COMPILE_FLAGS "-Xlint")
  62 endif()
  63
  64 # NDEBUG gives a lot of "initialized but unused variables" errors. Don't die anyway.
  65 if(enable_compile_warnings AND enable_debug)
  66   set(warnCFLAGS "${warnCFLAGS} -Werror")
  67   set(warnCXXFLAGS "${warnCXXFLAGS} -Werror")
  68   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC")
  69     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Werror -Werror=format-security")
  70   endif()
  71 endif()
  72
  73 # Activate the warnings on #if FOOBAR when FOOBAR has no value
  74 # It breaks on FreeBSD within Boost headers, so activate this only in Pure Hardcore debug mode.
  75 if(enable_maintainer_mode)
  76   set(warnCFLAGS "${warnCFLAGS} -Wundef")
  77   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wundef")
  78 endif()
  79
  80 # Se the optimisation flags
  81 # NOTE, we should CMAKE_BUILD_TYPE for this
  82 if(enable_compile_optimizations)
  83   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
  84 else()
  85   set(optCFLAGS "-O0 ")
  86 endif()
  87
  88 #ARM platforms have signed char by default, switch to unsigned for consistancy
  89 if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "aarch64")
  90   set(optCFLAGS "${optCFLAGS} -fsigned-char")
  91 endif()
  92
  93 if(enable_compile_optimizations AND CMAKE_COMPILER_IS_GNUCC
  94     AND (NOT enable_model-checking))
  95   # This is redundant (already in -03):
  96   set(optCFLAGS "${optCFLAGS} -finline-functions ")
  97 endif()
  98
  99 # Do not leak the current directory into the binaries
 100 if(CMAKE_COMPILER_IS_GNUCC)
 101   execute_process(COMMAND realpath --relative-to=${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}
 102     RESULT_VARIABLE RESULT OUTPUT_VARIABLE RELATIVE_SOURCE_DIR ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
 103   if(RESULT EQUAL 0)
 104     message(STATUS "Relative source directory is \"${RELATIVE_SOURCE_DIR}\".")
 105   else()
 106     message(WARNING "Failed to find relative source directory. Using \".\".")
 107     set(RELATIVE_SOURCE_DIR ".")
 108   endif()
 109   if (CMAKE_C_COMPILER_VERSION VERSION_LESS "8.0")
 110     set(optCFLAGS "${optCFLAGS} -fdebug-prefix-map=\"${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}\"")
 111   else()
 112     set(optCFLAGS "${optCFLAGS} -ffile-prefix-map=\"${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}\"")
 113   endif()
 114 endif()
 115
 116 # Configure LTO
 117 if(enable_lto) # User wants LTO. Try if we can do that
 118   set(enable_lto OFF)
 119   if(enable_compile_optimizations
 120       AND (NOT enable_model-checking))
 121     if(CMAKE_VERSION VERSION_LESS "3.9")
 122       if ( CMAKE_COMPILER_IS_GNUCC
 123          AND (CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8.5")
 124          AND (LINKER_VERSION VERSION_GREATER "2.22"))
 125         set(enable_lto ON)
 126       endif()
 127     else()
 128       include(CheckIPOSupported)
 129       check_ipo_supported(RESULT ipo LANGUAGES C CXX)
 130       if(ipo)
 131         set(enable_lto ON)
 132       endif()
 133     endif()
 134   endif()
 135
 136   if(enable_lto)
 137     message(STATUS "LTO seems usable.")
 138   else()
 139     if(NOT enable_compile_optimizations)
 140       message(STATUS "LTO disabled: Compile-time optimizations turned off.")
 141     else()
 142       if(enable_model-checking)
 143         message(STATUS "LTO disabled when compiling with model-checking.")
 144       else()
 145         message(STATUS "LTO does not seem usable -- try updating your build chain.")
 146       endif()
 147     endif()
 148   endif()
 149 else()
 150   message(STATUS "LTO disabled on the command line.")
 151 endif()
 152 if(enable_lto) # User wants LTO, and it seems usable. Go for it
 153   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
 154   if(LTO_EXTRA_FLAG AND CMAKE_COMPILER_IS_GNUCC)
 155     list(APPEND CMAKE_C_COMPILE_OPTIONS_IPO "-flto=${LTO_EXTRA_FLAG}")
 156     list(APPEND CMAKE_CXX_COMPILE_OPTIONS_IPO "-flto=${LTO_EXTRA_FLAG}")
 157   endif()
 158
 159   # Activate fat-lto-objects in case LD and gfortran differ too much.
 160   # Only test with GNU as it's the only case I know (clang+gfortran+lld)
 161   execute_process(COMMAND ${CMAKE_LINKER} -v OUTPUT_VARIABLE LINKER_ID ERROR_VARIABLE LINKER_ID)
 162   string(REGEX MATCH "GNU" LINKER_ID "${LINKER_ID}")
 163   if(${CMAKE_Fortran_COMPILER_ID} MATCHES "GNU"
 164      AND NOT "${LINKER_ID}" MATCHES "GNU")
 165        list(APPEND CMAKE_Fortran_COMPILE_OPTIONS_IPO "-ffat-lto-objects")
 166   endif()
 167
 168   # "Since version 4.9 gcc produces slim object files that only contain
 169   # the intermediate representation. In order to handle archives of
 170   # these objects you have to use the gcc wrappers:
 171   # gcc-ar, gcc-nm and gcc-ranlib."
 172   if(${CMAKE_C_COMPILER_ID} STREQUAL "GNU"
 173       AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8")
 174     set (CMAKE_AR gcc-ar)
 175     set (CMAKE_RANLIB gcc-ranlib)
 176   endif()
 177 endif()
 178
 179 if(enable_model-checking AND enable_compile_optimizations)
 180   # Forget it, do not optimize the code (because it confuses the MC):
 181   set(optCFLAGS "-O0")
 182   # But you can still optimize this:
 183   set(src_list ${simgrid_sources})
 184   # except...
 185   list(REMOVE_ITEM src_list ${SIMIX_SRC} ${S4U_SRC})
 186   # but...
 187   list(APPEND src_list
 188     src/kernel/actor/Simcall.cpp)
 189   foreach(src ${src_list})
 190       set (mcCFLAGS "-O3 -funroll-loops -fno-strict-aliasing")
 191       if(CMAKE_COMPILER_IS_GNUCC)
 192         set (mcCFLAGS "${mcCFLAGS} -finline-functions")
 193       endif()
 194       set_source_files_properties(${src} PROPERTIES COMPILE_FLAGS ${mcCFLAGS})
 195   endforeach()
 196 endif()
 197
 198 if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 199   # honor parentheses when determining the order of expression evaluation.
 200   # disallow optimizations for floating-point arithmetic with Nans or +-Infs (breaks Eigen3)
 201   set(optCFLAGS "${optCFLAGS} -fprotect-parens -fno-finite-math-only")
 202 endif()
 203
 204 if(NOT enable_debug)
 205   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
 206   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
 207 endif()
 208
 209 set(CMAKE_C_FLAGS   "${warnCFLAGS} ${CMAKE_C_FLAGS}   ${optCFLAGS}")
 210 set(CMAKE_CXX_FLAGS "${warnCXXFLAGS} ${CMAKE_CXX_FLAGS} ${optCFLAGS}")
 211
 212 # Try to make Mac a bit more compliant to open source standards
 213 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 214   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 215 endif()
 216
 217 # Avoid a failure seen with gcc 7.2.0 and ns3 3.27
 218 if(enable_ns3)
 219   set_source_files_properties(src/surf/network_ns3.cpp PROPERTIES COMPILE_FLAGS " -Wno-unused-local-typedef")
 220 endif()
 221
 222 set(TESH_OPTION "")
 223 if(enable_coverage)
 224   find_program(GCOV_PATH NAMES ENV{GCOV} gcov)
 225   if(GCOV_PATH)
 226     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE FILEPATH "Coverage testing tool (gcov)" FORCE)
 227     set(COVERAGE_BUILD_FLAGS "-fprofile-arcs -ftest-coverage -fprofile-abs-path")
 228     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE ${COVERAGE_BUILD_FLAGS}")
 229     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${COVERAGE_BUILD_FLAGS}")
 230     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} ${COVERAGE_BUILD_FLAGS}")
 231     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCOVERAGE ${COVERAGE_BUILD_FLAGS}")
 232     add_definitions(${COVERAGE_BUILD_FLAGS})
 233   endif()
 234 endif()
 235
 236 if(enable_address_sanitizer)
 237     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 238     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 239     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=address")
 240     set(TESH_OPTION --enable-sanitizers)
 241     try_compile(HAVE_SANITIZER_ADDRESS ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp)
 242     try_compile(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp
 243       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 244 else()
 245     set(HAVE_SANITIZER_ADDRESS FALSE CACHE INTERNAL "")
 246     set(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 247 endif()
 248
 249 if(enable_thread_sanitizer)
 250     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 251     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 252     if(CMAKE_COMPILER_IS_GNUCXX AND (NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "12.0")))
 253         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=tsan")
 254     endif()
 255     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=thread -no-pie")
 256     try_compile(HAVE_SANITIZER_THREAD ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp)
 257     try_compile(HAVE_SANITIZER_THREAD_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp
 258       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 259 else()
 260     set(HAVE_SANITIZER_THREAD FALSE CACHE INTERNAL "")
 261     set(HAVE_SANITIZER_THREAD_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 262 endif()
 263
 264 if(enable_undefined_sanitizer)
 265     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 266     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 267     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=undefined")
 268 endif()
 269
 270 if(NOT $ENV{CFLAGS} STREQUAL "")
 271   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
 272   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
 273 endif()
 274
 275 if(NOT $ENV{CXXFLAGS} STREQUAL "")
 276   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
 277   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
 278 endif()
 279
 280 if(NOT $ENV{LDFLAGS} STREQUAL "")
 281   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
 282   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
 283 endif()
 284
 285 if(MINGW)
 286   # http://stackoverflow.com/questions/10452262/create-64-bit-jni-under-windows
 287   # We don't want to ship libgcc_s_seh-1.dll nor libstdc++-6.dll
 288   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -static-libgcc")
 289   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -static-libgcc -static-libstdc++")
 290   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS   "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -static-libgcc")
 291   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -static-libgcc -static-libstdc++")
 292
 293   # JNI searches for stdcalls
 294   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -Wl,--add-stdcall-alias")
 295   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wl,--add-stdcall-alias")
 296   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -Wl,--add-stdcall-alias")
 297   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -Wl,--add-stdcall-alias")
 298
 299   # Specify the data model that we are using (yeah it may help Java)
 300   if(CMAKE_SIZEOF_VOID_P EQUAL 4) # 32 bits
 301     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m32")
 302     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 303   else()
 304     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m64")
 305     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m64")
 306   endif()
 307 endif()