buildtools/Cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 file(MAKE_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/html/)
   7 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/html/"
   8   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/html/)
   9 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/HelloWorld/"
  10   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/HelloWorld/)
  11
  12 #### Generate the manpages
  13 if(NOT WIN32)
  14   if( NOT MANPAGE_DIR)
  15     set( MANPAGE_DIR ${CMAKE_BINARY_DIR}/manpages )
  16   endif()
  17
  18   add_custom_target(manpages ALL
  19     COMMAND ${CMAKE_COMMAND} -E make_directory ${MANPAGE_DIR}
  20     COMMAND pod2man ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl > ${MANPAGE_DIR}/simgrid_update_xml.1
  21     COMMENT "Generating manpages"
  22     )
  23   install(FILES
  24     ${MANPAGE_DIR}/simgrid_update_xml.1
  25     ${CMAKE_HOME_DIRECTORY}/tools/tesh/tesh.1
  26     ${CMAKE_HOME_DIRECTORY}/doc/manpage/smpicc.1
  27     ${CMAKE_HOME_DIRECTORY}/doc/manpage/smpicxx.1
  28     ${CMAKE_HOME_DIRECTORY}/doc/manpage/smpif90.1
  29     ${CMAKE_HOME_DIRECTORY}/doc/manpage/smpiff.1
  30     ${CMAKE_HOME_DIRECTORY}/doc/manpage/smpirun.1
  31     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/share/man/man1)
  32
  33 endif()
  34
  35 # binaries
  36 if(enable_smpi)
  37   install(PROGRAMS
  38     ${CMAKE_BINARY_DIR}/bin/smpicc
  39     ${CMAKE_BINARY_DIR}/bin/smpicxx
  40     ${CMAKE_BINARY_DIR}/bin/smpirun
  41     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  42   if(SMPI_FORTRAN)
  43     install(PROGRAMS
  44       ${CMAKE_BINARY_DIR}/bin/smpif90
  45       ${CMAKE_BINARY_DIR}/bin/smpiff
  46       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  47   endif()
  48 endif()
  49
  50 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh
  51   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  52
  53 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/graphicator
  54   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  55
  56 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  57   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  58   RENAME simgrid-colorizer)
  59
  60 add_custom_target(simgrid-colorizer ALL
  61   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  62   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize
  63   )
  64
  65 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  66   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  67   RENAME simgrid_update_xml)
  68
  69 add_custom_target(simgrid_update_xml ALL
  70   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  71   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml
  72   )
  73
  74 # libraries
  75 install(TARGETS simgrid
  76   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  77
  78 if(enable_lib_static AND NOT WIN32)
  79   install(TARGETS simgrid_static
  80     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  81 endif()
  82
  83 if(enable_java)
  84   if(enable_lib_in_jar)
  85     set(SIMGRID_JAR_TO_INSTALL "${SIMGRID_FULL_JAR}")
  86   else()
  87     set(SIMGRID_JAR_TO_INSTALL "${SIMGRID_JAR}")
  88   endif()
  89   install(TARGETS simgrid-java
  90       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  91   install(FILES ${SIMGRID_JAR_TO_INSTALL}
  92       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/java/
  93       RENAME simgrid.jar)
  94 endif()
  95
  96 # include files
  97 set(HEADERS
  98   ${headers_to_install}
  99   ${generated_headers_to_install}
 100   )
 101 foreach(file ${HEADERS})
 102   get_filename_component(location ${file} PATH)
 103   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
 104   install(FILES ${file}
 105     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/${location})
 106 endforeach(file ${HEADERS})
 107
 108 # example files
 109 foreach(file ${examples_to_install})
 110   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
 111   get_filename_component(location ${file} PATH)
 112   install(FILES "examples/${file}"
 113     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/examples/${location})
 114 endforeach(file ${examples_to_install})
 115
 116 # bindings cruft
 117
 118 if(HAVE_LUA)
 119   file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/lib/lua/5.1")
 120   add_custom_target(simgrid_lua ALL
 121     DEPENDS simgrid
 122     ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 123     )
 124   add_custom_command(
 125     OUTPUT ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 126     COMMAND ${CMAKE_COMMAND} -E create_symlink ../../libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 127     )
 128   install(FILES ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 129     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/lua/5.1
 130     )
 131 endif()
 132
 133 ###########################################
 134 ### Fill in the "make uninstall" target ###
 135 ###########################################
 136
 137 add_custom_target(uninstall
 138   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/doc/simgrid
 139   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall doc ok"
 140   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsimgrid*
 141   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid*
 142   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall lib ok"
 143   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicc
 144   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicxx
 145   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpiff
 146   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif90
 147   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpirun
 148   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/tesh
 149   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid-colorizer
 150   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid_update_xml
 151   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/graphicator
 152   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall bin ok"
 153   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/instr
 154   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/msg
 155   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simdag
 156   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/smpi
 157   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simix
 158   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/surf
 159   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/xbt
 160   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/mc
 161   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simgrid
 162   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid.h
 163   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid_config.h
 164   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/xbt.h
 165   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall include ok"
 166   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/simgrid_update_xml.1
 167   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/tesh.1
 168   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpicc.1
 169   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpicxx.1
 170   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpirun.1
 171   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpiff.1
 172   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpif90.1
 173
 174
 175   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall man ok"
 176   WORKING_DIRECTORY "${CMAKE_INSTALL_PREFIX}"
 177   )
 178
 179 if(HAVE_LUA)
 180   add_custom_command(TARGET uninstall
 181     COMMAND ${CMAKE_COMMAND} -E echo "uninstall binding lua ok"
 182     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid.${LIB_EXE}
 183     WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}/"
 184     )
 185 endif()
 186
 187 ################################################################
 188 ## Build a sain "make dist" target to build a source package ###
 189 ##   containing only the files that I explicitely state      ###
 190 ##   (instead of any cruft laying on my disk as CPack does)  ###
 191 ################################################################
 192
 193 # This is the complete list of what will be added to the source archive
 194 set(source_to_pack
 195   ${headers_to_install}
 196   ${source_of_generated_headers}
 197   ${BINDINGS_SRC}
 198   ${GTNETS_SRC}
 199   ${JEDULE_SRC}
 200   ${JMSG_C_SRC}
 201   ${JMSG_JAVA_SRC}
 202   ${JSURF_SWIG_SRC}
 203   ${JSURF_SWIG_SRC_EXTRA}
 204   ${JSURF_C_SRC}
 205   ${LUA_SRC}
 206   ${MC_SRC_BASE}
 207   ${MC_SRC}
 208   ${MSG_SRC}
 209   ${NS3_SRC}
 210   ${RNGSTREAM_SRC}
 211   ${SIMDAG_SRC}
 212   ${SIMGRID_SRC}
 213   ${SIMIX_SRC}
 214   ${SMPI_SRC}
 215   ${SURF_SRC}
 216   ${TRACING_SRC}
 217   ${XBT_RL_SRC}
 218   ${XBT_SRC}
 219   ${EXTRA_DIST}
 220   ${CMAKE_SOURCE_FILES}
 221   ${EXAMPLES_CMAKEFILES_TXT}
 222   ${TESHSUITE_CMAKEFILES_TXT}
 223   ${TOOLS_CMAKEFILES_TXT}
 224   ${DOC_FIGS}
 225   ${DOC_IMG}
 226   ${DOC_SOURCES}
 227   ${DOC_TOOLS}
 228   ${PLATFORMS_EXAMPLES}
 229   ${README_files}
 230   ${bin_files}
 231   ${examples_src}
 232   ${tesh_files}
 233   ${teshsuite_src}
 234   ${testsuite_src}
 235   ${tools_src}
 236   ${txt_files}
 237   ${xml_files}
 238   )
 239
 240 ##########################################
 241 ### Fill in the "make dist-dir" target ###
 242 ##########################################
 243
 244 add_custom_target(dist-dir
 245   COMMENT "Generating the distribution directory"
 246   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 247   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 248   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 249   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 250   COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_HOME_DIRECTORY}/doc/html/ ${PROJECT_NAME}-${release_version}/doc/html/
 251   )
 252 add_dependencies(dist-dir maintainer_files)
 253
 254 set(dirs_in_tarball "")
 255 foreach(file ${source_to_pack})
 256   #message(${file})
 257   # This damn prefix is still set somewhere (seems to be in subdirs)
 258   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 259
 260   # Create the directory on need
 261   get_filename_component(file_location ${file} PATH)
 262   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 263   if(NOT OPERATION)
 264     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 265     add_custom_command(
 266       TARGET dist-dir
 267       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/
 268       )
 269   endif()
 270
 271   # Actually copy the file
 272   add_custom_command(
 273     TARGET dist-dir
 274     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location}
 275     )
 276 endforeach(file ${source_to_pack})
 277
 278 add_custom_command(
 279   TARGET dist-dir
 280   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/buildtools/Cmake/Scripts/Makefile.default ${PROJECT_NAME}-${release_version}/Makefile
 281   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion
 282   )
 283
 284 ######################################
 285 ### Fill in the "make dist" target ###
 286 ######################################
 287
 288 add_custom_target(dist
 289   COMMENT "Removing the distribution directory"
 290   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 291   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 292   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 293   )
 294
 295 add_custom_command(
 296   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 297   COMMENT "Compressing the archive from the distribution directory"
 298   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 299   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 300   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 301   )
 302 add_dependencies(dist dist-dir)
 303
 304 if(NOT enable_maintainer_mode)
 305   add_custom_target(echo-dist
 306     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 307     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 308     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 309     )
 310   add_dependencies(dist echo-dist)
 311 endif()
 312
 313 ###########################################
 314 ### Fill in the "make distcheck" target ###
 315 ###########################################
 316
 317 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 318
 319 # Allow to test the "make dist"
 320 add_custom_target(distcheck
 321   COMMAND ${CMAKE_COMMAND} -E echo "XXX compare archive with git repository"
 322   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 323
 324   COMMAND ${CMAKE_COMMAND} -E echo "XXX remove old copy"
 325   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 326
 327   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 328   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 329
 330   COMMAND ${CMAKE_COMMAND} -E echo "XXX create build and install subtrees"
 331   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 332   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 333
 334   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 335   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 336   ${CMAKE_COMMAND}
 337   -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 338   ..
 339   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 340   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM}
 341
 342   COMMAND ${CMAKE_COMMAND} -E echo "XXX Test"
 343   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure
 344
 345   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 346   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 347   COMMAND ${CMAKE_COMMAND} -E create_symlink
 348   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgrid.so
 349   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgridtest.so
 350
 351   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install with documentation"
 352   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 353
 354   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 355   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 356   )
 357 add_dependencies(distcheck dist)
 358
 359 #######################################
 360 ### Fill in the "make check" target ###
 361 #######################################
 362
 363 if(enable_memcheck)
 364   add_custom_target(check
 365     COMMAND ctest -D ExperimentalMemCheck
 366     )
 367 else()
 368   add_custom_target(check
 369     COMMAND make test
 370     )
 371 endif()
 372
 373 #######################################
 374 ### Fill in the "make xxx-clean" target ###
 375 #######################################
 376
 377 add_custom_target(maintainer-clean
 378   COMMAND ${CMAKE_COMMAND} -E remove -f src/config_unit.c
 379   COMMAND ${CMAKE_COMMAND} -E remove -f src/cunit_unit.c
 380   COMMAND ${CMAKE_COMMAND} -E remove -f src/dict_unit.c
 381   COMMAND ${CMAKE_COMMAND} -E remove -f src/dynar_unit.c
 382   COMMAND ${CMAKE_COMMAND} -E remove -f src/ex_unit.c
 383   COMMAND ${CMAKE_COMMAND} -E remove -f src/set_unit.c
 384   COMMAND ${CMAKE_COMMAND} -E remove -f src/simgrid_units_main.c
 385   COMMAND ${CMAKE_COMMAND} -E remove -f src/swag_unit.c
 386   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_sha_unit.c
 387   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_str_unit.c
 388   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_strbuff_unit.c
 389   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_synchro_unit.c
 390   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 391   )
 392
 393 include(CPack)