tools/cmake/Modules/pybind11Tools.cmake

   1 # tools/pybind11Tools.cmake -- Build system for the pybind11 modules
   2 #
   3 # Copyright (c) 2015 Wenzel Jakob <wenzel@inf.ethz.ch>
   4 #
   5 # All rights reserved. Use of this source code is governed by a
   6 # BSD-style license that can be found in the LICENSE file.
   7
   8 cmake_minimum_required(VERSION 2.8.12)
   9
  10 # Add a CMake parameter for choosing a desired Python version
  11 if(NOT PYBIND11_PYTHON_VERSION)
  12   set(PYBIND11_PYTHON_VERSION "" CACHE STRING "Python version to use for compiling modules")
  13 endif()
  14
  15 set(Python_ADDITIONAL_VERSIONS 3.7 3.6 3.5 3.4)
  16 find_package(PythonLibsNew ${PYBIND11_PYTHON_VERSION} REQUIRED)
  17
  18 include(CheckCXXCompilerFlag)
  19 include(CMakeParseArguments)
  20
  21 if(NOT PYBIND11_CPP_STANDARD AND NOT CMAKE_CXX_STANDARD)
  22   if(NOT MSVC)
  23     check_cxx_compiler_flag("-std=c++14" HAS_CPP14_FLAG)
  24
  25     if (HAS_CPP14_FLAG)
  26       set(PYBIND11_CPP_STANDARD -std=c++14)
  27     else()
  28       check_cxx_compiler_flag("-std=c++11" HAS_CPP11_FLAG)
  29       if (HAS_CPP11_FLAG)
  30         set(PYBIND11_CPP_STANDARD -std=c++11)
  31       else()
  32         message(FATAL_ERROR "Unsupported compiler -- pybind11 requires C++11 support!")
  33       endif()
  34     endif()
  35   elseif(MSVC)
  36     set(PYBIND11_CPP_STANDARD /std:c++14)
  37   endif()
  38
  39   set(PYBIND11_CPP_STANDARD ${PYBIND11_CPP_STANDARD} CACHE STRING
  40       "C++ standard flag, e.g. -std=c++11, -std=c++14, /std:c++14.  Defaults to C++14 mode." FORCE)
  41 endif()
  42
  43 # Checks whether the given CXX/linker flags can compile and link a cxx file.  cxxflags and
  44 # linkerflags are lists of flags to use.  The result variable is a unique variable name for each set
  45 # of flags: the compilation result will be cached base on the result variable.  If the flags work,
  46 # sets them in cxxflags_out/linkerflags_out internal cache variables (in addition to ${result}).
  47 function(_pybind11_return_if_cxx_and_linker_flags_work result cxxflags linkerflags cxxflags_out linkerflags_out)
  48   set(CMAKE_REQUIRED_LIBRARIES ${linkerflags})
  49   check_cxx_compiler_flag("${cxxflags}" ${result})
  50   if (${result})
  51     set(${cxxflags_out} "${cxxflags}" CACHE INTERNAL "" FORCE)
  52     set(${linkerflags_out} "${linkerflags}" CACHE INTERNAL "" FORCE)
  53   endif()
  54 endfunction()
  55
  56 # Internal: find the appropriate link time optimization flags for this compiler
  57 function(_pybind11_add_lto_flags target_name prefer_thin_lto)
  58   if (NOT DEFINED PYBIND11_LTO_CXX_FLAGS)
  59     set(PYBIND11_LTO_CXX_FLAGS "" CACHE INTERNAL "")
  60     set(PYBIND11_LTO_LINKER_FLAGS "" CACHE INTERNAL "")
  61
  62     if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
  63       set(cxx_append "")
  64       set(linker_append "")
  65       if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND NOT APPLE)
  66         # Clang Gold plugin does not support -Os; append -O3 to MinSizeRel builds to override it
  67         set(linker_append ";$<$<CONFIG:MinSizeRel>:-O3>")
  68       elseif(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
  69         set(cxx_append ";-fno-fat-lto-objects")
  70       endif()
  71
  72       if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND prefer_thin_lto)
  73         _pybind11_return_if_cxx_and_linker_flags_work(HAS_FLTO_THIN
  74           "-flto=thin${cxx_append}" "-flto=thin${linker_append}"
  75           PYBIND11_LTO_CXX_FLAGS PYBIND11_LTO_LINKER_FLAGS)
  76       endif()
  77
  78       if (NOT HAS_FLTO_THIN)
  79         _pybind11_return_if_cxx_and_linker_flags_work(HAS_FLTO
  80           "-flto${cxx_append}" "-flto${linker_append}"
  81           PYBIND11_LTO_CXX_FLAGS PYBIND11_LTO_LINKER_FLAGS)
  82       endif()
  83     elseif (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  84       # Intel equivalent to LTO is called IPO
  85       _pybind11_return_if_cxx_and_linker_flags_work(HAS_INTEL_IPO
  86       "-ipo" "-ipo" PYBIND11_LTO_CXX_FLAGS PYBIND11_LTO_LINKER_FLAGS)
  87     elseif(MSVC)
  88       # cmake only interprets libraries as linker flags when they start with a - (otherwise it
  89       # converts /LTCG to \LTCG as if it was a Windows path).  Luckily MSVC supports passing flags
  90       # with - instead of /, even if it is a bit non-standard:
  91       _pybind11_return_if_cxx_and_linker_flags_work(HAS_MSVC_GL_LTCG
  92         "/GL" "-LTCG" PYBIND11_LTO_CXX_FLAGS PYBIND11_LTO_LINKER_FLAGS)
  93     endif()
  94
  95     if (PYBIND11_LTO_CXX_FLAGS)
  96       message(STATUS "LTO enabled")
  97     else()
  98       message(STATUS "LTO disabled (not supported by the compiler and/or linker)")
  99     endif()
 100   endif()
 101
 102   # Enable LTO flags if found, except for Debug builds
 103   if (PYBIND11_LTO_CXX_FLAGS)
 104     target_compile_options(${target_name} PRIVATE "$<$<NOT:$<CONFIG:Debug>>:${PYBIND11_LTO_CXX_FLAGS}>")
 105   endif()
 106   if (PYBIND11_LTO_LINKER_FLAGS)
 107     target_link_libraries(${target_name} PRIVATE "$<$<NOT:$<CONFIG:Debug>>:${PYBIND11_LTO_LINKER_FLAGS}>")
 108   endif()
 109 endfunction()
 110
 111 # Build a Python extension module:
 112 # pybind11_add_module(<name> [MODULE | SHARED] [EXCLUDE_FROM_ALL]
 113 #                     [NO_EXTRAS] [THIN_LTO] source1 [source2 ...])
 114 #
 115 function(pybind11_add_module target_name)
 116   set(options MODULE SHARED EXCLUDE_FROM_ALL NO_EXTRAS THIN_LTO)
 117   cmake_parse_arguments(ARG "${options}" "" "" ${ARGN})
 118
 119   if(ARG_MODULE AND ARG_SHARED)
 120     message(FATAL_ERROR "Can't be both MODULE and SHARED")
 121   elseif(ARG_SHARED)
 122     set(lib_type SHARED)
 123   else()
 124     set(lib_type MODULE)
 125   endif()
 126
 127   if(ARG_EXCLUDE_FROM_ALL)
 128     set(exclude_from_all EXCLUDE_FROM_ALL)
 129   endif()
 130
 131   add_library(${target_name} ${lib_type} ${exclude_from_all} ${ARG_UNPARSED_ARGUMENTS})
 132
 133   target_include_directories(${target_name}
 134     PRIVATE ${PYBIND11_INCLUDE_DIR}  # from project CMakeLists.txt
 135     PRIVATE ${pybind11_INCLUDE_DIR}  # from pybind11Config
 136     PRIVATE ${PYTHON_INCLUDE_DIRS})
 137
 138   # Python debug libraries expose slightly different objects
 139   # https://docs.python.org/3.6/c-api/intro.html#debugging-builds
 140   # https://stackoverflow.com/questions/39161202/how-to-work-around-missing-pymodule-create2-in-amd64-win-python35-d-lib
 141   if(PYTHON_IS_DEBUG)
 142     target_compile_definitions(${target_name} PRIVATE Py_DEBUG)
 143   endif()
 144
 145   # The prefix and extension are provided by FindPythonLibsNew.cmake
 146   set_target_properties(${target_name} PROPERTIES PREFIX "${PYTHON_MODULE_PREFIX}")
 147   set_target_properties(${target_name} PROPERTIES SUFFIX "${PYTHON_MODULE_EXTENSION}")
 148
 149   # -fvisibility=hidden is required to allow multiple modules compiled against
 150   # different pybind versions to work properly, and for some features (e.g.
 151   # py::module_local).  We force it on everything inside the `pybind11`
 152   # namespace; also turning it on for a pybind module compilation here avoids
 153   # potential warnings or issues from having mixed hidden/non-hidden types.
 154   set_target_properties(${target_name} PROPERTIES CXX_VISIBILITY_PRESET "hidden")
 155
 156   if(WIN32 OR CYGWIN)
 157     # Link against the Python shared library on Windows
 158     target_link_libraries(${target_name} PRIVATE ${PYTHON_LIBRARIES})
 159   elseif(APPLE)
 160     # It's quite common to have multiple copies of the same Python version
 161     # installed on one's system. E.g.: one copy from the OS and another copy
 162     # that's statically linked into an application like Blender or Maya.
 163     # If we link our plugin library against the OS Python here and import it
 164     # into Blender or Maya later on, this will cause segfaults when multiple
 165     # conflicting Python instances are active at the same time (even when they
 166     # are of the same version).
 167
 168     # Windows is not affected by this issue since it handles DLL imports
 169     # differently. The solution for Linux and Mac OS is simple: we just don't
 170     # link against the Python library. The resulting shared library will have
 171     # missing symbols, but that's perfectly fine -- they will be resolved at
 172     # import time.
 173
 174     target_link_libraries(${target_name} PRIVATE "-undefined dynamic_lookup")
 175
 176     if(ARG_SHARED)
 177       # Suppress CMake >= 3.0 warning for shared libraries
 178       set_target_properties(${target_name} PROPERTIES MACOSX_RPATH ON)
 179     endif()
 180   endif()
 181
 182   # Make sure C++11/14 are enabled
 183   target_compile_options(${target_name} PUBLIC ${PYBIND11_CPP_STANDARD})
 184
 185   if(ARG_NO_EXTRAS)
 186     return()
 187   endif()
 188
 189   _pybind11_add_lto_flags(${target_name} ${ARG_THIN_LTO})
 190
 191   if (NOT MSVC AND NOT ${CMAKE_BUILD_TYPE} MATCHES Debug)
 192     # Strip unnecessary sections of the binary on Linux/Mac OS
 193     if(CMAKE_STRIP)
 194       if(APPLE)
 195         add_custom_command(TARGET ${target_name} POST_BUILD
 196                            COMMAND ${CMAKE_STRIP} -x $<TARGET_FILE:${target_name}>)
 197       else()
 198         add_custom_command(TARGET ${target_name} POST_BUILD
 199                            COMMAND ${CMAKE_STRIP} $<TARGET_FILE:${target_name}>)
 200       endif()
 201     endif()
 202   endif()
 203
 204   if(MSVC)
 205     # /MP enables multithreaded builds (relevant when there are many files), /bigobj is
 206     # needed for bigger binding projects due to the limit to 64k addressable sections
 207     target_compile_options(${target_name} PRIVATE /MP /bigobj)
 208   endif()
 209 endfunction()