tools/cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 install(DIRECTORY "${CMAKE_BINARY_DIR}/doc/html/" DESTINATION ${CMAKE_INSTALL_DOCDIR}/html/ OPTIONAL)
   7
   8 # binaries
   9 if(enable_smpi)
  10   install(PROGRAMS
  11     ${CMAKE_BINARY_DIR}/bin/smpicc
  12     ${CMAKE_BINARY_DIR}/bin/smpicxx
  13     ${CMAKE_BINARY_DIR}/bin/smpirun
  14     DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  15   if(SMPI_FORTRAN)
  16     install(PROGRAMS
  17       ${CMAKE_BINARY_DIR}/bin/smpif90
  18       ${CMAKE_BINARY_DIR}/bin/smpiff
  19       DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  20     install(PROGRAMS
  21       ${CMAKE_BINARY_DIR}/include/smpi/mpi.mod
  22       DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/smpi/)
  23   endif()
  24 endif()
  25
  26 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  27
  28 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  29   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  30   RENAME simgrid-colorizer)
  31
  32 add_custom_target(simgrid-colorizer ALL
  33   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  34   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize)
  35
  36 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  37   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  38   RENAME simgrid_update_xml)
  39
  40 add_custom_target(simgrid_update_xml ALL
  41   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  42   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml)
  43
  44 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py
  45   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  46   RENAME simgrid_convert_TI_traces)
  47
  48 add_custom_target(simgrid_convert_TI_traces ALL
  49     COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces"
  50     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces)
  51
  52 # libraries
  53 install(TARGETS simgrid DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  54
  55 if(enable_java)
  56   set(SIMGRID_JAR_TO_INSTALL "${SIMGRID_JAR}")
  57   install(TARGETS simgrid-java DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  58   install(FILES ${SIMGRID_JAR_TO_INSTALL}
  59       DESTINATION java/
  60       RENAME simgrid.jar)
  61 endif()
  62
  63 # pkg-config files
  64 configure_file("${CMAKE_HOME_DIRECTORY}/tools/pkg-config/simgrid.pc.in"
  65   "${PROJECT_BINARY_DIR}/simgrid.pc" @ONLY)
  66 install(FILES "${PROJECT_BINARY_DIR}/simgrid.pc" DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
  67
  68 # include files
  69 foreach(file ${headers_to_install} ${generated_headers_to_install})
  70   get_filename_component(location ${file} PATH)
  71   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  72   string(REGEX REPLACE "^include/" "" location "${location}")
  73   string(REGEX REPLACE "^include$" "" location "${location}")
  74   # message("installing '${file}' into '${CMAKE_INSTALL_INCLUDEDIR}/${location}'")
  75   install(FILES ${file} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${location})
  76 endforeach()
  77
  78 # example files
  79 foreach(file ${examples_to_install})
  80   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  81   get_filename_component(location ${file} PATH)
  82   # message("DOC installing 'examples/${file}' into '${CMAKE_INSTALL_DOCDIR}/examples/${location}'")
  83   install(FILES "examples/${file}"
  84     DESTINATION ${CMAKE_INSTALL_DOCDIR}/examples/${location})
  85 endforeach(file ${examples_to_install})
  86
  87 ###########################################
  88 ### Fill in the "make uninstall" target ###
  89 ###########################################
  90
  91 add_custom_target(uninstall
  92   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/doc/simgrid
  93   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall doc ok"
  94   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsimgrid*
  95   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid*
  96   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall lib ok"
  97   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicc
  98   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicxx
  99   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpiff
 100   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif90
 101   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpirun
 102   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/tesh
 103   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid-colorizer
 104   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid_update_xml
 105   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid_convert_TI_traces
 106   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/graphicator
 107   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall bin ok"
 108   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/instr
 109   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/msg
 110   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simdag
 111   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/smpi
 112   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simix
 113   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/surf
 114   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/xbt
 115   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/mc
 116   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simgrid
 117   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid.h
 118   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid/config.h
 119   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/xbt.h
 120   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall include ok"
 121   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/simgrid_update_xml.1
 122   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/tesh.1
 123   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpicc.1
 124   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpicxx.1
 125   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpirun.1
 126   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpiff.1
 127   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpif90.1
 128
 129
 130   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall man ok"
 131   WORKING_DIRECTORY "${CMAKE_INSTALL_PREFIX}")
 132
 133 if(SIMGRID_HAVE_LUA)
 134   add_custom_command(TARGET uninstall
 135     COMMAND ${CMAKE_COMMAND} -E echo "uninstall binding lua ok"
 136     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid.${LIB_EXE}
 137     WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}/")
 138 endif()
 139
 140 ################################################################
 141 ## Build a sain "make dist" target to build a source package ###
 142 ##    containing only the files that I explicitly state      ###
 143 ##   (instead of any cruft laying on my disk as CPack does)  ###
 144 ################################################################
 145
 146 # This is the complete list of what will be added to the source archive
 147 set(source_to_pack
 148   ${headers_to_install}
 149   ${source_of_generated_headers}
 150   ${BINDINGS_SRC}
 151   ${JEDULE_SRC}
 152   ${JMSG_C_SRC}
 153   ${JMSG_JAVA_SRC}
 154   ${LUA_SRC}
 155   ${MC_SRC_BASE}
 156   ${MC_SRC}
 157   ${MC_SIMGRID_MC_SRC}
 158   ${MSG_SRC}
 159   ${S4U_SRC}
 160   ${NS3_SRC}
 161   ${PLUGINS_SRC}
 162   ${SIMDAG_SRC}
 163   ${SIMGRID_SRC}
 164   ${SIMIX_SRC}
 165   ${SMPI_SRC}
 166   ${SURF_SRC}
 167   ${TRACING_SRC}
 168   ${XBT_RL_SRC}
 169   ${XBT_SRC}
 170   ${EXTRA_DIST}
 171   ${CMAKE_SOURCE_FILES}
 172   ${CMAKEFILES_TXT}
 173   ${DOC_IMG}
 174   ${DOC_SOURCES}
 175   ${DOC_TOOLS}
 176   ${PLATFORMS_EXAMPLES}
 177   ${README_files}
 178   ${bin_files}
 179   ${examples_src}
 180   ${tesh_files}
 181   ${teshsuite_src}
 182   ${tools_src}
 183   ${txt_files}
 184   ${xml_files}
 185   )
 186 list(SORT source_to_pack)
 187 list(REMOVE_DUPLICATES source_to_pack)
 188
 189 ##########################################
 190 ### Fill in the "make dist-dir" target ###
 191 ##########################################
 192
 193 add_custom_target(dist-dir
 194   COMMENT "Generating the distribution directory"
 195   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 196   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 197   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 198   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 199   )
 200 add_dependencies(dist-dir maintainer_files)
 201
 202 set(dirs_in_tarball "")
 203 set(PYTHON_SOURCES "include MANIFEST.in")
 204 foreach(file ${source_to_pack})
 205   #message(${file})
 206   # This damn prefix is still set somewhere (seems to be in subdirs)
 207   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 208
 209   # Prepare the list of files to include in the python sdist, one per line
 210   set(PYTHON_SOURCES "${PYTHON_SOURCES}\ninclude ${file}")
 211
 212   # Create the directory on need
 213   get_filename_component(file_location ${file} PATH)
 214   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 215   if(NOT OPERATION)
 216     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 217     add_custom_command(
 218       TARGET dist-dir
 219       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/)
 220   endif()
 221
 222   # Actually copy the file
 223   add_custom_command(
 224     TARGET dist-dir
 225     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location})
 226 endforeach(file ${source_to_pack})
 227 configure_file("${CMAKE_HOME_DIRECTORY}/MANIFEST.in.in" "${CMAKE_BINARY_DIR}/MANIFEST.in" @ONLY IMMEDIATE)
 228 unset(PYTHON_SOURCES)
 229
 230
 231 add_custom_command(
 232   TARGET dist-dir
 233   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion)
 234
 235 ##########################################################
 236 ### Link all sources to the bindir if srcdir != bindir ###
 237 ##########################################################
 238 add_custom_target(hardlinks
 239    COMMENT "Making the source files available from the bindir"
 240 )
 241 if (NOT ${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
 242   foreach(file ${source_to_pack})
 243     #message(${file})
 244     # This damn prefix is still set somewhere (seems to be in subdirs)
 245     string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 246
 247     # Create the directory on need
 248     get_filename_component(file_location ${file} PATH)
 249     string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_bindir}")
 250     if(NOT OPERATION)
 251       set(dirs_in_tarball "${dirs_in_bindir};${file_location};")
 252       add_custom_command(
 253         TARGET hardlinks
 254         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/${file_location}/)
 255     endif()
 256
 257     # Actually copy the file
 258     add_custom_command(
 259       TARGET hardlinks
 260       COMMAND if test -f ${CMAKE_HOME_DIRECTORY}/${file} \; then rm -f ${CMAKE_BINARY_DIR}/${file}\; ln ${CMAKE_HOME_DIRECTORY}/${file} ${CMAKE_BINARY_DIR}/${file_location}\; fi
 261     )
 262   endforeach(file ${source_to_pack})
 263 endif()
 264
 265
 266 ######################################
 267 ### Fill in the "make dist" target ###
 268 ######################################
 269
 270 add_custom_target(dist
 271   COMMENT "Removing the distribution directory"
 272   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 273   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 274   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 275
 276 add_custom_command(
 277   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 278   COMMENT "Compressing the archive from the distribution directory"
 279   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 280   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 281   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 282 add_dependencies(dist dist-dir)
 283
 284 if(NOT enable_maintainer_mode)
 285   add_custom_target(echo-dist
 286     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 287     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 288     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------")
 289   add_dependencies(dist echo-dist)
 290 endif()
 291
 292 ###########################################
 293 ### Fill in the "make distcheck" target ###
 294 ###########################################
 295
 296 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 297
 298 # Allow to test the "make dist"
 299 add_custom_target(distcheck
 300   COMMAND ${CMAKE_COMMAND} -E echo "XXX Compare archive with git repository"
 301   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/internal/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 302
 303   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove old copy"
 304   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 305
 306   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 307   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 308
 309   COMMAND ${CMAKE_COMMAND} -E echo "XXX Create build and install subtrees"
 310   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 311   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 312
 313   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 314   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 315           ${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst -Denable_lto=OFF ..
 316
 317   COMMAND ${CMAKE_COMMAND} -E echo "XXX Check generated files -- please copy new version if they are different"
 318   COMMAND ${CMAKE_COMMAND} -E compare_files ${CMAKE_HOME_DIRECTORY}/MANIFEST.in ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build/MANIFEST.in
 319
 320   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 321   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4
 322
 323   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 324   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 325
 326   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build tests"
 327   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4 tests
 328
 329   COMMAND ${CMAKE_COMMAND} -E echo "XXX Run tests"
 330   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure -j 4
 331
 332   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 333   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 334   )
 335 add_dependencies(distcheck dist)
 336
 337 #######################################
 338 ### Fill in the "make check" target ###
 339 #######################################
 340
 341 if(enable_memcheck)
 342   add_custom_target(check COMMAND ctest -D ExperimentalMemCheck)
 343 else()
 344   add_custom_target(check COMMAND make test)
 345 endif()
 346 add_dependencies(check tests)
 347
 348 #######################################
 349 ### Fill in the "make xxx-clean" target ###
 350 #######################################
 351
 352 add_custom_target(maintainer-clean
 353   COMMAND ${CMAKE_COMMAND} -E remove -f src/mpif.f90
 354   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}")
 355
 356 include(CPack)