examples/cpp/CMakeLists.txt

   1 # Regular examples: with only one source and tested with all factories by default
   2 #################################################################################
   3 ### Define the examples' specificities
   4
   5 set(_app-bittorrent_sources app-bittorrent/s4u-bittorrent.cpp app-bittorrent/s4u-bittorrent.hpp
   6                             app-bittorrent/s4u-peer.cpp app-bittorrent/s4u-peer.hpp
   7                             app-bittorrent/s4u-tracker.cpp app-bittorrent/s4u-tracker.hpp)
   8 set(_dht-chord_sources    dht-chord/s4u-dht-chord.cpp dht-chord/s4u-dht-chord.hpp dht-chord/s4u-dht-chord-node.cpp)
   9 set(_dht-kademlia_sources dht-kademlia/s4u-dht-kademlia.cpp dht-kademlia/s4u-dht-kademlia.hpp
  10                           dht-kademlia/node.cpp dht-kademlia/node.hpp
  11                           dht-kademlia/routing_table.cpp dht-kademlia/routing_table.hpp
  12                           dht-kademlia/answer.cpp dht-kademlia/answer.hpp dht-kademlia/message.hpp)
  13
  14 set(_actor-stacksize_factories "^thread") # Threads ignore modifications of the stack size
  15
  16 # The maestro-set example only works for threads
  17 set(_maestro-set_factories "thread")
  18
  19 if(SIMGRID_HAVE_MC)
  20   # These tests timeout with threads, not sure why
  21   foreach(example mc-bugged1 mc-bugged2 mc-failing-assert mc-electric-fence)
  22     set(_${example}_factories "^thread") # Timeout
  23     add_dependencies(tests-mc s4u-${example})
  24   endforeach()
  25
  26   if(enable_coverage)
  27     foreach (example mc-bugged1 mc-bugged2 mc-electric-fence mc-failing-assert)
  28       ADD_TEST(cover-${example} ${CMAKE_CURRENT_BINARY_DIR}/${example}/s4u-${example} ${CMAKE_HOME_DIRECTORY}/examples/platforms/model_checker_platform.xml)
  29     endforeach()
  30   endif()
  31 else()
  32   foreach (example mc-bugged1 mc-bugged2  mc-centralized-mutex mc-failing-assert mc-electric-fence)
  33     set(_${example}_disable 1)
  34   endforeach()
  35 endif()
  36
  37 set(tesh_files ${tesh_files} ${CMAKE_CURRENT_SOURCE_DIR}/synchro-mutex/s4u-mc-synchro-mutex-stateful.tesh)
  38 if(SIMGRID_HAVE_STATEFUL_MC)
  39   if(HAVE_C_STACK_CLEANER)
  40     add_executable       (s4u-mc-bugged1-liveness-cleaner-on  EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  41     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-on  simgrid)
  42     set_target_properties(s4u-mc-bugged1-liveness-cleaner-on  PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fstack-cleaner")
  43     add_dependencies(tests-mc s4u-mc-bugged1-liveness-cleaner-on)
  44
  45     add_executable       (s4u-mc-bugged1-liveness-cleaner-off EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  46     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-off simgrid)
  47     set_target_properties(s4u-mc-bugged1-liveness-cleaner-off PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fno-stack-cleaner")
  48     add_dependencies(tests-mc s4u-mc-bugged1-liveness-cleaner-off)
  49   endif()
  50
  51   ADD_TESH(s4u-mc-synchro-mutex-stateful
  52      --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/synchro-mutex
  53      --setenv libdir=${CMAKE_BINARY_DIR}/lib
  54      --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  55      --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/synchro-mutex
  56      --cd ${CMAKE_CURRENT_SOURCE_DIR}/synchro-mutex
  57       ${CMAKE_HOME_DIRECTORY}/examples/cpp/synchro-mutex/s4u-mc-synchro-mutex-stateful.tesh)
  58
  59   # Model-checking liveness
  60   if(HAVE_UCONTEXT_CONTEXTS AND SIMGRID_PROCESSOR_x86_64)
  61     # liveness model-checking works only on 64bits (for now ...)
  62     set(_mc-bugged1-liveness_factories "ucontext")
  63     add_dependencies(tests-mc s4u-mc-bugged1-liveness)
  64     set(_mc-bugged2-liveness_factories "ucontext")
  65
  66     # This example never ends, disable it for now
  67     set(_mc-bugged2-liveness_disable 1)
  68
  69     if ("${CMAKE_SYSTEM}" MATCHES "Linux")
  70       # timeout under FreeBSD (test never stops)
  71       ADD_TESH(s4u-mc-bugged1-liveness-visited-ucontext --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness
  72                                                         --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  73                                                         --cd ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness
  74                                                         ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh)
  75     endif()
  76     IF(HAVE_C_STACK_CLEANER)
  77       add_dependencies(tests-mc s4u-mc-bugged1-liveness-stack-cleaner)
  78       # This test checks if the stack cleaner is making a difference:
  79       ADD_TEST(s4u-mc-bugged1-liveness-stack-cleaner ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
  80                                                      ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/
  81                                                      ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/)
  82     ENDIF()
  83   else()
  84     set(_mc-bugged1-liveness_disable 1)
  85     set(_mc-bugged2-liveness_disable 1)
  86   endif()
  87
  88   if(enable_coverage)
  89     ADD_TEST(cover-mc-bugged1-liveness ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness ${CMAKE_HOME_DIRECTORY}/examples/platforms/small_platform.xml 1 1001)
  90   endif()
  91
  92 else()
  93   foreach (example mc-bugged1-liveness mc-bugged2-liveness)
  94     set(_${example}_disable 1)
  95   endforeach()
  96 endif()
  97
  98 # Hijack some regular tests to run them on top of the MC
  99 foreach (example synchro-barrier synchro-mutex synchro-semaphore)
 100   set(tesh_files ${tesh_files} ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-mc-${example}.tesh)
 101
 102   if (SIMGRID_HAVE_MC)
 103     ADD_TESH(s4u-mc-${example}
 104               --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 105               --setenv libdir=${CMAKE_BINARY_DIR}/lib
 106               --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 107               --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 108               --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 109               ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-mc-${example}.tesh)
 110
 111     add_dependencies(tests-mc s4u-${example})
 112   endif()
 113 endforeach()
 114
 115 if (SIMGRID_HAVE_MC)
 116   # Dependency on the regular tests
 117   foreach(example mc-centralized-mutex)
 118     add_dependencies(tests-mc s4u-${example})
 119   endforeach()
 120 endif()
 121
 122 if(NOT HAVE_GRAPHVIZ)
 123   set(_dag-from-dot_disable 1)
 124   set(_dag-from-dot-simple_disable 1)
 125 endif()
 126
 127 if (NOT SIMGRID_HAVE_JSON)
 128   set(_dag-from-json-simple_disable 1)
 129 endif()
 130
 131 if(SIMGRID_HAVE_NS3)
 132   if(NS3_VERSION VERSION_GREATER_EQUAL 3.37)
 133     set(_network-ns3_teshfile         ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-timed.tesh)
 134     set(tesh_files    ${tesh_files}   ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-notime.tesh)
 135   else()
 136     set(_network-ns3_teshfile         ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-notime.tesh)
 137     set(tesh_files    ${tesh_files}   ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-timed.tesh)
 138   endif()
 139
 140 foreach (example network-ns3 network-ns3-wifi)
 141   add_dependencies(tests-ns3 s4u-${example})
 142 endforeach()
 143
 144 else()
 145   # Even if ns3 is not found, we need to override the teshfile name and make sure that everything gets included in the archive
 146   set(_network-ns3_teshfile         ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-notime.tesh)
 147   set(tesh_files    ${tesh_files}   ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-timed.tesh)
 148
 149   foreach (example network-ns3 network-ns3-wifi)
 150     set(_${example}_disable 1)
 151   endforeach()
 152 endif()
 153
 154 # Deal with each example
 155
 156 foreach (example activityset-testany activityset-waitany activityset-waitall activityset-waitallfor
 157                  actor-create actor-daemon actor-exiting actor-join actor-kill
 158                  actor-lifetime actor-migrate actor-suspend actor-yield actor-stacksize
 159                  app-bittorrent app-chainsend app-token-ring
 160                  battery-degradation battery-simple battery-energy
 161                  chiller-simple
 162                  comm-pingpong comm-ready comm-suspend comm-wait comm-waituntil
 163                  comm-dependent comm-host2host comm-failure comm-throttling
 164                  cloud-capping cloud-migration cloud-simple
 165                  dag-comm dag-from-json-simple dag-from-dax-simple dag-from-dax dag-from-dot-simple dag-from-dot dag-failure dag-io dag-scheduling dag-simple dag-tuto
 166                  dht-chord dht-kademlia
 167                  energy-exec energy-boot energy-link energy-vm energy-exec-ptask energy-wifi
 168                  engine-filtering engine-run-partial
 169                  exec-async exec-basic exec-dvfs exec-remote exec-waitfor exec-dependent exec-unassigned
 170                  exec-ptask-multicore exec-ptask-multicore-latency exec-cpu-nonlinear exec-cpu-factors exec-failure exec-threads
 171                  maestro-set
 172                  mc-bugged1 mc-bugged1-liveness mc-bugged2 mc-bugged2-liveness mc-centralized-mutex mc-electric-fence mc-failing-assert
 173                  network-ns3 network-ns3-wifi network-wifi
 174                  io-async io-priority io-degradation io-file-system io-file-remote io-disk-raw io-dependent
 175                  task-io task-microservice task-parallelism task-simple task-storm task-switch-host task-variable-load
 176                  solar-panel-simple
 177                  platform-comm-serialize platform-failures platform-profile platform-properties
 178                  plugin-host-load plugin-jbod plugin-link-load plugin-prodcons
 179                  replay-comm replay-io
 180                  routing-get-clusters
 181                  synchro-barrier synchro-condition-variable synchro-condition-variable-waituntil synchro-mutex synchro-semaphore
 182                  clusters-multicpu network-factors network-nonlinear)
 183
 184   # Use default source file unless specified otherwise
 185   if(NOT DEFINED _${example}_sources)
 186     set(_${example}_sources ${example}/s4u-${example}.cpp)
 187   endif()
 188
 189   # Use default tesh file unless specified otherwise
 190   if(NOT DEFINED _${example}_teshfile)
 191     set(_${example}_teshfile ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 192   endif()
 193
 194   if(NOT DEFINED _${example}_disable)
 195     add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${_${example}_sources})
 196     add_dependencies     (tests s4u-${example})
 197     add_dependencies     (s4u-${example} platf_cpp)
 198     target_link_libraries(s4u-${example} simgrid)
 199     set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 200
 201     # Use default factories unless specified otherwise
 202     if(NOT DEFINED _${example}_factories)
 203       set(_${example}_factories "*")
 204     endif()
 205 #    message("Factories of ${example}: ${_${example}_factories}")
 206
 207     ADD_TESH_FACTORIES(s4u-${example} "${_${example}_factories}"
 208                                       --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 209                                       --setenv libdir=${CMAKE_BINARY_DIR}/lib
 210                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 211                                       --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 212                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 213                                       ${_${example}_teshfile})
 214   else()
 215     message(STATUS "Example ${example} disabled, thus not compiled.")
 216     unset(_${example}_disable)
 217   endif()
 218
 219   set(tesh_files    ${tesh_files}    ${_${example}_teshfile})
 220   foreach(file ${_${example}_sources})
 221     set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/${file})
 222   endforeach()
 223
 224   unset(_${example}_factories)
 225   unset(_${example}_sources)
 226   unset(_${example}_teshfile)
 227 endforeach()
 228
 229
 230 # Specific examples
 231 ###################
 232
 233 # MASTERWORKERS EXAMPLE
 234 foreach(variant fun class)
 235   add_executable       (s4u-app-masterworkers-${variant} EXCLUDE_FROM_ALL app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 236   target_link_libraries(s4u-app-masterworkers-${variant} simgrid)
 237   set_target_properties(s4u-app-masterworkers-${variant} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-masterworkers)
 238   add_dependencies(tests s4u-app-masterworkers-${variant})
 239
 240   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 241 endforeach()
 242 set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers.tesh)
 243
 244 # The tests the parallel variant of of DHTs
 245
 246 if(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_PROCESSOR STREQUAL "i386" AND CMAKE_SIZEOF_VOID_P EQUAL 8)
 247   # Thread-local storage (TLS) is needed for parallel execution, but it doesn't
 248   # play well with Ucontexts on 64bit SunOS (at least on x86_64).
 249   set(parallel-factories "^ucontext")
 250 else()
 251   set(parallel-factories "*")
 252 endif()
 253
 254 foreach(example app-bittorrent app-masterworkers
 255                 dht-chord dht-kademlia
 256                 )
 257   ADD_TESH_FACTORIES(s4u-${example}-parallel "${parallel-factories}" --cfg contexts/nthreads:4 ${CONTEXTS_SYNCHRO}
 258                                              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 259                                              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 260                                              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 261                                              ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 262 endforeach()
 263
 264 # Test non-DPOR reductions on a given MC test
 265 foreach(example mc-failing-assert)
 266 # State equality is not tested because it would take about 15 hours to run that test on my machine.
 267 # We should first optimize mmalloc_heap_differ() which takes ~4sec for each pair to compare (maybe {175 x 174/ 2} pairs here)
 268 # See the comment on mmalloc_heap_differ() in compare.cpp for more info on why it's hard to optimize.
 269 #
 270 #  if(SIMGRID_HAVE_STATEFUL_MC)
 271 #    ADD_TESH(s4u-${example}-statequality  --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 272 #                                      --setenv libdir=${CMAKE_BINARY_DIR}/lib
 273 #                                      --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 274 #                                      --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 275 #                                      --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 276 #                                      ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}-statequality.tesh)
 277 #  endif()
 278
 279   if(SIMGRID_HAVE_MC)
 280     ADD_TESH(s4u-${example}-nodpor    --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 281                                       --setenv libdir=${CMAKE_BINARY_DIR}/lib
 282                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 283                                       --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 284                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 285                                       ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}-nodpor.tesh)
 286   endif()
 287   set(tesh_files    ${tesh_files}   ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}-statequality.tesh)
 288   set(tesh_files    ${tesh_files}   ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}-nodpor.tesh)
 289 endforeach()
 290
 291 # Examples not accepting factories
 292 ##################################
 293
 294 foreach (example exec-ptask trace-categories trace-masterworkers trace-platform trace-process-migration
 295                  trace-host-user-variables trace-link-user-variables trace-route-user-variables)
 296   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 297   target_link_libraries(s4u-${example} simgrid)
 298   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 299   add_dependencies(tests s4u-${example})
 300
 301   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 302   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 303
 304   ADD_TESH(s4u-${example} --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 305                           --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 306                           --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 307                           --cd ${CMAKE_CURRENT_BINARY_DIR}/${example}
 308                           ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 309 endforeach()
 310
 311 if (NOT enable_memcheck)
 312   ADD_TESH(debug-breakpoint --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/comm-pingpong
 313                             --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 314                             ${CMAKE_CURRENT_SOURCE_DIR}/comm-pingpong/debug-breakpoint.tesh)
 315 endif()
 316
 317 # Add all extra files to the archive
 318 ####################################
 319 set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp        PARENT_SCOPE)
 320 set(tesh_files    ${tesh_files}   ${CMAKE_CURRENT_SOURCE_DIR}/comm-pingpong/debug-breakpoint.tesh
 321                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.tesh
 322                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh  PARENT_SCOPE)
 323 set(xml_files     ${xml_files}    ${CMAKE_CURRENT_SOURCE_DIR}/actor-create/s4u-actor-create_d.xml
 324                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-lifetime/s4u-actor-lifetime_d.xml
 325                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent_d.xml
 326                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers_d.xml
 327                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-scheduling/Montage_25.xml
 328                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord_d.xml
 329                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia_d.xml
 330                                   ${CMAKE_CURRENT_SOURCE_DIR}/io-file-remote/s4u-io-file-remote_d.xml
 331                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-failures/s4u-platform-failures_d.xml
 332                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split_d.xml
 333                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm_d.xml
 334                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io_d.xml
 335                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3hosts_2links_d.xml
 336                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links-timer_d.xml
 337                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links_d.xml
 338                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/crosstraffic_d.xml
 339                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/dogbone_d.xml
 340                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/onelink_d.xml
 341                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/one_cluster_d.xml                PARENT_SCOPE)
 342 set(bin_files     ${bin_files}    ${CMAKE_CURRENT_SOURCE_DIR}/battery-degradation/plot_battery_degradation.py
 343                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/generate.py
 344                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
 345                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/promela_bugged1_liveness
 346                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged2-liveness/promela_bugged2_liveness PARENT_SCOPE)
 347 set(txt_files     ${txt_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax/simple_dax_with_cycle.xml
 348                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax/smalldax.xml
 349                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax-simple/dag.xml
 350                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot/dag.dot
 351                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot-simple/dag.dot
 352                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot/dag_with_cycle.dot
 353                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-json-simple/dag.json
 354                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p0.txt
 355                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p1.txt
 356                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm.txt
 357                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io.txt                  PARENT_SCOPE)