acmacro/gras_arch.m4

   1 # BEGIN OF GRAS ARCH CHECK
   2 dnl
   3 dnl GRAS_DO_CHECK_SIZEOF: Get the size of a datatype (even in cross-compile)
   4 dnl  1: type tested
   5 dnl  2: extra include lines
   6 dnl  3: extra sizes to test
   7 dnl ("adapted" from openldap)
   8 dnl
   9 AC_DEFUN([GRAS_DO_CHECK_SIZEOF],
  10 [changequote(<<, >>)dnl
  11  dnl The cache variable name (and of the result).
  12  define(<<GRAS_CHECK_SIZEOF_RES>>, translit(ac_cv_sizeof_$1, [ *()], [_pLR]))dnl
  13  changequote([, ])dnl
  14  AC_CACHE_VAL(GRAS_CHECK_SIZEOF_RES,
  15  [for ac_size in 4 8 1 2 16 $3 ; do # List sizes in rough order of prevalence.
  16    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include "confdefs.h"
  17    #include <sys/types.h>
  18    $2
  19    ], [switch (0) case 0: case (sizeof ($1) == $ac_size):;]), GRAS_CHECK_SIZEOF_RES=$ac_size)
  20    if test x$GRAS_CHECK_SIZEOF_RES != x ; then break; fi
  21   done
  22  ])
  23 ])
  24
  25 dnl
  26 dnl GRAS_CHECK_SIZEOF: Get the size of a datatype (even in cross-compile), with msg display, and define the result
  27 dnl  1: type tested
  28 dnl  2: extra include lines
  29 dnl  3: extra sizes to test
  30 dnl ("adapted" from openldap)
  31 dnl
  32 AC_DEFUN([GRAS_CHECK_SIZEOF],
  33 [AC_MSG_CHECKING(size of $1)
  34 GRAS_DO_CHECK_SIZEOF($1,$2)
  35 if test x$GRAS_CHECK_SIZEOF_RES = x ; then
  36   AC_MSG_ERROR([cannot determine a size for $1])
  37 fi
  38 AC_MSG_RESULT($GRAS_CHECK_SIZEOF_RES)
  39 ])
  40
  41 dnl
  42 dnl GRAS_TWO_COMPLIMENT([type]): Make sure the type is two-compliment
  43 dnl warning, this does not work with char (quite logical)
  44 dnl
  45 AC_DEFUN([GRAS_TWO_COMPLIMENT],
  46 [
  47 AC_MSG_CHECKING(whether $1 is two-compliment)
  48 AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include "confdefs.h"
  49 union {
  50    signed $1 testInt;
  51    unsigned char bytes[sizeof($1)];
  52 } intTester;
  53 ]],[[
  54    intTester.testInt = -2;
  55    return ((unsigned int)intTester.bytes[0] +
  56            (unsigned int)intTester.bytes[sizeof($1) - 1]) - 509; /* should be 0 */
  57 ]])], dnl end of AC LANG PROGRAM
  58 [two_compliment=yes],[two_compliment=no] )dnl end of AC COMPILE IFELSE
  59
  60 AC_MSG_RESULT($two_compliment)
  61 if test x$two_compliment != xyes ; then
  62   AC_MSG_ERROR([GRAS works only two-compliment integers (yet)])
  63 fi
  64 ])
  65
  66 dnl
  67 dnl GRAS_SIGNED_SIZEOF: Get the size of the datatype, and make sure that
  68 dnl signed, unsigned and unspecified have the same size
  69 dnl
  70 AC_DEFUN([GRAS_SIGNED_SIZEOF],
  71 [AC_MSG_CHECKING(size of $1)
  72 GRAS_DO_CHECK_SIZEOF($1,$2)
  73 unspecif=$GRAS_CHECK_SIZEOF_RES
  74 if test x$unspecif = x ; then
  75   AC_MSG_ERROR([cannot determine a size for $1])
  76 fi
  77
  78 GRAS_DO_CHECK_SIZEOF(signed $1,$2)
  79 signed=$GRAS_CHECK_SIZEOF_RES
  80 if test x$signed = x ; then
  81   AC_MSG_ERROR([cannot determine a size for signed $1])
  82 fi
  83 if test x$unspecif != x$signed ; then
  84   AC_MSG_ERROR(['signed $1' and '$1' have different sizes ! ($signed != $unspecif)])
  85 fi
  86
  87 GRAS_DO_CHECK_SIZEOF(unsigned $1,$2)
  88 unsigned=$GRAS_CHECK_SIZEOF_RES
  89 if test x$unsigned = x ; then
  90   AC_MSG_ERROR([cannot determine a size for unsigned $1])
  91 fi
  92 if test x$unsigned != x$signed ; then
  93   AC_MSG_ERROR(['signed $1' and 'unsigned $1' have different sizes ! ($signed != $unsigned)])
  94 fi
  95
  96 AC_MSG_RESULT($GRAS_CHECK_SIZEOF_RES)
  97 ])
  98
  99 dnl
 100 dnl End of CHECK_SIGNED_SIZEOF
 101 dnl
 102
 103 # GRAS_STRUCT_BOUNDARY(): Check the minimal alignment boundary of $1 in structures
 104 # ---------------------
 105 # (using integer, I hope no arch let it change with the content)
 106 AC_DEFUN([GRAS_STRUCT_BOUNDARY],
 107 [changequote(<<, >>)dnl
 108  dnl The cache variable name (and of the result).
 109  define(<<GRAS_STRUCT_BOUNDARY_RES>>, translit(ac_cv_struct_boundary_$1, [ *()], [_pLR]))dnl
 110  changequote([, ])dnl
 111  AC_MSG_CHECKING(for the minimal structure boundary of $1)
 112
 113  AC_CACHE_VAL(GRAS_STRUCT_BOUNDARY_RES,
 114  [for ac_size in 1 2 4 8 16 32 64 ; do # List sizes in rough order of prevalence.
 115    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include "confdefs.h"
 116      #include <sys/types.h>
 117      struct s { char c; $1 i; };
 118      ],[switch (0) case 0: case (sizeof (struct s) == $ac_size+sizeof($1)):;]), GRAS_STRUCT_BOUNDARY_RES=$ac_size)
 119    if test x$GRAS_STRUCT_BOUNDARY_RES != x ; then break; fi
 120   done
 121  ])
 122  AC_MSG_RESULT($GRAS_STRUCT_BOUNDARY_RES)
 123 ])
 124
 125 # GRAS_ARCH(): check the gras_architecture of this plateform
 126 # -----------
 127 # The different cases here must be syncronized with the array in src/base/DataDesc/ddt_convert.c
 128 #
 129 AC_DEFUN([GRAS_ARCH],
 130 [
 131 # Check for the architecture
 132 AC_C_BIGENDIAN(endian=1,endian=0,AC_MSG_ERROR([GRAS works only for little or big endian systems (yet)]))
 133 dnl Make sure we don't run on a non-two-compliment arch, since we dunno convert them
 134 GRAS_TWO_COMPLIMENT(int)
 135 AC_DEFINE_UNQUOTED(GRAS_BIGENDIAN,$endian,[define if big endian])
 136
 137 GRAS_SIGNED_SIZEOF(char)              GRAS_STRUCT_BOUNDARY(char)
 138 GRAS_SIGNED_SIZEOF(short int)         GRAS_STRUCT_BOUNDARY(short int)
 139 GRAS_SIGNED_SIZEOF(int)               GRAS_STRUCT_BOUNDARY(int)
 140 GRAS_SIGNED_SIZEOF(long int)          GRAS_STRUCT_BOUNDARY(long int)
 141 GRAS_SIGNED_SIZEOF(long long int)     GRAS_STRUCT_BOUNDARY(long long int)
 142
 143 GRAS_STRUCT_BOUNDARY(float)           GRAS_STRUCT_BOUNDARY(double)
 144
 145 GRAS_CHECK_SIZEOF(void *)             GRAS_STRUCT_BOUNDARY(void *)
 146 GRAS_CHECK_SIZEOF(void (*) (void))
 147
 148
 149 AC_MSG_CHECKING(the GRAS signature of this architecture)
 150 if test x$endian = x1 ; then
 151   trace_endian=B
 152 else
 153   trace_endian=l
 154 fi
 155 gras_arch=unknown
 156 trace="$trace_endian"
 157
 158 trace="${trace}_C:${ac_cv_sizeof_char}/${ac_cv_struct_boundary_char}:"
 159
 160 trace="${trace}_I:${ac_cv_sizeof_short_int}/${ac_cv_struct_boundary_short_int}"
 161 trace="${trace}:${ac_cv_sizeof_int}/${ac_cv_struct_boundary_int}"
 162 trace="${trace}:${ac_cv_sizeof_long_int}/${ac_cv_struct_boundary_long_int}"
 163 trace="${trace}:${ac_cv_sizeof_long_long_int}/${ac_cv_struct_boundary_long_long_int}:"
 164
 165 trace="${trace}_P:${ac_cv_sizeof_void_p}/${ac_cv_struct_boundary_void_p}"
 166 trace="${trace}:${ac_cv_sizeof_void_LpR_LvoidR}/${ac_cv_struct_boundary_void_p}:"
 167
 168 trace="${trace}_D:4/${ac_cv_struct_boundary_float}:8/${ac_cv_struct_boundary_double}:"
 169
 170 # sizeof float/double are not tested since IEEE 754 is assumed.
 171 # Check README.IEEE for rational.
 172 case $trace in
 173   l_C:1/1:_I:2/2:4/4:4/4:8/4:_P:4/4:4/4:_D:4/4:8/4:) gras_arch=0; gras_arch_name=little32;;
 174   l_C:1/1:_I:2/2:4/4:8/8:8/8:_P:8/8:8/8:_D:4/4:8/8:) gras_arch=1; gras_arch_name=little64;;
 175   B_C:1/1:_I:2/2:4/4:4/4:8/8:_P:4/4:4/4:_D:4/4:8/8:) gras_arch=2; gras_arch_name=big32;;
 176   B_C:1/1:_I:2/2:4/4:8/8:8/8:_P:8/8:8/8:_D:4/4:8/8:) gras_arch=3; gras_arch_name=big64;;
 177 esac
 178 if test x$gras_arch = xunknown ; then
 179   AC_MSG_RESULT([damnit ($trace)])
 180   AC_MSG_ERROR([Impossible to determine the GRAS architecture signature.
 181 Please report this architecture trace ($trace) and what it corresponds to.])
 182 fi
 183 echo "$as_me:$LINENO: GRAS trace of this machine: $trace" >&AS_MESSAGE_LOG_FD
 184 AC_DEFINE_UNQUOTED(GRAS_THISARCH,$gras_arch,[defines the GRAS architecture signature of this machine])
 185 AC_MSG_RESULT($gras_arch ($gras_arch_name))
 186 ])
 187 # END OF GRAS ARCH CHECK
 188
 189 AC_DEFUN([GRAS_CHECK_STRUCT_COMPACTION],
 190 [  AC_MSG_CHECKING(whether the struct gets packed)
 191    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include "confdefs.h"
 192         #include <sys/types.h>
 193         #include <stddef.h> /* offsetof() */
 194         struct s {char c; double d;};
 195        ]],[[switch (0)
 196         case 0:
 197         case (sizeof(struct s) == sizeof(double)+sizeof(char)):;
 198        ]])],[gras_struct_packed=yes],[gras_struct_packed=no])
 199
 200    AC_MSG_RESULT($gras_struct_packed)
 201    if test x$gras_struct_packed = "xyes" ; then
 202      AC_MSG_ERROR([GRAS does not support packed structures since it leads to nasty misalignments])
 203    fi
 204
 205    AC_MSG_CHECKING(whether the struct gets compacted)
 206    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include "confdefs.h"
 207         #include <sys/types.h>
 208         #include <stddef.h> /* offsetof() */
 209         struct s {double d; int i; char c;};
 210        ]],[[switch (0)
 211         case 0:
 212         case (offsetof(struct s,c) == sizeof(double)+sizeof(int)):;
 213        ]])],[gras_struct_compact=yes],[gras_struct_compact=no])
 214
 215    AC_MSG_RESULT($gras_struct_compact)
 216
 217    if test x$gras_struct_compact != xyes ; then
 218      AC_MSG_ERROR([GRAS works only on structure compacting architectures (yet)])
 219    fi
 220    AC_DEFINE_UNQUOTED(GRAS_STRUCT_COMPACT, 1,
 221       [Defined if structures are compacted when possible.
 222
 223        Consider this structure: struct s {double d; int i; char c;};
 224
 225        If it is allowed, the char is placed just after the int. If not,
 226        it has to be on the 8 bytes boundary imposed by the double.
 227
 228        For now, GRAS requires the structures to be compacted.
 229       ])
 230    AC_MSG_CHECKING(whether arrays can straddle struct alignment boundaries)
 231
 232    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include "confdefs.h"
 233       #include <sys/types.h>
 234         #include <stddef.h> /* offsetof() */
 235         struct s { double d; int i; char c[6]; };
 236      ]],[[switch (0)
 237       case 0:
 238       case (offsetof(struct s,c) == sizeof(double)+sizeof(int)):;
 239      ]])],[gras_array_straddle_struct=yes],[gras_array_straddle_struct=no])
 240
 241    AC_MSG_RESULT($gras_array_straddle_struct)
 242
 243    if test x$gras_array_straddle_struct = xyes ; then
 244      AC_DEFINE_UNQUOTED(GRAS_ARRAY_STRADDLE_STRUCT, 1,
 245         [Defined if arrays in struct can straddle struct alignment boundaries.
 246
 247          This is like than the structure compaction above, but this time,
 248          the argument to be compacted is an array whom each element would be
 249          normally compacted. Exemple:
 250
 251          struct s { double d; int i; char c[6]; };
 252
 253          Arrays can straddle if c is allowed to come just after i.
 254
 255          Note that GRAS only support architecture presenting this
 256          caracteristic so far.
 257         ])
 258    else
 259      AC_MSG_ERROR([GRAS can only work on architectures allowing array fields to straddle alignment boundaries (yet)])
 260    fi
 261 ])
 262 # END OF GRAS CHECK STRUCT COMPACTION
 263
 264 AC_DEFUN([GRAS_C_COMPACT_STRUCT],
 265 [  AC_MSG_CHECKING(whether the struct gets compacted)
 266    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include "confdefs.h"
 267         #include <sys/types.h>
 268         #include <stddef.h> /* offsetof() */
 269         struct s {double d; int a; int b;};
 270        ]],[[switch (0)
 271         case 0:
 272         case (offsetof(struct s,b) == sizeof(double)+sizeof(int)):;
 273        ]])],[gras_compact_struct=yes],[gras_compact_struct=no])
 274
 275    AC_MSG_RESULT($gras_compact_struct)
 276
 277    if test x$gras_compact_struct = xyes ; then
 278      AC_DEFINE_UNQUOTED(GRAS_COMPACT_STRUCT, 1,
 279           [Defined if structures are compacted when possible])
 280    fi
 281 ])
 282 # END OF GRAS COMPACT STRUCT
 283