tools/cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 install(DIRECTORY "${CMAKE_BINARY_DIR}/doc/html/" DESTINATION ${CMAKE_INSTALL_DOCDIR}/html/ OPTIONAL)
   7
   8 # binaries
   9 if(enable_smpi)
  10   install(PROGRAMS
  11     ${CMAKE_BINARY_DIR}/bin/smpicc
  12     ${CMAKE_BINARY_DIR}/bin/smpicxx
  13     ${CMAKE_BINARY_DIR}/bin/smpirun
  14     DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  15   if(SMPI_FORTRAN)
  16     install(PROGRAMS
  17       ${CMAKE_BINARY_DIR}/bin/smpif90
  18       ${CMAKE_BINARY_DIR}/bin/smpiff
  19       DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  20     install(PROGRAMS
  21       ${CMAKE_BINARY_DIR}/include/smpi/mpi.mod
  22       DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/smpi/)
  23   endif()
  24 endif()
  25
  26 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  27
  28 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  29   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  30   RENAME simgrid-colorizer)
  31
  32 add_custom_target(simgrid-colorizer ALL
  33   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  34   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize)
  35
  36 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  37   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  38   RENAME simgrid_update_xml)
  39
  40 add_custom_target(simgrid_update_xml ALL
  41   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  42   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml)
  43
  44 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py
  45   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  46   RENAME simgrid_convert_TI_traces)
  47
  48 add_custom_target(simgrid_convert_TI_traces ALL
  49     COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces"
  50     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces)
  51
  52 # libraries
  53 install(TARGETS simgrid DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  54
  55 # pkg-config files
  56 configure_file("${CMAKE_HOME_DIRECTORY}/tools/pkg-config/simgrid.pc.in"
  57   "${PROJECT_BINARY_DIR}/simgrid.pc" @ONLY)
  58 install(FILES "${PROJECT_BINARY_DIR}/simgrid.pc" DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
  59
  60 # include files
  61 foreach(file ${headers_to_install} ${generated_headers_to_install})
  62   get_filename_component(location ${file} PATH)
  63   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  64   string(REGEX REPLACE "^include/" "" location "${location}")
  65   string(REGEX REPLACE "^include$" "" location "${location}")
  66   # message("installing '${file}' into '${CMAKE_INSTALL_INCLUDEDIR}/${location}'")
  67   install(FILES ${file} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${location})
  68 endforeach()
  69
  70 # example files
  71 foreach(file ${examples_to_install})
  72   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  73   get_filename_component(location ${file} PATH)
  74   # message("DOC installing 'examples/${file}' into '${CMAKE_INSTALL_DOCDIR}/examples/${location}'")
  75   install(FILES "examples/${file}"
  76     DESTINATION ${CMAKE_INSTALL_DOCDIR}/examples/${location})
  77 endforeach(file ${examples_to_install})
  78
  79 ################################################################
  80 ## Build a sane "make dist" target to build a source package ###
  81 ##    containing only the files that I explicitly state      ###
  82 ##   (instead of any cruft laying on my disk as CPack does)  ###
  83 ################################################################
  84
  85 # This is the complete list of what will be added to the source archive
  86 set(source_to_pack
  87   ${headers_to_install}
  88   ${source_of_generated_headers}
  89   ${JMSG_C_SRC}
  90   ${MC_SRC_BASE}
  91   ${MC_SRC}
  92   ${MC_SIMGRID_MC_SRC}
  93   ${MSG_SRC}
  94   ${S4U_SRC}
  95   ${NS3_SRC}
  96   ${PLUGINS_SRC}
  97   ${DAG_SRC}
  98   ${SIMGRID_SRC}
  99   ${SIMIX_SRC}
 100   ${SMPI_SRC}
 101   ${SURF_SRC}
 102   ${TRACING_SRC}
 103   ${XBT_RL_SRC}
 104   ${XBT_SRC}
 105   ${STHREAD_SRC}
 106   ${EXTRA_DIST}
 107   ${CMAKE_SOURCE_FILES}
 108   ${CMAKEFILES_TXT}
 109   ${DOC_IMG}
 110   ${DOC_SOURCES}
 111   ${DOC_TOOLS}
 112   ${PLATFORMS_EXAMPLES}
 113   ${README_files}
 114   ${bin_files}
 115   ${examples_src}
 116   ${tesh_files}
 117   ${teshsuite_src}
 118   ${tools_src}
 119   ${txt_files}
 120   ${xml_files}
 121   )
 122 list(SORT source_to_pack)
 123 list(REMOVE_DUPLICATES source_to_pack)
 124
 125 ##########################################
 126 ### Fill in the "make dist-dir" target ###
 127 ##########################################
 128
 129 add_custom_target(dist-dir
 130   COMMENT "Generating the distribution directory"
 131   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 132   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 133   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 134   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 135   )
 136 add_dependencies(dist-dir maintainer_files)
 137
 138 set(dirs_in_tarball "")
 139 foreach(file ${source_to_pack})
 140   #message(${file})
 141   # This damn prefix is still set somewhere (seems to be in subdirs)
 142   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 143
 144   # Prepare the list of files to include in the python sdist, one per line
 145   set(PYTHON_SOURCES "${PYTHON_SOURCES}\ninclude ${file}")
 146
 147   # Create the directory on need
 148   get_filename_component(file_location ${file} PATH)
 149   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 150   if(NOT OPERATION)
 151     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 152     add_custom_command(
 153       TARGET dist-dir
 154       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/)
 155   endif()
 156
 157   # Actually copy the file
 158   add_custom_command(
 159     TARGET dist-dir
 160     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location})
 161 endforeach(file ${source_to_pack})
 162 configure_file("${CMAKE_HOME_DIRECTORY}/MANIFEST.in.in" "${CMAKE_BINARY_DIR}/MANIFEST.in" @ONLY IMMEDIATE)
 163 unset(PYTHON_SOURCES)
 164
 165
 166 add_custom_command(
 167   TARGET dist-dir
 168   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion)
 169
 170 ##########################################################
 171 ### Link all sources to the bindir if srcdir != bindir ###
 172 ##########################################################
 173 add_custom_target(hardlinks
 174    COMMENT "Making the source files available from the bindir"
 175 )
 176 if (NOT ${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
 177   foreach(file ${source_to_pack})
 178     #message(${file})
 179     # This damn prefix is still set somewhere (seems to be in subdirs)
 180     string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 181
 182     # Create the directory on need
 183     get_filename_component(file_location ${file} PATH)
 184     string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_bindir}")
 185     if(NOT OPERATION)
 186       set(dirs_in_tarball "${dirs_in_bindir};${file_location};")
 187       add_custom_command(
 188         TARGET hardlinks
 189         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/${file_location}/)
 190     endif()
 191
 192     # Actually copy the file
 193     add_custom_command(
 194       TARGET hardlinks
 195       COMMAND if test -f ${CMAKE_HOME_DIRECTORY}/${file} \; then rm -f ${CMAKE_BINARY_DIR}/${file}\; ln ${CMAKE_HOME_DIRECTORY}/${file} ${CMAKE_BINARY_DIR}/${file_location}\; fi
 196     )
 197   endforeach(file ${source_to_pack})
 198 endif()
 199
 200
 201 ######################################
 202 ### Fill in the "make dist" target ###
 203 ######################################
 204
 205 add_custom_target(dist
 206   COMMENT "Removing the distribution directory"
 207   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 208   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 209   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 210
 211 add_custom_command(
 212   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 213   COMMENT "Compressing the archive from the distribution directory"
 214   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 215   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 216   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 217 add_dependencies(dist dist-dir)
 218
 219 if(NOT enable_maintainer_mode)
 220   add_custom_target(echo-dist
 221     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 222     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 223     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------")
 224   add_dependencies(dist echo-dist)
 225 endif()
 226
 227 ###########################################
 228 ### Fill in the "make distcheck" target ###
 229 ###########################################
 230
 231 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 232
 233 # Allow to test the "make dist"
 234 add_custom_target(distcheck
 235   COMMAND ${CMAKE_COMMAND} -E echo "XXX Compare archive with git repository"
 236   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/internal/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 237
 238   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove old copy"
 239   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 240
 241   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 242   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 243
 244   COMMAND ${CMAKE_COMMAND} -E echo "XXX Create build and install subtrees"
 245   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 246   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 247
 248   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 249   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 250           ${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst -Denable_lto=OFF ..
 251
 252   COMMAND ${CMAKE_COMMAND} -E echo "XXX Check generated files -- please copy new version if they are different"
 253   COMMAND ${CMAKE_COMMAND} -E compare_files ${CMAKE_HOME_DIRECTORY}/MANIFEST.in ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build/MANIFEST.in
 254
 255   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 256   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4
 257
 258   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 259   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 260
 261   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build tests"
 262   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4 tests
 263
 264   COMMAND ${CMAKE_COMMAND} -E echo "XXX Run tests"
 265   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure -j 4
 266
 267   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 268   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 269   )
 270 add_dependencies(distcheck dist)
 271
 272 #######################################
 273 ### Fill in the "make check" target ###
 274 #######################################
 275
 276 if(enable_memcheck)
 277   add_custom_target(check COMMAND ctest -D ExperimentalMemCheck)
 278 else()
 279   add_custom_target(check COMMAND make test)
 280 endif()
 281 add_dependencies(check tests)
 282
 283 include(CPack)