tools/cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 install(DIRECTORY "${CMAKE_BINARY_DIR}/doc/html/" DESTINATION ${CMAKE_INSTALL_DOCDIR}/html/ OPTIONAL)
   7
   8 # binaries
   9 if(enable_smpi)
  10   install(PROGRAMS
  11     ${CMAKE_BINARY_DIR}/bin/smpicc
  12     ${CMAKE_BINARY_DIR}/bin/smpicxx
  13     ${CMAKE_BINARY_DIR}/bin/smpirun
  14     DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  15   if(SMPI_FORTRAN)
  16     install(PROGRAMS
  17       ${CMAKE_BINARY_DIR}/bin/smpif90
  18       ${CMAKE_BINARY_DIR}/bin/smpiff
  19       DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  20     install(PROGRAMS
  21       ${CMAKE_BINARY_DIR}/include/smpi/mpi.mod
  22       DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/smpi/)
  23   endif()
  24 endif()
  25
  26 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  27
  28 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  29   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  30   RENAME simgrid_update_xml)
  31
  32 add_custom_target(simgrid_update_xml ALL
  33   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  34   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml)
  35
  36 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py
  37   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  38   RENAME simgrid_convert_TI_traces)
  39
  40 add_custom_target(simgrid_convert_TI_traces ALL
  41     COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces"
  42     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces)
  43
  44 # libraries
  45 install(TARGETS simgrid DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  46 install(TARGETS sthread DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  47
  48 # pkg-config files
  49 configure_file("${CMAKE_HOME_DIRECTORY}/tools/pkg-config/simgrid.pc.in"
  50   "${PROJECT_BINARY_DIR}/simgrid.pc" @ONLY)
  51 install(FILES "${PROJECT_BINARY_DIR}/simgrid.pc" DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
  52
  53 # include files
  54 foreach(file ${headers_to_install} ${generated_headers_to_install})
  55   get_filename_component(location ${file} PATH)
  56   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  57   string(REGEX REPLACE "^include/" "" location "${location}")
  58   string(REGEX REPLACE "^include$" "" location "${location}")
  59   # message("installing '${file}' into '${CMAKE_INSTALL_INCLUDEDIR}/${location}'")
  60   install(FILES ${file} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${location})
  61 endforeach()
  62
  63 # example files
  64 foreach(file ${examples_to_install})
  65   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  66   get_filename_component(location ${file} PATH)
  67   # message("DOC installing 'examples/${file}' into '${CMAKE_INSTALL_DOCDIR}/examples/${location}'")
  68   install(FILES "examples/${file}"
  69     DESTINATION ${CMAKE_INSTALL_DOCDIR}/examples/${location})
  70 endforeach(file ${examples_to_install})
  71
  72 ################################################################
  73 ## Build a sane "make dist" target to build a source package ###
  74 ##    containing only the files that I explicitly state      ###
  75 ##   (instead of any cruft laying on my disk as CPack does)  ###
  76 ################################################################
  77
  78 # This is the complete list of what will be added to the source archive
  79 set(source_to_pack
  80   ${headers_to_install}
  81   ${source_of_generated_headers}
  82   ${MC_SRC_BASE}
  83   ${MC_SRC}
  84   ${MC_SIMGRID_MC_SRC}
  85   ${S4U_SRC}
  86   ${NS3_SRC}
  87   ${PLUGINS_SRC}
  88   ${DAG_SRC}
  89   ${SIMGRID_SRC}
  90   ${SMPI_SRC}
  91   ${KERNEL_SRC}
  92   ${TRACING_SRC}
  93   ${XBT_RL_SRC}
  94   ${XBT_SRC}
  95   ${STHREAD_SRC}
  96   ${EXTRA_DIST}
  97   ${CMAKE_SOURCE_FILES}
  98   ${CMAKEFILES_TXT}
  99   ${DOC_SOURCES}
 100   ${DOC_TOOLS}
 101   ${PLATFORMS_EXAMPLES}
 102   ${README_files}
 103   ${bin_files}
 104   ${examples_src}
 105   ${tesh_files}
 106   ${teshsuite_src}
 107   ${tools_src}
 108   ${txt_files}
 109   ${xml_files}
 110   )
 111 list(SORT source_to_pack)
 112 list(REMOVE_DUPLICATES source_to_pack)
 113
 114 ##########################################
 115 ### Fill in the "make dist-dir" target ###
 116 ##########################################
 117
 118 add_custom_target(dist-dir
 119   COMMENT "Generating the distribution directory"
 120   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 121   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 122   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 123   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 124   )
 125 add_dependencies(dist-dir maintainer_files)
 126
 127 set(dirs_in_tarball "")
 128 foreach(file ${source_to_pack})
 129   #message(${file})
 130   # This damn prefix is still set somewhere (seems to be in subdirs)
 131   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 132
 133   # Prepare the list of files to include in the python sdist, one per line
 134   set(PYTHON_SOURCES "${PYTHON_SOURCES}\ninclude ${file}")
 135
 136   # Create the directory on need
 137   get_filename_component(file_location ${file} PATH)
 138   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 139   if(NOT OPERATION)
 140     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 141     add_custom_command(
 142       TARGET dist-dir
 143       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/)
 144   endif()
 145
 146   # Actually copy the file
 147   add_custom_command(
 148     TARGET dist-dir
 149     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location})
 150 endforeach(file ${source_to_pack})
 151 configure_file("${CMAKE_HOME_DIRECTORY}/MANIFEST.in.in" "${CMAKE_BINARY_DIR}/MANIFEST.in" @ONLY IMMEDIATE)
 152 unset(PYTHON_SOURCES)
 153
 154
 155 add_custom_command(
 156   TARGET dist-dir
 157   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion)
 158
 159 ##########################################################
 160 ### Link all sources to the bindir if srcdir != bindir ###
 161 ##########################################################
 162 add_custom_target(hardlinks
 163    COMMENT "Making the source files available from the bindir"
 164 )
 165 if (NOT ${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
 166   foreach(file ${source_to_pack})
 167     #message(${file})
 168     # This damn prefix is still set somewhere (seems to be in subdirs)
 169     string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 170
 171     # Create the directory on need
 172     get_filename_component(file_location ${file} PATH)
 173     string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_bindir}")
 174     if(NOT OPERATION)
 175       set(dirs_in_tarball "${dirs_in_bindir};${file_location};")
 176       add_custom_command(
 177         TARGET hardlinks
 178         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/${file_location}/)
 179     endif()
 180
 181     # Actually copy the file
 182     add_custom_command(
 183       TARGET hardlinks
 184       COMMAND if test -f ${CMAKE_HOME_DIRECTORY}/${file} \; then rm -f ${CMAKE_BINARY_DIR}/${file}\; ln ${CMAKE_HOME_DIRECTORY}/${file} ${CMAKE_BINARY_DIR}/${file_location}\; fi
 185     )
 186   endforeach(file ${source_to_pack})
 187 endif()
 188
 189
 190 ######################################
 191 ### Fill in the "make dist" target ###
 192 ######################################
 193
 194 add_custom_target(dist
 195   COMMENT "Removing the distribution directory"
 196   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 197   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 198   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 199
 200 add_custom_command(
 201   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 202   COMMENT "Compressing the archive from the distribution directory"
 203   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 204   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 205   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 206 add_dependencies(dist dist-dir)
 207
 208 ###########################################
 209 ### Fill in the "make distcheck" target ###
 210 ###########################################
 211
 212 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 213
 214 # Allow to test the "make dist"
 215 add_custom_target(distcheck-archive
 216   COMMAND ${CMAKE_COMMAND} -E echo "XXX Compare archive with git repository"
 217   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/internal/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 218   )
 219 add_dependencies(distcheck-archive dist)
 220
 221 add_custom_target(distcheck-configure
 222   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove old copy"
 223   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 224
 225   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 226   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 227
 228   COMMAND ${CMAKE_COMMAND} -E echo "XXX Create build and install subtrees"
 229   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 230   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 231
 232   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 233   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 234           ${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst -Denable_lto=OFF ..
 235
 236   COMMAND ${CMAKE_COMMAND} -E echo "XXX Check generated files -- please copy new version if they are different"
 237   COMMAND ${CMAKE_COMMAND} -E compare_files ${CMAKE_HOME_DIRECTORY}/MANIFEST.in ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build/MANIFEST.in
 238   )
 239 add_dependencies(distcheck-configure distcheck-archive)
 240
 241 add_custom_target(distcheck
 242   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 243   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4
 244
 245   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 246   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 247
 248   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build tests"
 249   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4 tests
 250
 251   COMMAND ${CMAKE_COMMAND} -E echo "XXX Run tests"
 252   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure -j 4
 253
 254   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 255   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 256   )
 257 add_dependencies(distcheck distcheck-configure)
 258
 259 #######################################
 260 ### Fill in the "make check" target ###
 261 #######################################
 262
 263 if(enable_memcheck)
 264   add_custom_target(check COMMAND ctest -D ExperimentalMemCheck)
 265 else()
 266   add_custom_target(check COMMAND make test)
 267 endif()
 268 add_dependencies(check tests)
 269
 270 include(CPack)