tools/cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 install(DIRECTORY "${CMAKE_BINARY_DIR}/doc/html/" DESTINATION ${CMAKE_INSTALL_DOCDIR}/html/ OPTIONAL)
   7
   8 # binaries
   9 if(enable_smpi)
  10   install(PROGRAMS
  11     ${CMAKE_BINARY_DIR}/bin/smpicc
  12     ${CMAKE_BINARY_DIR}/bin/smpicxx
  13     ${CMAKE_BINARY_DIR}/bin/smpirun
  14     DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  15   if(SMPI_FORTRAN)
  16     install(PROGRAMS
  17       ${CMAKE_BINARY_DIR}/bin/smpif90
  18       ${CMAKE_BINARY_DIR}/bin/smpiff
  19       DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  20     install(PROGRAMS
  21       ${CMAKE_BINARY_DIR}/include/smpi/mpi.mod
  22       DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/smpi/)
  23   endif()
  24 endif()
  25
  26 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  27
  28 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  29   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  30   RENAME simgrid-colorizer)
  31
  32 add_custom_target(simgrid-colorizer ALL
  33   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  34   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize)
  35
  36 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  37   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  38   RENAME simgrid_update_xml)
  39
  40 add_custom_target(simgrid_update_xml ALL
  41   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  42   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml)
  43
  44 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py
  45   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  46   RENAME simgrid_convert_TI_traces)
  47
  48 add_custom_target(simgrid_convert_TI_traces ALL
  49     COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces"
  50     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces)
  51
  52 # libraries
  53 install(TARGETS simgrid DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  54
  55 if(enable_java)
  56   set(SIMGRID_JAR_TO_INSTALL "${SIMGRID_JAR}")
  57   install(TARGETS simgrid-java DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  58   install(FILES ${SIMGRID_JAR_TO_INSTALL}
  59       DESTINATION java/
  60       RENAME simgrid.jar)
  61 endif()
  62
  63 # pkg-config files
  64 configure_file("${CMAKE_HOME_DIRECTORY}/tools/pkg-config/simgrid.pc.in"
  65   "${PROJECT_BINARY_DIR}/simgrid.pc" @ONLY)
  66 install(FILES "${PROJECT_BINARY_DIR}/simgrid.pc" DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
  67
  68 # include files
  69 foreach(file ${headers_to_install} ${generated_headers_to_install})
  70   get_filename_component(location ${file} PATH)
  71   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  72   string(REGEX REPLACE "^include/" "" location "${location}")
  73   string(REGEX REPLACE "^include$" "" location "${location}")
  74   # message("installing '${file}' into '${CMAKE_INSTALL_INCLUDEDIR}/${location}'")
  75   install(FILES ${file} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${location})
  76 endforeach()
  77
  78 # example files
  79 foreach(file ${examples_to_install})
  80   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  81   get_filename_component(location ${file} PATH)
  82   # message("DOC installing 'examples/${file}' into '${CMAKE_INSTALL_DOCDIR}/examples/${location}'")
  83   install(FILES "examples/${file}"
  84     DESTINATION ${CMAKE_INSTALL_DOCDIR}/examples/${location})
  85 endforeach(file ${examples_to_install})
  86
  87 ################################################################
  88 ## Build a sane "make dist" target to build a source package ###
  89 ##    containing only the files that I explicitly state      ###
  90 ##   (instead of any cruft laying on my disk as CPack does)  ###
  91 ################################################################
  92
  93 # This is the complete list of what will be added to the source archive
  94 set(source_to_pack
  95   ${headers_to_install}
  96   ${source_of_generated_headers}
  97   ${JMSG_C_SRC}
  98   ${JMSG_JAVA_SRC}
  99   ${MC_SRC_BASE}
 100   ${MC_SRC}
 101   ${MC_SIMGRID_MC_SRC}
 102   ${MSG_SRC}
 103   ${S4U_SRC}
 104   ${NS3_SRC}
 105   ${PLUGINS_SRC}
 106   ${DAG_SRC}
 107   ${SIMGRID_SRC}
 108   ${SIMIX_SRC}
 109   ${SMPI_SRC}
 110   ${SURF_SRC}
 111   ${TRACING_SRC}
 112   ${XBT_RL_SRC}
 113   ${XBT_SRC}
 114   ${EXTRA_DIST}
 115   ${CMAKE_SOURCE_FILES}
 116   ${CMAKEFILES_TXT}
 117   ${DOC_IMG}
 118   ${DOC_SOURCES}
 119   ${DOC_TOOLS}
 120   ${PLATFORMS_EXAMPLES}
 121   ${README_files}
 122   ${bin_files}
 123   ${examples_src}
 124   ${tesh_files}
 125   ${teshsuite_src}
 126   ${tools_src}
 127   ${txt_files}
 128   ${xml_files}
 129   )
 130 list(SORT source_to_pack)
 131 list(REMOVE_DUPLICATES source_to_pack)
 132
 133 ##########################################
 134 ### Fill in the "make dist-dir" target ###
 135 ##########################################
 136
 137 add_custom_target(dist-dir
 138   COMMENT "Generating the distribution directory"
 139   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 140   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 141   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 142   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 143   )
 144 add_dependencies(dist-dir maintainer_files)
 145
 146 set(dirs_in_tarball "")
 147 foreach(file ${source_to_pack})
 148   #message(${file})
 149   # This damn prefix is still set somewhere (seems to be in subdirs)
 150   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 151
 152   # Prepare the list of files to include in the python sdist, one per line
 153   set(PYTHON_SOURCES "${PYTHON_SOURCES}\ninclude ${file}")
 154
 155   # Create the directory on need
 156   get_filename_component(file_location ${file} PATH)
 157   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 158   if(NOT OPERATION)
 159     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 160     add_custom_command(
 161       TARGET dist-dir
 162       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/)
 163   endif()
 164
 165   # Actually copy the file
 166   add_custom_command(
 167     TARGET dist-dir
 168     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location})
 169 endforeach(file ${source_to_pack})
 170 configure_file("${CMAKE_HOME_DIRECTORY}/MANIFEST.in.in" "${CMAKE_BINARY_DIR}/MANIFEST.in" @ONLY IMMEDIATE)
 171 unset(PYTHON_SOURCES)
 172
 173
 174 add_custom_command(
 175   TARGET dist-dir
 176   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion)
 177
 178 ##########################################################
 179 ### Link all sources to the bindir if srcdir != bindir ###
 180 ##########################################################
 181 add_custom_target(hardlinks
 182    COMMENT "Making the source files available from the bindir"
 183 )
 184 if (NOT ${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
 185   foreach(file ${source_to_pack})
 186     #message(${file})
 187     # This damn prefix is still set somewhere (seems to be in subdirs)
 188     string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 189
 190     # Create the directory on need
 191     get_filename_component(file_location ${file} PATH)
 192     string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_bindir}")
 193     if(NOT OPERATION)
 194       set(dirs_in_tarball "${dirs_in_bindir};${file_location};")
 195       add_custom_command(
 196         TARGET hardlinks
 197         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/${file_location}/)
 198     endif()
 199
 200     # Actually copy the file
 201     add_custom_command(
 202       TARGET hardlinks
 203       COMMAND if test -f ${CMAKE_HOME_DIRECTORY}/${file} \; then rm -f ${CMAKE_BINARY_DIR}/${file}\; ln ${CMAKE_HOME_DIRECTORY}/${file} ${CMAKE_BINARY_DIR}/${file_location}\; fi
 204     )
 205   endforeach(file ${source_to_pack})
 206 endif()
 207
 208
 209 ######################################
 210 ### Fill in the "make dist" target ###
 211 ######################################
 212
 213 add_custom_target(dist
 214   COMMENT "Removing the distribution directory"
 215   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 216   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 217   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 218
 219 add_custom_command(
 220   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 221   COMMENT "Compressing the archive from the distribution directory"
 222   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 223   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 224   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 225 add_dependencies(dist dist-dir)
 226
 227 if(NOT enable_maintainer_mode)
 228   add_custom_target(echo-dist
 229     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 230     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 231     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------")
 232   add_dependencies(dist echo-dist)
 233 endif()
 234
 235 ###########################################
 236 ### Fill in the "make distcheck" target ###
 237 ###########################################
 238
 239 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 240
 241 # Allow to test the "make dist"
 242 add_custom_target(distcheck
 243   COMMAND ${CMAKE_COMMAND} -E echo "XXX Compare archive with git repository"
 244   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/internal/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 245
 246   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove old copy"
 247   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 248
 249   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 250   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 251
 252   COMMAND ${CMAKE_COMMAND} -E echo "XXX Create build and install subtrees"
 253   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 254   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 255
 256   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 257   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 258           ${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst -Denable_lto=OFF ..
 259
 260   COMMAND ${CMAKE_COMMAND} -E echo "XXX Check generated files -- please copy new version if they are different"
 261   COMMAND ${CMAKE_COMMAND} -E compare_files ${CMAKE_HOME_DIRECTORY}/MANIFEST.in ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build/MANIFEST.in
 262
 263   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 264   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4
 265
 266   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 267   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 268
 269   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build tests"
 270   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4 tests
 271
 272   COMMAND ${CMAKE_COMMAND} -E echo "XXX Run tests"
 273   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure -j 4
 274
 275   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 276   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 277   )
 278 add_dependencies(distcheck dist)
 279
 280 #######################################
 281 ### Fill in the "make check" target ###
 282 #######################################
 283
 284 if(enable_memcheck)
 285   add_custom_target(check COMMAND ctest -D ExperimentalMemCheck)
 286 else()
 287   add_custom_target(check COMMAND make test)
 288 endif()
 289 add_dependencies(check tests)
 290
 291 include(CPack)