tools/cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 install(DIRECTORY "${CMAKE_BINARY_DIR}/doc/html/" DESTINATION ${CMAKE_INSTALL_DOCDIR}/html/ OPTIONAL)
   7
   8 # binaries
   9 if(enable_smpi)
  10   install(PROGRAMS
  11     ${CMAKE_BINARY_DIR}/bin/smpicc
  12     ${CMAKE_BINARY_DIR}/bin/smpicxx
  13     ${CMAKE_BINARY_DIR}/bin/smpirun
  14     DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  15   if(SMPI_FORTRAN)
  16     install(PROGRAMS
  17       ${CMAKE_BINARY_DIR}/bin/smpif90
  18       ${CMAKE_BINARY_DIR}/bin/smpiff
  19       DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  20     install(PROGRAMS
  21       ${CMAKE_BINARY_DIR}/include/smpi/mpi.mod
  22       DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/smpi/)
  23   endif()
  24 endif()
  25
  26 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  27
  28 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  29   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  30   RENAME simgrid_update_xml)
  31
  32 add_custom_target(simgrid_update_xml ALL
  33   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  34   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml)
  35
  36 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py
  37   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  38   RENAME simgrid_convert_TI_traces)
  39
  40 add_custom_target(simgrid_convert_TI_traces ALL
  41     COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces"
  42     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces)
  43
  44 # libraries
  45 install(TARGETS simgrid DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  46
  47 # pkg-config files
  48 configure_file("${CMAKE_HOME_DIRECTORY}/tools/pkg-config/simgrid.pc.in"
  49   "${PROJECT_BINARY_DIR}/simgrid.pc" @ONLY)
  50 install(FILES "${PROJECT_BINARY_DIR}/simgrid.pc" DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
  51
  52 # include files
  53 foreach(file ${headers_to_install} ${generated_headers_to_install})
  54   get_filename_component(location ${file} PATH)
  55   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  56   string(REGEX REPLACE "^include/" "" location "${location}")
  57   string(REGEX REPLACE "^include$" "" location "${location}")
  58   # message("installing '${file}' into '${CMAKE_INSTALL_INCLUDEDIR}/${location}'")
  59   install(FILES ${file} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${location})
  60 endforeach()
  61
  62 # example files
  63 foreach(file ${examples_to_install})
  64   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  65   get_filename_component(location ${file} PATH)
  66   # message("DOC installing 'examples/${file}' into '${CMAKE_INSTALL_DOCDIR}/examples/${location}'")
  67   install(FILES "examples/${file}"
  68     DESTINATION ${CMAKE_INSTALL_DOCDIR}/examples/${location})
  69 endforeach(file ${examples_to_install})
  70
  71 ################################################################
  72 ## Build a sane "make dist" target to build a source package ###
  73 ##    containing only the files that I explicitly state      ###
  74 ##   (instead of any cruft laying on my disk as CPack does)  ###
  75 ################################################################
  76
  77 # This is the complete list of what will be added to the source archive
  78 set(source_to_pack
  79   ${headers_to_install}
  80   ${source_of_generated_headers}
  81   ${MC_SRC_BASE}
  82   ${MC_SRC}
  83   ${MC_SIMGRID_MC_SRC}
  84   ${S4U_SRC}
  85   ${NS3_SRC}
  86   ${PLUGINS_SRC}
  87   ${DAG_SRC}
  88   ${SIMGRID_SRC}
  89   ${SMPI_SRC}
  90   ${KERNEL_SRC}
  91   ${TRACING_SRC}
  92   ${XBT_RL_SRC}
  93   ${XBT_SRC}
  94   ${STHREAD_SRC}
  95   ${EXTRA_DIST}
  96   ${CMAKE_SOURCE_FILES}
  97   ${CMAKEFILES_TXT}
  98   ${DOC_SOURCES}
  99   ${DOC_TOOLS}
 100   ${PLATFORMS_EXAMPLES}
 101   ${README_files}
 102   ${bin_files}
 103   ${examples_src}
 104   ${tesh_files}
 105   ${teshsuite_src}
 106   ${tools_src}
 107   ${txt_files}
 108   ${xml_files}
 109   )
 110 list(SORT source_to_pack)
 111 list(REMOVE_DUPLICATES source_to_pack)
 112
 113 ##########################################
 114 ### Fill in the "make dist-dir" target ###
 115 ##########################################
 116
 117 add_custom_target(dist-dir
 118   COMMENT "Generating the distribution directory"
 119   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 120   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 121   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 122   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 123   )
 124 add_dependencies(dist-dir maintainer_files)
 125
 126 set(dirs_in_tarball "")
 127 foreach(file ${source_to_pack})
 128   #message(${file})
 129   # This damn prefix is still set somewhere (seems to be in subdirs)
 130   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 131
 132   # Prepare the list of files to include in the python sdist, one per line
 133   set(PYTHON_SOURCES "${PYTHON_SOURCES}\ninclude ${file}")
 134
 135   # Create the directory on need
 136   get_filename_component(file_location ${file} PATH)
 137   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 138   if(NOT OPERATION)
 139     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 140     add_custom_command(
 141       TARGET dist-dir
 142       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/)
 143   endif()
 144
 145   # Actually copy the file
 146   add_custom_command(
 147     TARGET dist-dir
 148     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location})
 149 endforeach(file ${source_to_pack})
 150 configure_file("${CMAKE_HOME_DIRECTORY}/MANIFEST.in.in" "${CMAKE_BINARY_DIR}/MANIFEST.in" @ONLY IMMEDIATE)
 151 unset(PYTHON_SOURCES)
 152
 153
 154 add_custom_command(
 155   TARGET dist-dir
 156   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion)
 157
 158 ##########################################################
 159 ### Link all sources to the bindir if srcdir != bindir ###
 160 ##########################################################
 161 add_custom_target(hardlinks
 162    COMMENT "Making the source files available from the bindir"
 163 )
 164 if (NOT ${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
 165   foreach(file ${source_to_pack})
 166     #message(${file})
 167     # This damn prefix is still set somewhere (seems to be in subdirs)
 168     string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 169
 170     # Create the directory on need
 171     get_filename_component(file_location ${file} PATH)
 172     string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_bindir}")
 173     if(NOT OPERATION)
 174       set(dirs_in_tarball "${dirs_in_bindir};${file_location};")
 175       add_custom_command(
 176         TARGET hardlinks
 177         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/${file_location}/)
 178     endif()
 179
 180     # Actually copy the file
 181     add_custom_command(
 182       TARGET hardlinks
 183       COMMAND if test -f ${CMAKE_HOME_DIRECTORY}/${file} \; then rm -f ${CMAKE_BINARY_DIR}/${file}\; ln ${CMAKE_HOME_DIRECTORY}/${file} ${CMAKE_BINARY_DIR}/${file_location}\; fi
 184     )
 185   endforeach(file ${source_to_pack})
 186 endif()
 187
 188
 189 ######################################
 190 ### Fill in the "make dist" target ###
 191 ######################################
 192
 193 add_custom_target(dist
 194   COMMENT "Removing the distribution directory"
 195   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 196   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 197   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 198
 199 add_custom_command(
 200   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 201   COMMENT "Compressing the archive from the distribution directory"
 202   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 203   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 204   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 205 add_dependencies(dist dist-dir)
 206
 207 ###########################################
 208 ### Fill in the "make distcheck" target ###
 209 ###########################################
 210
 211 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 212
 213 # Allow to test the "make dist"
 214 add_custom_target(distcheck
 215   COMMAND ${CMAKE_COMMAND} -E echo "XXX Compare archive with git repository"
 216   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/internal/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 217
 218   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove old copy"
 219   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 220
 221   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 222   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 223
 224   COMMAND ${CMAKE_COMMAND} -E echo "XXX Create build and install subtrees"
 225   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 226   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 227
 228   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 229   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 230           ${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst -Denable_lto=OFF ..
 231
 232   COMMAND ${CMAKE_COMMAND} -E echo "XXX Check generated files -- please copy new version if they are different"
 233   COMMAND ${CMAKE_COMMAND} -E compare_files ${CMAKE_HOME_DIRECTORY}/MANIFEST.in ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build/MANIFEST.in
 234
 235   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 236   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4
 237
 238   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 239   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 240
 241   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build tests"
 242   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4 tests
 243
 244   COMMAND ${CMAKE_COMMAND} -E echo "XXX Run tests"
 245   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure -j 4
 246
 247   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 248   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 249   )
 250 add_dependencies(distcheck dist)
 251
 252 #######################################
 253 ### Fill in the "make check" target ###
 254 #######################################
 255
 256 if(enable_memcheck)
 257   add_custom_target(check COMMAND ctest -D ExperimentalMemCheck)
 258 else()
 259   add_custom_target(check COMMAND make test)
 260 endif()
 261 add_dependencies(check tests)
 262
 263 include(CPack)