tools/cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 file(MAKE_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/html/)
   7 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/html/"
   8   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/html/)
   9 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/HelloWorld/"
  10   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/HelloWorld/)
  11
  12 # binaries
  13 if(enable_smpi)
  14   install(PROGRAMS
  15     ${CMAKE_BINARY_DIR}/bin/smpicc
  16     ${CMAKE_BINARY_DIR}/bin/smpicxx
  17     ${CMAKE_BINARY_DIR}/bin/smpirun
  18     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  19   if(SMPI_FORTRAN)
  20     install(PROGRAMS
  21       ${CMAKE_BINARY_DIR}/bin/smpif90
  22       ${CMAKE_BINARY_DIR}/bin/smpiff
  23       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  24   endif()
  25 endif()
  26
  27 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh
  28   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  29
  30 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/graphicator
  31   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  32
  33 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  34   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  35   RENAME simgrid-colorizer)
  36
  37 add_custom_target(simgrid-colorizer ALL
  38   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  39   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize
  40   )
  41
  42 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  43   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  44   RENAME simgrid_update_xml)
  45
  46 add_custom_target(simgrid_update_xml ALL
  47   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  48   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml
  49   )
  50
  51 # libraries
  52 install(TARGETS simgrid
  53   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  54
  55 if(enable_java)
  56   set(SIMGRID_JAR_TO_INSTALL "${SIMGRID_JAR}")
  57   install(TARGETS simgrid-java
  58       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  59   install(FILES ${SIMGRID_JAR_TO_INSTALL}
  60       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/java/
  61       RENAME simgrid.jar)
  62 endif()
  63
  64 # include files
  65 set(HEADERS
  66   ${headers_to_install}
  67   ${generated_headers_to_install}
  68   )
  69 foreach(file ${HEADERS})
  70   get_filename_component(location ${file} PATH)
  71   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  72   install(FILES ${file}
  73     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/${location})
  74 endforeach(file ${HEADERS})
  75
  76 # example files
  77 foreach(file ${examples_to_install})
  78   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  79   get_filename_component(location ${file} PATH)
  80   install(FILES "examples/${file}"
  81     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/examples/${location})
  82 endforeach(file ${examples_to_install})
  83
  84 ###########################################
  85 ### Fill in the "make uninstall" target ###
  86 ###########################################
  87
  88 add_custom_target(uninstall
  89   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/doc/simgrid
  90   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall doc ok"
  91   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsimgrid*
  92   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid*
  93   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall lib ok"
  94   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicc
  95   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicxx
  96   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpiff
  97   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif90
  98   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpirun
  99   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/tesh
 100   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid-colorizer
 101   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid_update_xml
 102   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/graphicator
 103   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall bin ok"
 104   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/instr
 105   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/msg
 106   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simdag
 107   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/smpi
 108   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simix
 109   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/surf
 110   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/xbt
 111   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/mc
 112   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simgrid
 113   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid.h
 114   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid_config.h
 115   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/xbt.h
 116   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall include ok"
 117   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/simgrid_update_xml.1
 118   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/tesh.1
 119   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpicc.1
 120   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpicxx.1
 121   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpirun.1
 122   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpiff.1
 123   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpif90.1
 124
 125
 126   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall man ok"
 127   WORKING_DIRECTORY "${CMAKE_INSTALL_PREFIX}"
 128   )
 129
 130 if(HAVE_LUA)
 131   add_custom_command(TARGET uninstall
 132     COMMAND ${CMAKE_COMMAND} -E echo "uninstall binding lua ok"
 133     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid.${LIB_EXE}
 134     WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}/"
 135     )
 136 endif()
 137
 138 ################################################################
 139 ## Build a sain "make dist" target to build a source package ###
 140 ##   containing only the files that I explicitely state      ###
 141 ##   (instead of any cruft laying on my disk as CPack does)  ###
 142 ################################################################
 143
 144 # This is the complete list of what will be added to the source archive
 145 set(source_to_pack
 146   ${headers_to_install}
 147   ${source_of_generated_headers}
 148   ${BINDINGS_SRC}
 149   ${JEDULE_SRC}
 150   ${JMSG_C_SRC}
 151   ${JMSG_JAVA_SRC}
 152   ${JSURF_SWIG_SRC}
 153   ${JSURF_SWIG_SRC_EXTRA}
 154   ${JSURF_C_SRC}
 155   ${LUA_SRC}
 156   ${MC_SRC_BASE}
 157   ${MC_SRC}
 158   ${MC_SIMGRID_MC_SRC}
 159   ${MSG_SRC}
 160   ${S4U_SRC}
 161   ${NS3_SRC}
 162   ${RNGSTREAM_SRC}
 163   ${SIMDAG_SRC}
 164   ${SIMGRID_SRC}
 165   ${SIMIX_SRC}
 166   ${SMPI_SRC}
 167   ${SURF_SRC}
 168   ${TRACING_SRC}
 169   ${XBT_RL_SRC}
 170   ${XBT_SRC}
 171   ${EXTRA_DIST}
 172   ${CMAKE_SOURCE_FILES}
 173   ${EXAMPLES_CMAKEFILES_TXT}
 174   ${TESHSUITE_CMAKEFILES_TXT}
 175   ${TOOLS_CMAKEFILES_TXT}
 176   ${DOC_FIGS}
 177   ${DOC_IMG}
 178   ${DOC_SOURCES}
 179   ${DOC_TOOLS}
 180   ${PLATFORMS_EXAMPLES}
 181   ${README_files}
 182   ${bin_files}
 183   ${examples_src}
 184   ${tesh_files}
 185   ${teshsuite_src}
 186   ${testsuite_src}
 187   ${tools_src}
 188   ${txt_files}
 189   ${xml_files}
 190   )
 191
 192 ##########################################
 193 ### Fill in the "make dist-dir" target ###
 194 ##########################################
 195
 196 add_custom_target(dist-dir
 197   COMMENT "Generating the distribution directory"
 198   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 199   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 200   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 201   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 202   COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_HOME_DIRECTORY}/doc/html/ ${PROJECT_NAME}-${release_version}/doc/html/
 203   )
 204 add_dependencies(dist-dir maintainer_files)
 205
 206 set(dirs_in_tarball "")
 207 foreach(file ${source_to_pack})
 208   #message(${file})
 209   # This damn prefix is still set somewhere (seems to be in subdirs)
 210   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 211
 212   # Create the directory on need
 213   get_filename_component(file_location ${file} PATH)
 214   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 215   if(NOT OPERATION)
 216     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 217     add_custom_command(
 218       TARGET dist-dir
 219       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/
 220       )
 221   endif()
 222
 223   # Actually copy the file
 224   add_custom_command(
 225     TARGET dist-dir
 226     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location}
 227     )
 228 endforeach(file ${source_to_pack})
 229
 230 add_custom_command(
 231   TARGET dist-dir
 232   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion
 233   )
 234
 235 ######################################
 236 ### Fill in the "make dist" target ###
 237 ######################################
 238
 239 add_custom_target(dist
 240   COMMENT "Removing the distribution directory"
 241   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 242   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 243   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 244   )
 245
 246 add_custom_command(
 247   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 248   COMMENT "Compressing the archive from the distribution directory"
 249   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 250   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 251   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 252   )
 253 add_dependencies(dist dist-dir)
 254
 255 if(NOT enable_maintainer_mode)
 256   add_custom_target(echo-dist
 257     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 258     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 259     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 260     )
 261   add_dependencies(dist echo-dist)
 262 endif()
 263
 264 ###########################################
 265 ### Fill in the "make distcheck" target ###
 266 ###########################################
 267
 268 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 269
 270 # Allow to test the "make dist"
 271 add_custom_target(distcheck
 272   COMMAND ${CMAKE_COMMAND} -E echo "XXX compare archive with git repository"
 273   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/internal/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 274
 275   COMMAND ${CMAKE_COMMAND} -E echo "XXX remove old copy"
 276   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 277
 278   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 279   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 280
 281   COMMAND ${CMAKE_COMMAND} -E echo "XXX create build and install subtrees"
 282   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 283   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 284
 285   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 286   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 287   ${CMAKE_COMMAND}
 288   -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 289   ..
 290   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 291   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM}
 292
 293   COMMAND ${CMAKE_COMMAND} -E echo "XXX Test"
 294   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure
 295
 296   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 297   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 298   COMMAND ${CMAKE_COMMAND} -E create_symlink
 299   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgrid.so
 300   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgridtest.so
 301
 302   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install with documentation"
 303   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 304
 305   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 306   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 307   )
 308 add_dependencies(distcheck dist)
 309
 310 #######################################
 311 ### Fill in the "make check" target ###
 312 #######################################
 313
 314 if(enable_memcheck)
 315   add_custom_target(check
 316     COMMAND ctest -D ExperimentalMemCheck
 317     )
 318 else()
 319   add_custom_target(check
 320     COMMAND make test
 321     )
 322 endif()
 323
 324 #######################################
 325 ### Fill in the "make xxx-clean" target ###
 326 #######################################
 327
 328 add_custom_target(maintainer-clean
 329   COMMAND ${CMAKE_COMMAND} -E remove -f src/config_unit.c
 330   COMMAND ${CMAKE_COMMAND} -E remove -f src/cunit_unit.c
 331   COMMAND ${CMAKE_COMMAND} -E remove -f src/dict_unit.c
 332   COMMAND ${CMAKE_COMMAND} -E remove -f src/dynar_unit.c
 333   COMMAND ${CMAKE_COMMAND} -E remove -f src/ex_unit.c
 334   COMMAND ${CMAKE_COMMAND} -E remove -f src/set_unit.c
 335   COMMAND ${CMAKE_COMMAND} -E remove -f src/simgrid_units_main.c
 336   COMMAND ${CMAKE_COMMAND} -E remove -f src/swag_unit.c
 337   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_sha_unit.c
 338   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_str_unit.c
 339   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_strbuff_unit.c
 340   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_synchro_unit.c
 341   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 342   )
 343
 344 include(CPack)