configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.1.1-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15
  16 AM_INIT_AUTOMAKE(gnu)
  17 AC_CONFIG_MACRO_DIR(acmacro)
  18 ACLOCAL="$ACLOCAL -I acmacro"
  19 AC_LIBTOOL_WIN32_DLL
  20 AC_PROG_LIBTOOL
  21
  22 ###############
  23 ## System checks
  24 ##
  25 SG_CONFIGURE_PART(System checks...)
  26 AC_PROG_CC(xlC gcc cc)
  27 AM_SANITY_CHECK
  28 AC_PROG_MAKE_SET
  29 AC_CHECK_PRINTF_NULL
  30 AC_CHECK_VA_COPY
  31
  32 # Checks for header files.
  33 AC_HEADER_STDC
  34 AC_HEADER_TIME
  35 AC_CHECK_HEADERS([sys/socket.h \
  36                   sys/stat.h \
  37                   windows.h winsock.h winsock2.h \
  38                   sys/time.h \
  39                   errno.h unistd.h \
  40                   execinfo.h\
  41                   signal.h ])
  42 AC_CHECK_FUNCS([gettimeofday usleep \
  43                 getdtablesize \
  44                 sysconf\
  45                 readv\
  46                 popen\
  47                 signal])
  48
  49 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  50 AC_FUNC_SNPRINTF
  51 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  52 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  53 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  54
  55 # Checks for typedefs, structures, and compiler characteristics.
  56 AC_C_CONST
  57 AC_C_INLINE
  58 AC_TYPE_SIZE_T
  59
  60 ###################################
  61 ## SimGrid and GRAS specific checks
  62 ##
  63
  64 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  65 # Check architecture signature begin
  66 GRAS_ARCH
  67 # Check architecture signature end
  68 GRAS_CHECK_STRUCT_COMPACTION
  69
  70
  71 dnl ##
  72 dnl ##  CONTEXT IMPLEMENTATION
  73 dnl ##
  74
  75 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  76
  77 dnl #
  78 dnl #  1. determine possibilities
  79 dnl #
  80
  81 dnl #  check for MCSC method
  82 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  83
  84 dnl #  check for pthread method
  85 AC_CHECK_HEADERS([pthread.h])
  86 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  87
  88 dnl #
  89 dnl #  2. make a general decision
  90 dnl #
  91
  92 if test ".$mcsc" = .yes; then
  93    mcsc=yes
  94 elif test ".$pthread" = .yes; then
  95    pthread=yes
  96 else
  97     ac_header=windows.h
  98     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
  99     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 100       windows_context=yes
 101     else
 102       AC_ERROR([no appropriate backend found])
 103     fi
 104 fi
 105
 106 dnl #
 107 dnl #  3. allow decision to be overridden by user
 108 dnl #
 109
 110 AC_MSG_CHECKING(what kind of backend should we use)
 111
 112 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 113
 114 AC_ARG_WITH(context,
 115   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 116   with_context=auto)
 117
 118 if test "x$with_context$mcsc" = "xucontextno" ; then
 119   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 120 fi
 121
 122 case $with_context in
 123  ucontext) ;;
 124  pthread) ;;
 125  windows) ;;
 126  auto) with_context=ucontext;;
 127  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 128 esac
 129
 130 if test "x$with_context" = "xucontext" ; then
 131   if test ".$mcsc" = .yes; then
 132     AC_MSG_RESULT(found working ucontext. Great!)
 133     AC_DEFINE([USE_UCONTEXT],1,[Define if we use ucontext or not])
 134   else
 135     if test ".$windows_context" = .yes ; then
 136       AC_MSG_RESULT(use windows context portability layer.)
 137       with_context=windows
 138     else
 139       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 140       with_context=pthread
 141     fi
 142   fi
 143 fi
 144
 145 if test "x$with_context" = "xpthread"; then
 146   AC_CHECK_HEADERS([pthread.h])
 147   AC_CHECK_LIB(pthread,pthread_create,,
 148     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 149   AC_DEFINE([USE_PTHREADS],1,[Define if we use pthreads or not])
 150   AC_MSG_RESULT(You have pthreads. Let's use them.)
 151 fi
 152
 153 dnl #
 154 dnl #  4. determine a few additional details
 155 dnl #
 156
 157 if test "x$with_context" = "xucontext" ; then
 158 dnl #  direction of stack grow
 159   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 160   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 161       PTH_STACK_GROWTH="down"
 162   else
 163       PTH_STACK_GROWTH="up"
 164   fi
 165   AC_SUBST(PTH_STACK_GROWTH)
 166
 167   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 168 fi
 169
 170
 171 #########################################
 172 ## Build optional modules (simix)
 173 ##
 174 SG_CONFIGURE_PART(Optional modules)
 175 AC_ARG_ENABLE(simix,
 176   AS_HELP_STRING([--enable-simix], [Use the new SimIX module (default=no)]),
 177   enable_simix=$enableval,enable_simix=no)
 178 if test "x$enable_simix" = "xyes" ; then
 179   AC_MSG_RESULT("***** You have decided to use the experimental SimIX. We hope you know what you're doing.. ****")
 180   AC_DEFINE(USE_SIMIX, 1, [Indicates whether we should use SimIX or not])
 181 else
 182   AC_MSG_RESULT(Eventually you will come to SimIX: x$enable_simix)
 183 fi
 184 AM_CONDITIONAL(USE_SIMIX,test x$enable_simix != xno)
 185
 186 #########################################
 187 ## Check for libraries extra-dependencies
 188 ##
 189
 190 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 191
 192 SIMGRID_DEP=""
 193 GRAS_DEP=""
 194 AC_CHECK_LIB(pthread,pthread_create,SIMGRID_DEP="-lpthread"; GRAS_DEP="-lpthread")
 195
 196 AC_MSG_CHECKING(for csdp)
 197 sdp=no
 198 AC_CHECK_LIB(sdp,sdp,csdp=yes, csdp=no,-llapack -lblas -lm)
 199 if test "x$csdp" = xyes; then
 200   SIMGRID_DEP="$SIMGRID_DEP -lsdp -llapack -lblas -lm"
 201   AC_MSG_RESULT(Found working sdp library.)
 202   AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 203 else
 204   AC_MSG_RESULT(Could not find any working sdp library.)
 205 fi;
 206 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 207
 208 AC_SUBST([SIMGRID_DEP])
 209
 210 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 211 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 212
 213 AC_MSG_CHECKING(for extra dependencies of libgras)
 214 case $host_os in
 215   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 216             AC_SUBST(AM_CFLAGS,-DDLL_EXPORT);;
 217 esac
 218
 219 if test "x$GRAS_DEP" = x; then
 220    AC_MSG_RESULT(none)
 221 else
 222    AC_MSG_RESULT($GRAS_DEP)
 223 fi
 224 AC_SUBST([GRAS_DEP])
 225
 226
 227 ##############################################
 228 ## Enhance maintainer mode and SUBST variables
 229 ## (must be placed after any compilation tests since our overprotective flags
 230 ##  let some tests fail)
 231
 232 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 233 # Next line is modified by sed when building gramine source tree
 234 gramine_mode=no
 235 if test x$gramine_mode = xyes
 236 then
 237   USE_MAINTAINER_MODE=no
 238 fi
 239 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 240
 241
 242 AM_MAINTAINER_MODE
 243 if test x$USE_MAINTAINER_MODE = xyes
 244 then
 245    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 246    enable_compile_warnings=yes
 247 fi
 248 SG_COMPILE_FLAGS
 249
 250 AC_SUBST(CFLAGS)
 251 AC_SUBST(CPPFLAGS)
 252 AC_SUBST(LDFLAGS)
 253 AC_SUBST([abs_builddir])
 254 AC_SUBST([abs_srcdir])
 255 AC_SUBST([abs_top_builddir])
 256 AC_SUBST([abs_top_srcdir])
 257
 258 #####################
 259 ## Check for programs
 260 ##
 261
 262 SG_CONFIGURE_PART(Check for programs...)
 263 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 264 WARNING="This file is generated, do not edit"
 265 AC_SUBST(WARNING)
 266
 267
 268 # Can we rebuild the parsers?
 269 # We really want flex and refuse other lex. So, the parser is portable and
 270 # does not induce extra lib dependency
 271 AC_PROG_FLEX(2.5.30)
 272
 273 # Can we rebuild the xml-lexers from the XML specification?
 274 # if not, simply touch the flex source files (which are distributed in
 275 #  tarballs even if generated by flexml) and hope for the best.
 276 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 277 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 278
 279 if test x$USE_MAINTAINER_MODE = xyes
 280 then
 281    # Check for doxygen when in maintainer mode since dist* targets fail
 282    # without it
 283    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 284    if test x$DOXYGEN = x ; then
 285      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 286    fi
 287 fi
 288
 289 # Can we extract really usable backtraces? (also need the popen function)
 290 AC_PATH_PROG(ADDR2LINE, addr2line)
 291 if test x$ADDR2LINE != x ; then
 292   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 293 fi
 294
 295 AC_SUBST(ac_configure_args)
 296 # Can we make status line about the compilation result?
 297 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 298 if test x$MD5SUM != xno ; then
 299   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 300                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 301 else
 302   build_version="no_md5sum_binary"
 303 fi
 304 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 305 AC_SUBST(build_id)
 306
 307 ###################
 308 ## Makes the output
 309 ##
 310
 311
 312 #
 313 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 314 #  src/amok/Makefile
 315
 316 SG_CONFIGURE_PART(Generating files...)
 317
 318 # Core of the libraries
 319
 320 AC_CONFIG_FILES([
 321   Makefile
 322   include/Makefile
 323   src/Makefile
 324   src/ucontext_stack.h
 325 ])
 326
 327 # Tools being embeeded in gramine (stub generator)
 328 AC_CONFIG_FILES([
 329   tools/Makefile
 330     tools/gras/Makefile
 331 ])
 332
 333 # GRAMINE_CUT_BEGIN
 334
 335 # Tools NOT being embeeded in gramine
 336 AC_CONFIG_FILES([
 337   tools/graspe-slave
 338 ],[
 339     for file in                                                 \
 340      tools/graspe-slave           tools/graspe-master           \
 341     ; do                                                        \
 342       test -e $file && chmod +x $file;                          \
 343     done
 344 ])
 345
 346 # Testsuite
 347
 348 AC_CONFIG_FILES([
 349   testsuite/Makefile
 350   testsuite/run_tests
 351   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 352 ],[
 353     for file in                                                 \
 354      testsuite/run_tests                                        \
 355      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 356     ; do                                                        \
 357       test -e $file && chmod +x $file;                          \
 358     done
 359 ])
 360
 361 # Documentation
 362 AC_CONFIG_FILES([
 363   doc/Makefile
 364   doc/Doxyfile
 365 ])
 366
 367 # Examples
 368
 369 AC_CONFIG_FILES([
 370   examples/Makefile
 371     examples/msg/Makefile           examples/msg/run_msg_test
 372     examples/simdag/Makefile        examples/simdag/test_simdag
 373     examples/gras/Makefile
 374       examples/gras/ping/Makefile   examples/gras/ping/test_sg   examples/gras/ping/test_rl
 375       examples/gras/rpc/Makefile    examples/gras/rpc/test_sg    examples/gras/rpc/test_rl
 376       examples/gras/timer/Makefile  examples/gras/timer/test_sg  examples/gras/timer/test_rl
 377       examples/gras/chrono/Makefile examples/gras/chrono/test_sg examples/gras/chrono/test_rl
 378       examples/gras/mutual_exclusion/simple_token/Makefile examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl
 379       examples/gras/mmrpc/Makefile  examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl
 380       examples/gras/pmm/Makefile    examples/gras/pmm/test_sg    examples/gras/pmm/test_rl
 381       examples/gras/all2all/Makefile examples/gras/all2all/test_sg examples/gras/all2all/test_rl
 382
 383       examples/gras/p2p/Makefile
 384       examples/gras/p2p/chord/Makefile examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl
 385       examples/gras/p2p/can/Makefile   examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl
 386
 387     examples/amok/Makefile
 388       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 389       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 390 ],[
 391     for file in                                                 \
 392      \
 393      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 394      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 395      \
 396      examples/gras/ping/test_sg   examples/gras/ping/test_rl    \
 397      examples/gras/rpc/test_sg    examples/gras/rpc/test_rl     \
 398      examples/gras/timer/test_sg  examples/gras/timer/test_rl   \
 399      examples/gras/chrono/test_sg examples/gras/chrono/test_rl  \
 400      examples/gras/mutual_exclusion/simple_token/test_sg examples/gras/mutual_exclusion/simple_token/test_rl  \
 401      examples/gras/mmrpc/test_sg  examples/gras/mmrpc/test_rl   \
 402      examples/gras/pmm/test_sg    examples/gras/pmm/test_rl     \
 403      examples/gras/all2all/test_sg  examples/gras/all2all/test_rl   \
 404      examples/gras/p2p/chord/test_sg examples/gras/p2p/chord/test_rl  \
 405      examples/gras/p2p/can/test_sg   examples/gras/p2p/can/test_rl  \
 406      examples/msg/run_msg_test                                  \
 407      examples/simdag/test_simdag                                \
 408     ; do                                                        \
 409       test -e $file && chmod +x $file;                          \
 410     done
 411 ])
 412
 413 #     examples/gras/chord/test_sg  examples/gras/chord/test_rl   \
 414 #    examples/gras/pastry/test_sg
 415
 416
 417
 418 #    examples/gras/saturate/Makefile  examples/gras/saturate/test_sg
 419 #    examples/gras/alnem/Makefile     examples/gras/alnem/test_sg
 420
 421
 422 # GRAMINE_CUT_END
 423
 424 AC_OUTPUT
 425
 426 echo "
 427
 428 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 429
 430         Compiler:        ${CC} (version: ${GCC_VERSION})
 431
 432         CFlags:          ${CFLAGS}
 433         CPPFlags:        ${CPPFLAGS}
 434         LDFlags:         ${LDFLAGS}
 435
 436         Context backend: ${with_context}
 437 "
 438
 439 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 440   echo "WARNING:"
 441   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 442   echo "WARNING: You may want to enable this by specifying:"
 443   echo "WARNING:"
 444   echo "WARNING: ./configure --enable-maintainer-mode  $ac_configure_args"
 445   echo "WARNING:"
 446 fi
 447 echo $build_id > stamp.configure
 448
 449 exit 0;