examples/s4u/CMakeLists.txt

   1
   2 # Regular examples: with only one source and tested with all factories
   3 ######################################################################
   4
   5 foreach (example actor-create actor-daemon actor-exiting actor-join actor-kill
   6                  actor-lifetime actor-migrate actor-suspend actor-yield
   7                  app-chainsend app-pingpong app-token-ring
   8                  async-ready async-wait async-waitany async-waitall async-waituntil
   9                  comm-dependent
  10                  cloud-capping cloud-migration cloud-simple
  11                  energy-exec energy-boot energy-link energy-vm energy-exec-ptask
  12                  engine-filtering
  13                  exec-async exec-basic exec-dvfs exec-ptask exec-remote exec-waitany exec-waitfor exec-dependent
  14                  io-async io-file-system io-file-remote io-disk-raw io-dependent
  15                  platform-failures platform-profile platform-properties
  16                  plugin-hostload
  17                  replay-comm replay-io
  18                  routing-get-clusters
  19                  synchro-barrier synchro-condition-variable synchro-mutex synchro-semaphore)
  20   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
  21   add_dependencies     (tests s4u-${example})
  22   target_link_libraries(s4u-${example} simgrid)
  23   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
  24
  25   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
  26   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
  27
  28   ADD_TESH_FACTORIES(s4u-${example} "thread;ucontext;raw;boost"
  29                                     --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
  30                                     --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  31                                     --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
  32                                     ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
  33 endforeach()
  34
  35
  36 # Model-checking examples: with only one source and tested with all factories but thread
  37 ######################################################################
  38
  39 foreach (example mc-failing-assert)
  40   if(SIMGRID_HAVE_MC)
  41     add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
  42     add_dependencies     (tests s4u-${example})
  43     target_link_libraries(s4u-${example} simgrid)
  44     set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
  45
  46
  47     ADD_TESH_FACTORIES(s4u-${example} "ucontext;raw;boost"
  48                                       --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
  49                                     --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  50                                     --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
  51                                     ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
  52   endif()
  53
  54   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
  55   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
  56 endforeach()
  57
  58
  59 # Multi-files examples
  60 ######################
  61
  62 # MASTERWORKERS EXAMPLE
  63 foreach(variant fun class)
  64   add_executable       (s4u-app-masterworkers-${variant} EXCLUDE_FROM_ALL app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
  65   target_link_libraries(s4u-app-masterworkers-${variant} simgrid)
  66   set_target_properties(s4u-app-masterworkers-${variant} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-masterworkers)
  67   add_dependencies(tests s4u-app-masterworkers-${variant})
  68
  69   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
  70 endforeach()
  71 set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers.tesh)
  72
  73 # CHORD EXAMPLE
  74 add_executable       (s4u-dht-chord EXCLUDE_FROM_ALL dht-chord/s4u-dht-chord.cpp dht-chord/s4u-dht-chord-node.cpp)
  75 target_link_libraries(s4u-dht-chord simgrid)
  76 set_target_properties(s4u-dht-chord PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/dht-chord)
  77 add_dependencies(tests s4u-dht-chord)
  78 foreach (file s4u-dht-chord.cpp s4u-dht-chord-node.cpp s4u-dht-chord.hpp)
  79   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/${file})
  80 endforeach()
  81
  82 # KADEMLIA EXAMPLE
  83 add_executable       (s4u-dht-kademlia EXCLUDE_FROM_ALL dht-kademlia/s4u-dht-kademlia.cpp dht-kademlia/node.cpp
  84                       dht-kademlia/routing_table.cpp dht-kademlia/answer.cpp)
  85 target_link_libraries(s4u-dht-kademlia simgrid)
  86 set_target_properties(s4u-dht-kademlia PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/dht-kademlia)
  87 add_dependencies(tests s4u-dht-kademlia)
  88 foreach (file answer routing_table node s4u-dht-kademlia)
  89   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/${file}.cpp
  90                                      ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/${file}.hpp)
  91 endforeach()
  92 set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/message.hpp)
  93
  94 # BITTORRENT EXAMPLE
  95 add_executable       (s4u-bittorrent EXCLUDE_FROM_ALL app-bittorrent/s4u-bittorrent.cpp app-bittorrent/s4u-peer.cpp
  96                       app-bittorrent/s4u-tracker.cpp)
  97 target_link_libraries(s4u-bittorrent simgrid)
  98 set_target_properties(s4u-bittorrent PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-bittorrent)
  99 add_dependencies(tests s4u-bittorrent)
 100 foreach (file s4u-bittorrent s4u-peer s4u-tracker)
 101   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/${file}.cpp
 102                                      ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/${file}.hpp)
 103 endforeach()
 104
 105 # The tests of DHT, along with the parallel variant
 106
 107 if(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_PROCESSOR STREQUAL "i386" AND CMAKE_SIZEOF_VOID_P EQUAL 8)
 108   # Thread-local storage (TLS) is needed for parallel execution, but it doesn't
 109   # play well with Ucontexts on 64bit SunOS (at least on x86_64).
 110   set(parallel-factories "thread;raw;boost")
 111 else()
 112   set(parallel-factories "thread;ucontext;raw;boost")
 113 endif()
 114
 115 foreach(example app-bittorrent app-masterworkers
 116                 dht-chord dht-kademlia
 117                 )
 118   ADD_TESH_FACTORIES(s4u-${example} "thread;ucontext;raw;boost"
 119                                     --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 120                                     --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 121                                     --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 122                                     ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 123
 124   ADD_TESH_FACTORIES(s4u-${example}-parallel "${parallel-factories}" --cfg contexts/nthreads:4 ${CONTEXTS_SYNCHRO}
 125                                              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 126                                              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 127                                              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 128                                              ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 129 endforeach()
 130
 131 # Examples not accepting factories
 132 ##################################
 133
 134 foreach (example trace-platform)
 135   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 136   target_link_libraries(s4u-${example} simgrid)
 137   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 138   add_dependencies(tests s4u-${example})
 139
 140   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 141   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 142
 143   ADD_TESH(s4u-${example} --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 144                           --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 145                           ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 146 endforeach()
 147
 148 if (NOT enable_memcheck AND NOT WIN32)
 149   ADD_TESH(simix-breakpoint --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/app-pingpong
 150                             --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 151                             ${CMAKE_CURRENT_SOURCE_DIR}/app-pingpong/simix-breakpoint.tesh)
 152 endif()
 153
 154 # Examples accepting only thread factories
 155 ##################################
 156 foreach (example maestro-set)
 157   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 158   target_link_libraries(s4u-${example} simgrid)
 159   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 160   add_dependencies(tests s4u-${example})
 161
 162   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 163   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 164
 165   if(NOT WIN32)
 166     ADD_TESH_FACTORIES(s4u-${example} "thread" --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 167                                                --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 168                                                ${CMAKE_HOME_DIRECTORY}/examples/s4u/${example}/s4u-${example}.tesh)
 169   else()
 170     message("Test maestro-set disabled on windows: this feature is not working")
 171   endif()
 172 endforeach()
 173
 174 # Add all extra files to the archive
 175 ####################################
 176
 177 set(examples_src  ${examples_src}                                                                          PARENT_SCOPE)
 178 set(tesh_files    ${tesh_files}   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent.tesh
 179                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-pingpong/simix-breakpoint.tesh
 180                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord.tesh
 181                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia.tesh
 182                   PARENT_SCOPE)
 183 set(xml_files     ${xml_files}    ${CMAKE_CURRENT_SOURCE_DIR}/actor-create/s4u-actor-create_d.xml
 184                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-lifetime/s4u-actor-lifetime_d.xml
 185                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-yield/s4u-actor-yield_d.xml
 186                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent_d.xml
 187                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers_d.xml
 188                                   ${CMAKE_CURRENT_SOURCE_DIR}/async-wait/s4u-async-wait_d.xml
 189                                   ${CMAKE_CURRENT_SOURCE_DIR}/async-waitany/s4u-async-waitany_d.xml
 190                                   ${CMAKE_CURRENT_SOURCE_DIR}/async-waitall/s4u-async-waitall_d.xml
 191                                   ${CMAKE_CURRENT_SOURCE_DIR}/async-ready/s4u-async-ready_d.xml
 192                                   ${CMAKE_CURRENT_SOURCE_DIR}/async-waituntil/s4u-async-waituntil_d.xml
 193                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord_d.xml
 194                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia_d.xml
 195                                   ${CMAKE_CURRENT_SOURCE_DIR}/energy-boot/platform_boot.xml
 196                                   ${CMAKE_CURRENT_SOURCE_DIR}/io-file-remote/s4u-io-file-remote_d.xml
 197                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-properties/s4u-platform-properties_d.xml
 198                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-failures/s4u-platform-failures_d.xml
 199                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split_d.xml
 200                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm_d.xml
 201                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io_d.xml
 202                   PARENT_SCOPE)
 203 set(bin_files     ${bin_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/generate.py                     PARENT_SCOPE)
 204 set(txt_files     ${txt_files}    ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p0.txt
 205                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p1.txt
 206                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm.txt
 207                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io.txt                  PARENT_SCOPE)
 208