tools/cmake/Flags.cmake

   1 ##
   2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
   3 ##
   4 ##   These flags do break some classical CMake tests, so you don't
   5 ##   want to do so before the very end of the configuration.
   6 ##
   7 ##   Other compiler flags (C/C++ standard version) are tested and set
   8 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
   9
  10 set(warnCFLAGS "")
  11 set(optCFLAGS "")
  12
  13
  14
  15 if(enable_compile_warnings)
  16   set(warnCFLAGS "-fno-common -Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing -Wno-format-nonliteral -Werror ")
  17   if(CMAKE_COMPILER_IS_GNUCC)
  18     set(warnCFLAGS "${warnCFLAGS}-Wclobbered -Wno-error=clobbered ")
  19   endif()
  20
  21   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra  -Wunused -Wpointer-arith -Wchar-subscripts -Wcomment  -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing -Wno-format-nonliteral -Werror")
  22   if(CMAKE_COMPILER_IS_GNUCXX)
  23     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wclobbered -Wno-error=clobbered")
  24   endif()
  25   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang") # don't care about class that become struct
  26     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-mismatched-tags")
  27   endif()
  28
  29   set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
  30   set(CMAKE_JAVA_COMPILE_FLAGS "-Xlint")
  31 endif()
  32
  33 if(enable_compile_optimizations)
  34   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
  35   if(CMAKE_COMPILER_IS_GNUCC AND (NOT enable_model-checking))
  36     set(optCFLAGS "${optCFLAGS} -finline-functions ")
  37     if(WIN32)
  38       if (COMPILER_C_VERSION_MAJOR_MINOR STRGREATER "4.8")
  39       # On windows, we need 4.8 or higher to enable lto because of http://gcc.gnu.org/bugzilla/show_bug.cgi?id=50293
  40       #
  41       # We are experiencing assertion failures even with 4.8 on MinGW.
  42       # Push the support forward: will see if 4.9 works when we test it.
  43       set(optCFLAGS "${optCFLAGS} -flto ")
  44       endif()
  45     else()
  46       # On non-windows, 4.6 is enough for that
  47       if(LINKER_VERSION STRGREATER "2.22")
  48         set(optCFLAGS "${optCFLAGS} -flto ")
  49       endif()
  50     endif()
  51   endif()
  52 else()
  53   set(optCFLAGS "-O0 ")
  54 endif()
  55
  56 if(enable_sdt)
  57   add_definitions(-DUSE_SDT)
  58 endif()
  59
  60 if(enable_ust)
  61   add_definitions(-DUSE_UST)
  62 endif()
  63
  64 if(enable_model-checking AND enable_compile_optimizations)
  65   # Forget it, do not optimize the code (because it confuses the MC):
  66   set(optCFLAGS "-O0 ")
  67   # But you can still optimize this:
  68   foreach(s
  69       src/xbt/mmalloc/mm.c
  70       src/xbt/log.c src/xbt/xbt_log_appender_file.c
  71       src/xbt/xbt_log_layout_format.c src/xbt/xbt_log_layout_simple.c
  72       src/xbt/dict.c src/xbt/dict_elm.c src/xbt/dict_multi.c src/xbt/dict_cursor.c
  73       src/xbt/set.c src/xbt/setset.c
  74       src/xbt/dynar.c src/xbt/fifo.c src/xbt/heap.c src/xbt/swag.c
  75       src/xbt/str.c src/xbt/strbuff.c src/xbt/snprintf.c
  76       src/xbt/queue.c
  77       src/xbt/xbt_os_time.c src/xbt/xbt_os_thread.c
  78       src/xbt/sha.c
  79       src/xbt/matrix.c
  80       src/xbt/backtrace_linux.c
  81       ${MC_SRC_BASE} ${MC_SRC})
  82       set (mcCFLAGS "-O3  -funroll-loops -fno-strict-aliasing")
  83        if(CMAKE_COMPILER_IS_GNUCC)
  84          set (mcCFLAGS "${mcCFLAGS} -finline-functions")
  85       endif()
  86       set_source_files_properties(${s} PROPERTIES COMPILE_FLAGS ${mcCFLAGS})
  87   endforeach()
  88 endif()
  89
  90 if(NOT enable_debug)
  91   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
  92   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
  93 endif()
  94
  95 if(enable_msg_deprecated)
  96   set(CMAKE_C_FLAGS "-DMSG_USE_DEPRECATED ${CMAKE_C_FLAGS}")
  97 endif()
  98
  99 set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   ${optCFLAGS} ${warnCFLAGS}")
 100 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${optCFLAGS}")
 101
 102 # Try to make Mac a bit more complient to open source standards
 103 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 104   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 105 endif()
 106
 107 set(TESH_OPTION "")
 108 if(enable_coverage)
 109   find_program(GCOV_PATH gcov)
 110   if(GCOV_PATH)
 111     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE TYPE FILEPATH FORCE)
 112     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE")
 113     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
 114     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
 115     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -fprofile-arcs -ftest-coverage")
 116     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
 117     set(TESH_OPTION --enable-coverage)
 118     add_definitions(-fprofile-arcs -ftest-coverage)
 119   endif()
 120 endif()
 121
 122 if(NOT $ENV{CFLAGS} STREQUAL "")
 123   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
 124   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
 125 endif()
 126
 127 if(NOT $ENV{CXXFLAGS} STREQUAL "")
 128   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
 129   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
 130 endif()
 131
 132 if(NOT $ENV{LDFLAGS} STREQUAL "")
 133   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
 134   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
 135 endif()