examples/cpp/CMakeLists.txt

   1
   2 # Regular examples: with only one source and tested with all factories by default
   3 #################################################################################
   4 ### Define the examples' specificities
   5
   6 set(_app-bittorrent_sources app-bittorrent/s4u-bittorrent.cpp app-bittorrent/s4u-bittorrent.hpp
   7                             app-bittorrent/s4u-peer.cpp app-bittorrent/s4u-peer.hpp
   8                             app-bittorrent/s4u-tracker.cpp app-bittorrent/s4u-tracker.hpp)
   9 set(_dht-chord_sources    dht-chord/s4u-dht-chord.cpp dht-chord/s4u-dht-chord.hpp dht-chord/s4u-dht-chord-node.cpp)
  10 set(_dht-kademlia_sources dht-kademlia/s4u-dht-kademlia.cpp dht-kademlia/s4u-dht-kademlia.hpp
  11                           dht-kademlia/node.cpp dht-kademlia/node.hpp
  12                           dht-kademlia/routing_table.cpp dht-kademlia/routing_table.hpp
  13                           dht-kademlia/answer.cpp dht-kademlia/answer.hpp dht-kademlia/message.hpp)
  14
  15 set(_actor-stacksize_factories "^thread") # Threads ignore modifications of the stack size
  16
  17 # The maestro-set example only works for threads and when not using windows.
  18 set(_maestro-set_factories "thread")
  19 if(WIN32)
  20   set(_maestro-set_disable 1)
  21 endif()
  22
  23 if(SIMGRID_HAVE_MC)
  24   # These tests timeout with threads, maybe because of dwarf parsing? not sure
  25   foreach(example mc-bugged1 mc-bugged2 mc-failing-assert mc-electric-fence)
  26      set(_${example}_factories "^thread") # Timeout
  27      add_dependencies(tests-mc s4u-${example})
  28   endforeach()
  29
  30   # Make all MC tests buildable together
  31   #foreach(example ) # no test to be build in any case
  32   #endforeach()
  33
  34   if(HAVE_C_STACK_CLEANER)
  35     add_executable       (s4u-mc-bugged1-liveness-cleaner-on  EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  36     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-on  simgrid)
  37     set_target_properties(s4u-mc-bugged1-liveness-cleaner-on  PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fstack-cleaner")
  38     add_dependencies(tests-mc s4u-mc-bugged1-liveness-cleaner-on)
  39
  40     add_executable       (s4u-mc-bugged1-liveness-cleaner-off EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  41     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-off simgrid)
  42     set_target_properties(s4u-mc-bugged1-liveness-cleaner-off PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fno-stack-cleaner")
  43     add_dependencies(tests-mc s4u-mc-bugged1-liveness-cleaner-off)
  44   endif()
  45
  46   # Model-checking liveness
  47   if(HAVE_UCONTEXT_CONTEXTS AND SIMGRID_PROCESSOR_x86_64)
  48     # liveness model-checking works only on 64bits (for now ...)
  49     set(_mc-bugged1-liveness_factories "ucontext") # Timeout
  50     add_dependencies(tests-mc s4u-mc-bugged1-liveness)
  51     set(_mc-bugged2-liveness_factories "ucontext") # Timeout
  52   else()
  53     set(_mc-bugged1-liveness_disable 1)
  54   endif()
  55
  56   # This example never ends, disable it for now
  57   set(_mc-bugged2-liveness_disable 1)
  58
  59   # This example hit the 5' timeout on CI, disable it for now
  60   #    ADD_TESH(s4u-mc-bugged1-liveness-visited-ucontext --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness
  61   #                                                      --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  62   #                                                      --cd ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness
  63   #                                                       ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh)
  64   IF(HAVE_C_STACK_CLEANER)
  65     add_dependencies(tests-mc s4u-mc-bugged1-liveness-stack-cleaner)
  66     # This test checks if the stack cleaner is making a difference:
  67     ADD_TEST(s4u-mc-bugged1-liveness-stack-cleaner ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
  68                                                    ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/
  69                                                    ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/)
  70   ENDIF()
  71
  72   if(enable_coverage)
  73     foreach (example mc-bugged1 mc-bugged2 mc-electric-fence mc-failing-assert)
  74       ADD_TEST(cover-${example} ${CMAKE_CURRENT_BINARY_DIR}/${example}/s4u-${example} ${CMAKE_HOME_DIRECTORY}/examples/platforms/model_checker_platform.xml)
  75     endforeach()
  76     ADD_TEST(cover-mc-bugged1-liveness ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness ${CMAKE_HOME_DIRECTORY}/examples/platforms/small_platform.xml 1 1001)
  77   endif()
  78
  79 else()
  80   foreach (example mc-bugged1 mc-bugged2  mc-centralized-mutex mc-failing-assert mc-electric-fence
  81                    mc-bugged1-liveness mc-bugged2-liveness)
  82     set(_${example}_disable 1)
  83   endforeach()
  84 endif()
  85
  86 if(NOT HAVE_GRAPHVIZ)
  87   set(_dag-from-dot_disable 1)
  88 endif()
  89
  90 if(NOT SIMGRID_HAVE_NS3)
  91   foreach (example network-ns3 network-ns3-wifi)
  92     set(_${example}_disable 1)
  93   endforeach()
  94 endif()
  95
  96 # Deal with each example
  97
  98 foreach (example activity-testany activity-waitany
  99                  actor-create actor-daemon actor-exiting actor-join actor-kill
 100                  actor-lifetime actor-migrate actor-suspend actor-yield actor-stacksize
 101                  app-bittorrent app-chainsend app-token-ring
 102                  comm-pingpong comm-ready comm-serialize comm-suspend comm-testany comm-wait comm-waitany comm-waitall comm-waituntil
 103                  comm-dependent comm-host2host comm-failure comm-throttling
 104                  cloud-capping cloud-migration cloud-simple
 105                  dag-comm dag-from-dax dag-from-dot dag-failure dag-io dag-scheduling dag-simple
 106                  dht-chord dht-kademlia
 107                  energy-exec energy-boot energy-link energy-vm energy-exec-ptask energy-wifi
 108                  engine-filtering engine-run-partial
 109                  exec-async exec-basic exec-dvfs exec-remote exec-waitany exec-waitfor exec-dependent exec-unassigned
 110                  exec-ptask-multicore exec-ptask-multicore-latency exec-cpu-nonlinear exec-cpu-factors exec-failure
 111                  maestro-set
 112                  mc-bugged1 mc-bugged1-liveness mc-bugged2 mc-bugged2-liveness mc-centralized-mutex mc-electric-fence mc-failing-assert
 113                  network-ns3 network-ns3-wifi network-wifi
 114                  io-async io-priority io-degradation io-file-system io-file-remote io-disk-raw io-dependent
 115                  platform-failures platform-profile platform-properties
 116                  plugin-host-load plugin-link-load plugin-prodcons
 117                  replay-comm replay-io
 118                  routing-get-clusters
 119                  synchro-barrier synchro-condition-variable synchro-condition-variable-waituntil synchro-mutex synchro-semaphore
 120                  clusters-multicpu network-factors network-nonlinear)
 121
 122   # Use default source file unless specified otherwise
 123   if(NOT DEFINED _${example}_sources)
 124     set(_${example}_sources ${example}/s4u-${example}.cpp)
 125   endif()
 126
 127   if(NOT DEFINED _${example}_disable)
 128     add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${_${example}_sources})
 129     add_dependencies     (tests s4u-${example})
 130     add_dependencies     (s4u-${example} platf_cpp)
 131     target_link_libraries(s4u-${example} simgrid)
 132     set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 133
 134     # Use default factories unless specified otherwise
 135     if(NOT DEFINED _${example}_factories)
 136       set(_${example}_factories "*")
 137     endif()
 138 #    message("Factories of ${example}: ${_${example}_factories}")
 139
 140     ADD_TESH_FACTORIES(s4u-${example} "${_${example}_factories}"
 141                                       --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 142                                       --setenv libdir=${CMAKE_BINARY_DIR}/lib
 143                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 144                                       --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 145                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 146                                       ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 147   else()
 148     message(STATUS "Example ${example} disabled, thus not compiled.")
 149     unset(_${example}_disable)
 150   endif()
 151
 152   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 153   foreach(file ${_${example}_sources})
 154     set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/${file})
 155   endforeach()
 156
 157   unset(_${example}_factories)
 158   unset(_${example}_sources)
 159 endforeach()
 160
 161
 162 # Specific examples
 163 ###################
 164
 165 # MASTERWORKERS EXAMPLE
 166 foreach(variant fun class)
 167   add_executable       (s4u-app-masterworkers-${variant} EXCLUDE_FROM_ALL app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 168   target_link_libraries(s4u-app-masterworkers-${variant} simgrid)
 169   set_target_properties(s4u-app-masterworkers-${variant} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-masterworkers)
 170   add_dependencies(tests s4u-app-masterworkers-${variant})
 171
 172   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 173 endforeach()
 174 set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers.tesh)
 175
 176 # The tests the parallel variant of of DHTs
 177
 178 if(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_PROCESSOR STREQUAL "i386" AND CMAKE_SIZEOF_VOID_P EQUAL 8)
 179   # Thread-local storage (TLS) is needed for parallel execution, but it doesn't
 180   # play well with Ucontexts on 64bit SunOS (at least on x86_64).
 181   set(parallel-factories "^ucontext")
 182 else()
 183   set(parallel-factories "*")
 184 endif()
 185
 186 foreach(example app-bittorrent app-masterworkers
 187                 dht-chord dht-kademlia
 188                 )
 189   ADD_TESH_FACTORIES(s4u-${example}-parallel "${parallel-factories}" --cfg contexts/nthreads:4 ${CONTEXTS_SYNCHRO}
 190                                              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 191                                              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 192                                              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 193                                              ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 194 endforeach()
 195
 196 # Examples not accepting factories
 197 ##################################
 198
 199 foreach (example exec-ptask trace-categories trace-masterworkers trace-platform trace-process-migration
 200                  trace-host-user-variables trace-link-user-variables trace-route-user-variables)
 201   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 202   target_link_libraries(s4u-${example} simgrid)
 203   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 204   add_dependencies(tests s4u-${example})
 205
 206   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 207   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 208
 209   ADD_TESH(s4u-${example} --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 210                           --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 211                           --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 212                           --cd ${CMAKE_CURRENT_BINARY_DIR}/${example}
 213                           ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 214 endforeach()
 215
 216 if (NOT enable_memcheck AND NOT WIN32)
 217   ADD_TESH(simix-breakpoint --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/comm-pingpong
 218                             --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 219                             ${CMAKE_CURRENT_SOURCE_DIR}/comm-pingpong/simix-breakpoint.tesh)
 220 endif()
 221
 222 # Add all extra files to the archive
 223 ####################################
 224 set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp        PARENT_SCOPE)
 225 set(tesh_files    ${tesh_files}   ${CMAKE_CURRENT_SOURCE_DIR}/comm-pingpong/simix-breakpoint.tesh
 226                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.tesh
 227                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh  PARENT_SCOPE)
 228 set(xml_files     ${xml_files}    ${CMAKE_CURRENT_SOURCE_DIR}/actor-create/s4u-actor-create_d.xml
 229                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-lifetime/s4u-actor-lifetime_d.xml
 230                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent_d.xml
 231                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers_d.xml
 232                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-scheduling/Montage_25.xml
 233                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord_d.xml
 234                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia_d.xml
 235                                   ${CMAKE_CURRENT_SOURCE_DIR}/io-file-remote/s4u-io-file-remote_d.xml
 236                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-failures/s4u-platform-failures_d.xml
 237                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split_d.xml
 238                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm_d.xml
 239                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io_d.xml
 240                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3hosts_2links_d.xml
 241                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links-timer_d.xml
 242                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links_d.xml
 243                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/crosstraffic_d.xml
 244                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/dogbone_d.xml
 245                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/onelink_d.xml
 246                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/one_cluster_d.xml                PARENT_SCOPE)
 247 set(bin_files     ${bin_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/generate.py
 248                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
 249                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/promela_bugged1_liveness
 250                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged2-liveness/promela_bugged2_liveness PARENT_SCOPE)
 251 set(txt_files     ${txt_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax/simple_dax_with_cycle.xml
 252                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax/smalldax.xml
 253                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot/dag.dot
 254                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot/dag_with_cycle.dot
 255                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p0.txt
 256                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p1.txt
 257                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm.txt
 258                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io.txt                  PARENT_SCOPE)