examples/s4u/CMakeLists.txt

   1
   2 # Regular examples: with only one source and tested with all factories by default
   3 #################################################################################
   4 ### Define the examples' specificities
   5
   6 set(_app-bittorrent_sources app-bittorrent/s4u-bittorrent.cpp app-bittorrent/s4u-bittorrent.hpp
   7                             app-bittorrent/s4u-peer.cpp app-bittorrent/s4u-peer.hpp
   8                             app-bittorrent/s4u-tracker.cpp app-bittorrent/s4u-tracker.hpp)
   9 set(_dht-chord_sources    dht-chord/s4u-dht-chord.cpp dht-chord/s4u-dht-chord.hpp dht-chord/s4u-dht-chord-node.cpp)
  10 set(_dht-kademlia_sources dht-kademlia/s4u-dht-kademlia.cpp dht-kademlia/s4u-dht-kademlia.hpp
  11                           dht-kademlia/node.cpp dht-kademlia/node.hpp
  12                           dht-kademlia/routing_table.cpp dht-kademlia/routing_table.hpp
  13                           dht-kademlia/answer.cpp dht-kademlia/answer.hpp dht-kademlia/message.hpp)
  14
  15 set(_actor-stacksize_factories "raw;boost;ucontext") # Threads ignore modifications of the stack size
  16
  17 # The maestro-set example only works for threads and when not using windows.
  18 set(_maestro-set_factories "thread")
  19 if(WIN32)
  20   set(_maestro-set_disable 1)
  21 endif()
  22
  23 foreach (example mc-bugged1 mc-bugged2 mc-failing-assert mc-electric-fence)
  24   if(NOT SIMGRID_HAVE_MC)
  25     set(_${example}_disable 1)
  26   endif()
  27   set(_${example}_factories "ucontext;raw;boost")
  28 endforeach()
  29
  30 set(_mc-bugged1-liveness_disable 1)
  31 if(SIMGRID_HAVE_MC)
  32    add_executable       (s4u-mc-bugged1-liveness  EXCLUDE_FROM_ALL mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  33    target_link_libraries(s4u-mc-bugged1-liveness  simgrid)
  34    set_target_properties(s4u-mc-bugged1-liveness PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness)
  35    add_dependencies(tests s4u-mc-bugged1-liveness)
  36    set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  37    set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.tesh)
  38
  39   if(HAVE_C_STACK_CLEANER)
  40     add_executable       (s4u-mc-bugged1-liveness-cleaner-on  EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  41     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-on  simgrid)
  42     set_target_properties(s4u-mc-bugged1-liveness-cleaner-on  PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fstack-cleaner")
  43     add_dependencies(tests s4u-mc-bugged1-liveness-cleaner-on)
  44
  45     add_executable       (s4u-mc-bugged1-liveness-cleaner-off EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  46     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-off simgrid)
  47     set_target_properties(s4u-mc-bugged1-liveness-cleaner-off PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fno-stack-cleaner")
  48     add_dependencies(tests s4u-mc-bugged1-liveness-cleaner-off)
  49   endif()
  50 endif()
  51
  52 if(SIMGRID_HAVE_NS3)
  53   add_executable       (s4u-network-ns3 EXCLUDE_FROM_ALL network-ns3/s4u-network-ns3.cpp)
  54   target_link_libraries(s4u-network-ns3 simgrid)
  55   set_target_properties(s4u-network-ns3  PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/network-ns3)
  56   add_dependencies(tests s4u-network-ns3)
  57 endif()
  58
  59 # Deal with each example
  60
  61 foreach (example actor-create actor-daemon actor-exiting actor-join actor-kill
  62                  actor-lifetime actor-migrate actor-suspend actor-yield actor-stacksize
  63                  app-bittorrent app-chainsend app-pingpong app-token-ring
  64                  comm-ready comm-suspend comm-wait comm-waitany comm-waitall comm-waituntil
  65                  comm-dependent
  66                  cloud-capping cloud-migration cloud-simple
  67                  dht-chord dht-kademlia
  68                  energy-exec energy-boot energy-link energy-vm energy-exec-ptask energy-wifi
  69                  engine-filtering
  70                  exec-async exec-basic exec-dvfs exec-ptask exec-remote exec-waitany exec-waitfor exec-dependent
  71                  maestro-set
  72                  mc-bugged1 mc-bugged1-liveness mc-bugged2 mc-electric-fence mc-failing-assert
  73                  network-wifi
  74                  io-async io-file-system io-file-remote io-disk-raw io-dependent
  75                  platform-failures platform-profile platform-properties
  76                  plugin-host-load plugin-link-load
  77                  replay-comm replay-io
  78                  routing-get-clusters
  79                  synchro-barrier synchro-condition-variable synchro-condition-variable-waituntil synchro-mutex synchro-semaphore)
  80
  81   # Use default source file unless specified otherwise
  82   if(NOT DEFINED _${example}_sources)
  83     set(_${example}_sources ${example}/s4u-${example}.cpp)
  84   endif()
  85
  86   if(NOT DEFINED _${example}_disable)
  87     add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${_${example}_sources})
  88     add_dependencies     (tests s4u-${example})
  89     target_link_libraries(s4u-${example} simgrid)
  90     set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
  91
  92     # Use default factories unless specified otherwise
  93     if(NOT DEFINED _${example}_factories)
  94       set(_${example}_factories "thread;ucontext;raw;boost")
  95     endif()
  96 #    message("Factories of ${example}: ${_${example}_factories}")
  97
  98     ADD_TESH_FACTORIES(s4u-${example} "${_${example}_factories}"
  99                                       --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 100                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 101                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 102                                       ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 103   else()
 104     message(STATUS "Example ${example} disabled, thus not compiled.")
 105     unset(_${example}_disabled)
 106   endif()
 107
 108   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 109   foreach(file ${_${example}_sources})
 110     set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/${file})
 111   endforeach()
 112
 113   unset(_${example}_factories)
 114   unset(_${example}_sources)
 115 endforeach()
 116
 117
 118 # Specific examples
 119 ###################
 120
 121 # MASTERWORKERS EXAMPLE
 122 foreach(variant fun class)
 123   add_executable       (s4u-app-masterworkers-${variant} EXCLUDE_FROM_ALL app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 124   target_link_libraries(s4u-app-masterworkers-${variant} simgrid)
 125   set_target_properties(s4u-app-masterworkers-${variant} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-masterworkers)
 126   add_dependencies(tests s4u-app-masterworkers-${variant})
 127
 128   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 129 endforeach()
 130 set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers.tesh)
 131
 132 # Model-checking liveness
 133 if(SIMGRID_HAVE_MC)
 134   IF(HAVE_UCONTEXT_CONTEXTS AND SIMGRID_PROCESSOR_x86_64) # liveness model-checking works only on 64bits (for now ...)
 135     ADD_TESH(s4u-mc-bugged1-liveness-ucontext     --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness
 136                                                   --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 137                                                   --cd ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness
 138                                                   ${CMAKE_HOME_DIRECTORY}/examples/s4u/mc-bugged1-liveness/s4u-mc-bugged1-liveness.tesh)
 139
 140 # This example hit the 5' timeout on CI, disable it for now
 141 #    ADD_TESH(s4u-mc-bugged1-liveness-visited-ucontext --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness
 142 #                                                      --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 143 #                                                      --cd ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness
 144 #                                                       ${CMAKE_HOME_DIRECTORY}/examples/s4u/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh)
 145     IF(HAVE_C_STACK_CLEANER)
 146       # This test checks if the stack cleaner is making a difference:
 147       ADD_TEST(s4u-mc-bugged1-liveness-stack-cleaner ${CMAKE_HOME_DIRECTORY}/examples/s4u/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
 148                                                      ${CMAKE_HOME_DIRECTORY}/examples/s4u/mc-bugged1-liveness/
 149                                                      ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/)
 150     ENDIF()
 151   ENDIF()
 152
 153 #  if (enable_coverage)
 154 #    SET_TESTS_PROPERTIES(mc-bugged1-liveness-visited-ucontext PROPERTIES RUN_SERIAL "TRUE")
 155 #  endif()
 156 ENDIF()
 157
 158 # The tests the parallel variant of of DHTs
 159
 160 if(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_PROCESSOR STREQUAL "i386" AND CMAKE_SIZEOF_VOID_P EQUAL 8)
 161   # Thread-local storage (TLS) is needed for parallel execution, but it doesn't
 162   # play well with Ucontexts on 64bit SunOS (at least on x86_64).
 163   set(parallel-factories "thread;raw;boost")
 164 else()
 165   set(parallel-factories "thread;ucontext;raw;boost")
 166 endif()
 167
 168 foreach(example app-bittorrent app-masterworkers
 169                 dht-chord dht-kademlia
 170                 )
 171   ADD_TESH_FACTORIES(s4u-${example}-parallel "${parallel-factories}" --cfg contexts/nthreads:4 ${CONTEXTS_SYNCHRO}
 172                                              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 173                                              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 174                                              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 175                                              ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 176 endforeach()
 177
 178 # ns3-tests
 179 if(SIMGRID_HAVE_NS3)
 180   ADD_TESH_FACTORIES(s4u-network-ns3 "thread;ucontext;raw;boost"
 181                                      --setenv srcdir=${CMAKE_HOME_DIRECTORY}/examples/s4u
 182                                      --setenv bindir=${CMAKE_BINARY_DIR}/examples/s4u
 183                                      --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 184                                      ${CMAKE_HOME_DIRECTORY}/examples/s4u/network-ns3/s4u-network-ns3.tesh)
 185 endif()
 186 # Examples not accepting factories
 187 ##################################
 188
 189 foreach (example trace-categories trace-host-user-variables trace-link-user-variables trace-platform)
 190   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 191   target_link_libraries(s4u-${example} simgrid)
 192   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 193   add_dependencies(tests s4u-${example})
 194
 195   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 196   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 197
 198   ADD_TESH(s4u-${example} --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 199                           --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 200                           --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 201                           --cd ${CMAKE_CURRENT_BINARY_DIR}/${example}
 202                           ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 203 endforeach()
 204
 205 if (NOT enable_memcheck AND NOT WIN32)
 206   ADD_TESH(simix-breakpoint --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/app-pingpong
 207                             --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 208                             ${CMAKE_CURRENT_SOURCE_DIR}/app-pingpong/simix-breakpoint.tesh)
 209 endif()
 210
 211 if(enable_coverage)
 212   foreach (example mc-bugged1 mc-bugged2 mc-electric-fence mc-failing-assert)
 213     if(NOT DEFINED _${example}_disable)
 214       ADD_TEST(cover-${example} ${CMAKE_CURRENT_BINARY_DIR}/${example}/s4u-${example} ${CMAKE_HOME_DIRECTORY}/examples/platforms/model_checker_platform.xml)
 215     endif()
 216   endforeach()
 217   if(SIMGRID_HAVE_MC)
 218     ADD_TEST(cover-mc-bugged1-liveness ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness ${CMAKE_HOME_DIRECTORY}/examples/platforms/small_platform.xml 1 1001)
 219   endif()
 220 endif()
 221
 222 # Add all extra files to the archive
 223 ####################################
 224
 225 set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/s4u-network-ns3.cpp              PARENT_SCOPE)
 226 set(tesh_files    ${tesh_files}   ${CMAKE_CURRENT_SOURCE_DIR}/app-pingpong/simix-breakpoint.tesh
 227                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh
 228                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/s4u-network-ns3.tesh             PARENT_SCOPE)
 229 set(xml_files     ${xml_files}    ${CMAKE_CURRENT_SOURCE_DIR}/actor-create/s4u-actor-create_d.xml
 230                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-lifetime/s4u-actor-lifetime_d.xml
 231                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-yield/s4u-actor-yield_d.xml
 232                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent_d.xml
 233                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers_d.xml
 234                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-suspend/s4u-comm-suspend_d.xml
 235                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-wait/s4u-comm-wait_d.xml
 236                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-waitany/s4u-comm-waitany_d.xml
 237                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-waitall/s4u-comm-waitall_d.xml
 238                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-ready/s4u-comm-ready_d.xml
 239                                   ${CMAKE_CURRENT_SOURCE_DIR}/comm-waituntil/s4u-comm-waituntil_d.xml
 240                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord_d.xml
 241                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia_d.xml
 242                                   ${CMAKE_CURRENT_SOURCE_DIR}/energy-boot/platform_boot.xml
 243                                   ${CMAKE_CURRENT_SOURCE_DIR}/io-file-remote/s4u-io-file-remote_d.xml
 244                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-properties/s4u-platform-properties_d.xml
 245                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-failures/s4u-platform-failures_d.xml
 246                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split_d.xml
 247                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm_d.xml
 248                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io_d.xml
 249                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3hosts_2links_d.xml
 250                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links-timer_d.xml
 251                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links_d.xml
 252                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/crosstraffic_d.xml
 253                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/dogbone_d.xml
 254                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/onelink_d.xml
 255                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/one_cluster_d.xml                PARENT_SCOPE)
 256 set(bin_files     ${bin_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/generate.py
 257                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
 258                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/promela_bugged1_liveness PARENT_SCOPE)
 259 set(txt_files     ${txt_files}    ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p0.txt
 260                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p1.txt
 261                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm.txt
 262                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io.txt                  PARENT_SCOPE)
 263