buildtools/Cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 file(MAKE_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/shared/doxygen/)
   7 file(MAKE_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/ref_guide/html/)
   8 file(MAKE_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/user_guide/html/)
   9
  10 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/ref_guide/html/"
  11   DESTINATION "$ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/ref_guide/html/"
  12   PATTERN ".svn" EXCLUDE
  13   PATTERN ".git" EXCLUDE
  14   PATTERN "*.o" EXCLUDE
  15   PATTERN "*~" EXCLUDE
  16   )
  17
  18 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/user_guide/html/"
  19   DESTINATION "$ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/user_guide/html/"
  20   PATTERN ".svn" EXCLUDE
  21   PATTERN ".git" EXCLUDE
  22   PATTERN "*.o" EXCLUDE
  23   PATTERN "*~" EXCLUDE
  24   )
  25
  26 #### Generate the manpages
  27 if(NOT WIN32)
  28   if( NOT MANPAGE_DIR)
  29     set( MANPAGE_DIR ${CMAKE_BINARY_DIR}/manpages )
  30   endif()
  31
  32   add_custom_target(manpages ALL
  33     COMMAND ${CMAKE_COMMAND} -E make_directory ${MANPAGE_DIR}
  34     COMMAND pod2man ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl > ${MANPAGE_DIR}/simgrid_update_xml.1
  35     COMMENT "Generating manpages"
  36     )
  37   install(FILES ${MANPAGE_DIR}/simgrid_update_xml.1 ${CMAKE_HOME_DIRECTORY}/tools/tesh/tesh.1
  38     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/share/man/man1)
  39
  40 endif()
  41
  42 # binaries
  43 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/smpicc
  44   ${CMAKE_BINARY_DIR}/bin/smpif2c
  45   ${CMAKE_BINARY_DIR}/bin/smpiff
  46   ${CMAKE_BINARY_DIR}/bin/smpirun
  47   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  48
  49 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh
  50   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  51
  52 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/graphicator
  53   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  54
  55 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  56   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  57   RENAME simgrid-colorizer)
  58
  59 add_custom_target(simgrid-colorizer ALL
  60   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  61   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize
  62   )
  63
  64 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  65   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  66   RENAME simgrid_update_xml)
  67
  68 add_custom_target(simgrid_update_xml ALL
  69   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  70   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml
  71   )
  72
  73 # libraries
  74 install(TARGETS simgrid
  75   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  76
  77 if(enable_smpi)
  78   install(TARGETS smpi
  79     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  80 endif()
  81
  82 if(enable_lib_static AND NOT WIN32)
  83   install(TARGETS simgrid_static
  84     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  85   if(enable_smpi)
  86     install(TARGETS smpi_static
  87       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  88   endif()
  89 endif()
  90
  91 # include files
  92 set(HEADERS
  93   ${headers_to_install}
  94   ${generated_headers_to_install}
  95   )
  96 foreach(file ${HEADERS})
  97   get_filename_component(location ${file} PATH)
  98   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  99   install(FILES ${file}
 100     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/${location})
 101 endforeach(file ${HEADERS})
 102
 103 # example files
 104 foreach(file ${examples_to_install})
 105   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
 106   get_filename_component(location ${file} PATH)
 107   install(FILES "examples/${file}"
 108     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/examples/${location})
 109 endforeach(file ${examples_to_install})
 110
 111 # bindings cruft
 112
 113 if(HAVE_LUA)
 114   file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/lib/lua/5.1")
 115   add_custom_target(simgrid_lua ALL
 116     DEPENDS simgrid
 117     ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 118     )
 119   add_custom_command(
 120     OUTPUT ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 121     COMMAND ${CMAKE_COMMAND} -E create_symlink ../../libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 122     )
 123   install(FILES ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 124     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/lua/5.1
 125     )
 126 endif()
 127
 128 ###########################################
 129 ### Fill in the "make uninstall" target ###
 130 ###########################################
 131
 132 add_custom_target(uninstall
 133   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/doc/simgrid
 134   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall doc ok"
 135   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsimgrid*
 136   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsmpi*
 137   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid*
 138   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall lib ok"
 139   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicc
 140   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif2c
 141   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpiff
 142   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpirun
 143   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/tesh
 144   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid-colorizer
 145   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid_update_xml
 146   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/graphicator
 147   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall bin ok"
 148   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/instr
 149   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/msg
 150   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simdag
 151   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/smpi
 152   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simix
 153   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/surf
 154   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/xbt
 155   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/mc
 156   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simgrid
 157   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid_config.h
 158   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/xbt.h
 159   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall include ok"
 160   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/simgrid_update_xml.1
 161     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/tesh.1
 162   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall man ok"
 163   WORKING_DIRECTORY "${CMAKE_INSTALL_PREFIX}"
 164   )
 165
 166 if(HAVE_LUA)
 167   add_custom_command(TARGET uninstall
 168     COMMAND ${CMAKE_COMMAND} -E echo "uninstall binding lua ok"
 169     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid.${LIB_EXE}
 170     WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}/"
 171     )
 172 endif()
 173
 174 ################################################################
 175 ## Build a sain "make dist" target to build a source package ###
 176 ##   containing only the files that I explicitely state      ###
 177 ##   (instead of any cruft laying on my disk as CPack does)  ###
 178 ################################################################
 179
 180 # This is the complete list of what will be added to the source archive
 181 set(source_to_pack
 182   ${headers_to_install}
 183   ${source_of_generated_headers}
 184   ${BINDINGS_SRC}
 185   ${GTNETS_SRC}
 186   ${JEDULE_SRC}
 187   ${LUA_SRC}
 188   ${MC_SRC}
 189   ${MSG_SRC}
 190   ${NS3_SRC}
 191   ${RNGSTREAM_SRC}
 192   ${SIMDAG_SRC}
 193   ${SIMIX_SRC}
 194   ${SMPI_SRC}
 195   ${SURF_SRC}
 196   ${TRACING_SRC}
 197   ${XBT_RL_SRC}
 198   ${XBT_SRC}
 199   ${EXTRA_DIST}
 200   ${CMAKE_SOURCE_FILES}
 201   ${EXAMPLES_CMAKEFILES_TXT}
 202   ${TESHSUITE_CMAKEFILES_TXT}
 203   ${TESTSUITE_CMAKEFILES_TXT}
 204   ${TOOLS_CMAKEFILES_TXT}
 205   ${DOC_FIGS}
 206   ${DOC_IMG}
 207   ${DOC_SOURCES}
 208   ${DOC_TOOLS}
 209   ${DOC_SHARED_TAG}
 210   ${REF_GUIDE_SOURCES}
 211   ${USER_GUIDE_SOURCES}
 212   ${DEV_GUIDE_SOURCES}
 213   ${PLATFORMS_EXAMPLES}
 214   ${README_files}
 215   ${bin_files}
 216   ${examples_src}
 217   ${tesh_files}
 218   ${teshsuite_src}
 219   ${testsuite_src}
 220   ${tools_src}
 221   ${txt_files}
 222   ${xml_files}
 223   )
 224
 225 ##########################################
 226 ### Fill in the "make dist-dir" target ###
 227 ##########################################
 228
 229 add_custom_target(dist-dir
 230   COMMENT "Generating the distribution directory"
 231   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 232   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 233   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 234   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/user_guide/html/
 235   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/ref_guide/html/
 236   COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_HOME_DIRECTORY}/doc/user_guide/html/ ${PROJECT_NAME}-${release_version}/doc/user_guide/html/
 237   COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_HOME_DIRECTORY}/doc/ref_guide/html/ ${PROJECT_NAME}-${release_version}/doc/ref_guide/html/
 238   )
 239 add_dependencies(dist-dir simgrid_documentation)
 240 add_dependencies(dist-dir maintainer_files)
 241
 242 set(dirs_in_tarball "")
 243 foreach(file ${source_to_pack})
 244   #message(${file})
 245   # This damn prefix is still set somewhere (seems to be in subdirs)
 246   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 247
 248   # Create the directory on need
 249   get_filename_component(file_location ${file} PATH)
 250   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 251   if(NOT OPERATION)
 252     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 253     add_custom_command(
 254       TARGET dist-dir
 255       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/
 256       )
 257   endif()
 258
 259   # Actually copy the file
 260   add_custom_command(
 261     TARGET dist-dir
 262     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location}/
 263     )
 264 endforeach(file ${source_to_pack})
 265
 266 add_custom_command(
 267   TARGET dist-dir
 268   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/buildtools/Cmake/Scripts/Makefile.default ${PROJECT_NAME}-${release_version}/Makefile
 269   )
 270
 271 ######################################
 272 ### Fill in the "make dist" target ###
 273 ######################################
 274
 275 add_custom_target(dist
 276   COMMENT "Removing the distribution directory"
 277   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 278   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 279   )
 280
 281 add_custom_command(
 282   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 283   COMMENT "Compressing the archive from the distribution directory"
 284   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 285   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 286   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 287   )
 288 add_dependencies(dist dist-dir)
 289
 290 if(NOT enable_maintainer_mode)
 291   add_custom_target(echo-dist
 292     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 293     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 294     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 295     )
 296   add_dependencies(dist echo-dist)
 297 endif()
 298
 299 ###########################################
 300 ### Fill in the "make distcheck" target ###
 301 ###########################################
 302
 303 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 304
 305 # Allow to test the "make dist"
 306 add_custom_target(distcheck
 307   COMMAND ${CMAKE_COMMAND} -E echo "XXX remove old copy"
 308   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 309
 310   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 311   COMMAND ${CMAKE_COMMAND} -E tar  xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 312
 313   COMMAND ${CMAKE_COMMAND} -E echo "XXX create build and install subtrees"
 314   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 315   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 316
 317   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 318   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 319   ${CMAKE_COMMAND}
 320   -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 321   -Denable_lua=ON
 322   -Denable_model-checking=ON
 323   ..
 324   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 325   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM}
 326
 327   COMMAND ${CMAKE_COMMAND} -E echo "XXX Test"
 328   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest || true
 329
 330   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 331   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 332   COMMAND ${CMAKE_COMMAND} -E create_symlink
 333   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgrid.so
 334   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgridtest.so
 335
 336   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 337   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 338   )
 339 #add_dependencies(distcheck dist)
 340
 341 #######################################
 342 ### Fill in the "make check" target ###
 343 #######################################
 344
 345 if(enable_memcheck)
 346   add_custom_target(check
 347     COMMAND ctest -D ExperimentalMemCheck
 348     )
 349 else()
 350   add_custom_target(check
 351     COMMAND make test
 352     )
 353 endif()
 354
 355 #######################################
 356 ### Fill in the "make xxx-clean" target ###
 357 #######################################
 358
 359 add_custom_target(maintainer-clean
 360   COMMAND ${CMAKE_COMMAND} -E remove -f src/config_unit.c
 361   COMMAND ${CMAKE_COMMAND} -E remove -f src/cunit_unit.c
 362   COMMAND ${CMAKE_COMMAND} -E remove -f src/dict_unit.c
 363   COMMAND ${CMAKE_COMMAND} -E remove -f src/dynar_unit.c
 364   COMMAND ${CMAKE_COMMAND} -E remove -f src/ex_unit.c
 365   COMMAND ${CMAKE_COMMAND} -E remove -f src/set_unit.c
 366   COMMAND ${CMAKE_COMMAND} -E remove -f src/simgrid_units_main.c
 367   COMMAND ${CMAKE_COMMAND} -E remove -f src/swag_unit.c
 368   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_sha_unit.c
 369   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_str_unit.c
 370   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_strbuff_unit.c
 371   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_synchro_unit.c
 372   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 373   )
 374
 375 add_custom_target(supernovae-clean
 376   COMMAND ${CMAKE_COMMAND} -E remove -f src/supernovae_sg.c
 377   COMMAND ${CMAKE_COMMAND} -E remove -f src/supernovae_smpi.c
 378   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 379   )
 380
 381
 382 include(CPack)