tools/cmake/Tests.cmake

   1 IF(enable_smpi AND NOT WIN32)
   2   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpicc)
   3   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpicxx)
   4   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpiff)
   5   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpif90)
   6   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpirun)
   7 ENDIF()
   8
   9 SET(TESH_OPTION "--ignore-jenkins")
  10 SET(TESH_COMMAND "${PYTHON_EXECUTABLE}" ${CMAKE_BINARY_DIR}/bin/tesh)
  11
  12 SET(TESH_LIBRARY_PATH "${CMAKE_BINARY_DIR}/lib")
  13 if(NOT $ENV{LD_LIBRARY_PATH} STREQUAL "")
  14   SET(TESH_LIBRARY_PATH "${TESH_LIBRARY_PATH}:$ENV{LD_LIBRARY_PATH}")
  15 endif()
  16
  17 IF(enable_memcheck)
  18   INCLUDE(FindValgrind)
  19
  20   if (NOT VALGRIND_EXE MATCHES "NOTFOUND")
  21     execute_process(COMMAND ${VALGRIND_EXE} --version  OUTPUT_VARIABLE "VALGRIND_VERSION")
  22     message(STATUS "Valgrind version: ${VALGRIND_VERSION}")
  23
  24     set(TESH_WRAPPER ${CMAKE_HOME_DIRECTORY}/tools/cmake/scripts/my_valgrind.pl)
  25     set(TESH_WRAPPER ${TESH_WRAPPER}\ --trace-children=yes\ --trace-children-skip=/usr/bin/*,/bin/*\ --leak-check=full\ --show-reachable=yes\ --track-origins=no\ --read-var-info=no\ --num-callers=20\ --suppressions=${CMAKE_HOME_DIRECTORY}/tools/simgrid.supp\ )
  26     if(enable_memcheck_xml)
  27       SET(TESH_WRAPPER ${TESH_WRAPPER}\ --xml=yes\ --xml-file=memcheck_test_%p.memcheck\ --child-silent-after-fork=yes\ )
  28     endif()
  29     set(TESH_OPTION ${TESH_OPTION} --setenv VALGRIND_NO_LEAK_CHECK=--leak-check=no\ --show-leak-kinds=none)
  30
  31 #    message(STATUS "tesh wrapper: ${TESH_WRAPPER}")
  32
  33     mark_as_advanced(TESH_WRAPPER)
  34   else()
  35     set(enable_memcheck false)
  36     message(STATUS "Error: Command valgrind not found --> enable_memcheck autoset to false.")
  37   endif()
  38 ENDIF()
  39 SET(TESH_WRAPPER_UNBOXED "${TESH_WRAPPER}")
  40 SEPARATE_ARGUMENTS(TESH_WRAPPER_UNBOXED)
  41
  42 #some tests may take forever on non futexes systems, using busy_wait with n cores < n workers
  43 # default to posix for these tests if futexes are not supported
  44 IF(NOT HAVE_FUTEX_H)
  45   SET(CONTEXTS_SYNCHRO --cfg contexts/synchro:posix)
  46 ENDIF()
  47
  48 MACRO(ADD_TESH NAME)
  49   SET(ARGT ${ARGV})
  50   LIST(REMOVE_AT ARGT 0)
  51   IF(WIN32)
  52     STRING(REPLACE "§" "\;" ARGT "${ARGT}")
  53   ENDIF()
  54   if(TESH_WRAPPER)
  55     ADD_TEST(${NAME} ${TESH_COMMAND} --wrapper "${TESH_WRAPPER}" ${TESH_OPTION} ${ARGT})
  56   else()
  57     ADD_TEST(${NAME} ${TESH_COMMAND} ${TESH_OPTION} ${ARGT})
  58   endif()
  59 ENDMACRO()
  60
  61 MACRO(ADD_TESH_FACTORIES NAME FACTORIES)
  62   SET(ARGR ${ARGV})
  63   LIST(REMOVE_AT ARGR 0) # remove name
  64   FOREACH(I ${FACTORIES}) # remove all factories
  65     LIST(REMOVE_AT ARGR 0)
  66   ENDFOREACH()
  67   FOREACH(FACTORY ${FACTORIES})
  68     if ((${FACTORY} STREQUAL "thread" ) OR # Always available, thanks to C++11 threads
  69         (${FACTORY} STREQUAL "boost" AND HAVE_BOOST_CONTEXTS) OR
  70         (${FACTORY} STREQUAL "raw" AND HAVE_RAW_CONTEXTS) OR
  71         (${FACTORY} STREQUAL "ucontext" AND HAVE_UCONTEXT_CONTEXTS))
  72       ADD_TESH("${NAME}-${FACTORY}" "--cfg" "contexts/factory:${FACTORY}" ${ARGR})
  73     ENDIF()
  74   ENDFOREACH()
  75 ENDMACRO()
  76
  77 MACRO(SET_TESH_PROPERTIES NAME FACTORIES)
  78   SET(ARGR ${ARGV})
  79   LIST(REMOVE_AT ARGR 0) # remove name
  80   FOREACH(I ${FACTORIES}) # remove all factories
  81     LIST(REMOVE_AT ARGR 0)
  82   ENDFOREACH()
  83   FOREACH(FACTORY ${FACTORIES})
  84     if ((${FACTORY} STREQUAL "thread" ) OR # Always available, thanks to C++11 threads
  85         (${FACTORY} STREQUAL "boost" AND HAVE_BOOST_CONTEXTS) OR
  86         (${FACTORY} STREQUAL "raw" AND HAVE_RAW_CONTEXTS) OR
  87         (${FACTORY} STREQUAL "ucontext" AND HAVE_UCONTEXT_CONTEXTS))
  88       set_tests_properties("${NAME}-${FACTORY}" PROPERTIES ${ARGR})
  89     endif()
  90   ENDFOREACH()
  91 ENDMACRO()
  92
  93 IF(enable_java)
  94   IF(WIN32)
  95     SET(TESH_CLASSPATH "${CMAKE_BINARY_DIR}/examples/deprecated/java/\;${CMAKE_BINARY_DIR}/teshsuite/java/\;${SIMGRID_JAR}")
  96     STRING(REPLACE "\;" "§" TESH_CLASSPATH "${TESH_CLASSPATH}")
  97   ELSE()
  98     SET(TESH_CLASSPATH "${CMAKE_BINARY_DIR}/examples/deprecated/java/:${CMAKE_BINARY_DIR}/teshsuite/java/:${SIMGRID_JAR}")
  99   ENDIF()
 100 ENDIF()
 101
 102 # New tests should use the Catch Framework
 103 set(UNIT_TESTS  src/xbt/unit-tests_main.cpp
 104                 src/kernel/resource/profile/Profile_test.cpp
 105                 src/xbt/config_test.cpp
 106                 src/xbt/dict_test.cpp
 107                 src/xbt/dynar_test.cpp
 108                 src/xbt/random_test.cpp
 109                 src/xbt/xbt_str_test.cpp
 110                 src/kernel/lmm/maxmin_test.cpp)
 111 if (SIMGRID_HAVE_MC)
 112   set(UNIT_TESTS ${UNIT_TESTS} src/mc/sosp/Snapshot_test.cpp src/mc/sosp/PageStore_test.cpp)
 113 else()
 114   set(EXTRA_DIST ${EXTRA_DIST} src/mc/sosp/Snapshot_test.cpp src/mc/sosp/PageStore_test.cpp)
 115 endif()
 116
 117 add_executable       (unit-tests EXCLUDE_FROM_ALL ${UNIT_TESTS})
 118 add_dependencies     (tests unit-tests)
 119 target_link_libraries(unit-tests simgrid)
 120 ADD_TEST(unit-tests ${CMAKE_BINARY_DIR}/unit-tests)
 121 set_property(TARGET unit-tests APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}")
 122 add_dependencies(tests unit-tests)
 123 set(EXTRA_DIST ${EXTRA_DIST} ${UNIT_TESTS})
 124
 125 unset(UNIT_TESTS)