configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15 AM_PROG_GCJ
  16
  17 AM_INIT_AUTOMAKE([gnu -Wno-portability])
  18 AC_CONFIG_MACRO_DIR(acmacro)
  19 ACLOCAL="$ACLOCAL -I acmacro"
  20
  21 dnl Next few lines is a hack to prevent libtool checking for F77
  22 m4_undefine([AC_PROG_F77])
  23 m4_defun([AC_PROG_F77],[])
  24
  25 dnl We do build a proper DLL when using win32
  26 AC_LIBTOOL_WIN32_DLL
  27 AC_PROG_LIBTOOL
  28
  29 ###############
  30 ## System checks
  31 ##
  32 SG_CONFIGURE_PART([System checks...])
  33 AC_PROG_CC(xlC gcc cc)
  34 AM_SANITY_CHECK
  35 AC_PROG_MAKE_SET
  36 AC_CHECK_PRINTF_NULL
  37 AC_CHECK_VA_COPY
  38
  39 # Checks for header files.
  40 AC_HEADER_STDC
  41 AC_HEADER_TIME
  42 AC_CHECK_HEADERS([sys/socket.h \
  43                   sys/stat.h \
  44                   windows.h winsock.h winsock2.h \
  45                   sys/time.h \
  46                   errno.h unistd.h \
  47                   execinfo.h\
  48                   signal.h ])
  49 AC_CHECK_FUNCS([gettimeofday usleep \
  50                 getdtablesize \
  51                 sysconf\
  52                 readv\
  53                 popen\
  54                 signal\
  55                 getline])
  56
  57 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  58 AC_FUNC_SNPRINTF
  59 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  60 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  61 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  62
  63 # Checks for typedefs, structures, and compiler characteristics.
  64 AC_C_CONST
  65 AC_C_INLINE
  66 AC_TYPE_SIZE_T
  67
  68 ###################################
  69 ## SimGrid and GRAS specific checks
  70 ##
  71
  72 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  73 # Check architecture signature begin
  74 GRAS_ARCH
  75 # Check architecture signature end
  76 GRAS_CHECK_STRUCT_COMPACTION
  77
  78
  79 dnl ##
  80 dnl ##  CONTEXT IMPLEMENTATION
  81 dnl ##
  82
  83 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  84
  85 dnl #
  86 dnl #  1. determine possibilities
  87 dnl #
  88
  89 dnl #  check for MCSC method
  90 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  91
  92 dnl #  check for pthread method
  93 AC_CHECK_HEADERS([pthread.h])
  94 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  95
  96 dnl #
  97 dnl #  2. make a general decision
  98 dnl #
  99
 100 if test ".$mcsc" = .yes; then
 101    mcsc=yes
 102 elif test ".$pthread" = .yes; then
 103    pthread=yes
 104 else
 105     ac_header=windows.h
 106     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 107     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 108       windows_context=yes
 109     else
 110       AC_ERROR([no appropriate backend found])
 111     fi
 112 fi
 113
 114 dnl #
 115 dnl #  3. allow decision to be overridden by user
 116 dnl #
 117
 118 AC_MSG_CHECKING(what kind of backend should we use)
 119
 120 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 121 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
 122
 123 AC_ARG_WITH(context,
 124   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 125   with_context=auto)
 126
 127 if test "x$with_context$mcsc" = "xucontextno" ; then
 128   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 129 fi
 130
 131 case $with_context in
 132  ucontext) ;;
 133  pthread) ;;
 134  pthreads) ;;
 135  windows) ;;
 136  auto) with_context=ucontext;;
 137  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 138 esac
 139
 140 if test "x$with_context" = "xucontext" ; then
 141   if test ".$mcsc" = .yes; then
 142     AC_MSG_RESULT(found working ucontext. Great!)
 143     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
 144   else
 145     if test ".$windows_context" = .yes ; then
 146       AC_MSG_RESULT(use windows context portability layer.)
 147       with_context=windows
 148     else
 149       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 150       with_context=pthread
 151     fi
 152   fi
 153 fi
 154
 155 if test "x$with_context" = "xpthreads"; then
 156   with_context=pthread
 157 fi
 158 if test "x$with_context" = "xpthread"; then
 159   AC_CHECK_HEADERS([pthread.h])
 160   AC_CHECK_LIB(pthread,pthread_create,,
 161     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 162   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
 163   AC_MSG_RESULT(You have pthreads. Let's use them.)
 164 fi
 165
 166 dnl #
 167 dnl #  4. determine a few additional details
 168 dnl #
 169
 170 if test "x$with_context" = "xucontext" ; then
 171 dnl #  direction of stack grow
 172   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 173   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 174       PTH_STACK_GROWTH="down"
 175   else
 176       PTH_STACK_GROWTH="up"
 177   fi
 178   AC_SUBST(PTH_STACK_GROWTH)
 179
 180   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 181 fi
 182
 183 #########################################
 184 ## Check for libraries extra-dependencies
 185 ##
 186
 187 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 188
 189 SIMGRID_DEP=""
 190 GRAS_DEP=""
 191
 192 if test xpthread=xyes ; then
 193   # if the pthreads are usable
 194   if test "x$with_context" = "xpthread" ; then
 195     # if we use them to implement the xbt_context
 196     SIMGRID_DEP="-lpthread"
 197   fi
 198   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
 199   if test "x$with_context" != "xwindows" ; then
 200     GRAS_DEP="-lpthread"
 201   fi
 202 fi
 203
 204
 205 #########################################
 206 ## Build optional modules (gtnets)
 207 ##
 208 gtnets=no
 209 AC_ARG_WITH(gtnets,
 210   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
 211   gtnets_path="$withval",gtnets_path="no")
 212 if test "x$gtnets_path" = "xno" ; then
 213   AC_MSG_RESULT(Eventually you will come to GTNetS.)
 214 else
 215   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. ****)
 216   AC_MSG_CHECKING(for gtnets)
 217   AX_CXX_CHECK_LIB(gtnets,[Simulator::RunUntilNextCompletion],gtnets=yes, gtnets=no,-L$gtnets_path/lib)
 218
 219   if test "x$gtnets" = xyes ; then
 220     GTNETS_CFLAGS=-I$gtnets_path/include
 221     AC_SUBST([GTNETS_CFLAGS])
 222     GTNETS_LDFLAGS=-L$gtnets_path/lib
 223     AC_SUBST([GTNETS_LDFLAGS])
 224     SIMGRID_DEP="$SIMGRID_DEP $GTNETS_LDFLAGS"
 225     AC_MSG_RESULT(Found working gtnets library.)
 226     AC_DEFINE(HAVE_GTNETS, 1, [Indicates whether we have the GTNETS library or not])
 227   else
 228     AC_MSG_RESULT(Could not find any working gtnets library.)
 229   fi
 230 fi
 231 AM_CONDITIONAL(HAVE_GTNETS,test "x$gtnets" != xno)
 232
 233 #########################################
 234 ## Build optional modules (csdp)
 235 ##
 236 csdp=no
 237 AC_ARG_WITH(csdp,
 238   AS_HELP_STRING([--with-csdp], [Path to csdp installation (default to empty, ie not using csdp)]),
 239   csdp_path="$withval",csdp_path="no")
 240 if test "x$csdp_path" = "xno" ; then
 241   AC_MSG_RESULT(Eventually you will come to csdp.)
 242 else
 243   AC_MSG_RESULT(***** You have decided to use csdp. Let's check whether it works or not ****)
 244   AC_MSG_CHECKING(for csdp)
 245   AC_CHECK_LIB(sdp,easy_sdp, csdp_lib=yes, csdp_lib=no,-L$csdp_path/lib -llapack -lblas -lm)
 246   AC_CHECK_HEADER(declarations.h, csdp_header=yes, csdp_header=no,-I$csdp_path/include -I$csdp_path/include/csdp)
 247
 248   if test "x$csdp_lib = xyes" -a "x$csdp_header = xyes" ; then
 249      csdp=yes;
 250   else
 251      csdp=no;
 252   fi
 253   if test "x$csdp" = xyes; then
 254     CSDP_CFLAGS="-I$csdp_path/include -I$csdp_path/include/csdp"
 255     AC_SUBST([CSDP_CFLAGS])
 256     CSDP_LDFLAGS="-L$csdp_path/lib"
 257     AC_SUBST([CSDP_LDFLAGS])
 258     SIMGRID_DEP="$SIMGRID_DEP $CSDP_LDFLAGS -lsdp -llapack -lblas -lm"
 259     AC_MSG_RESULT(Found working sdp library.)
 260     AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 261   else
 262     AC_MSG_RESULT(Could not find any working sdp library.)
 263   fi;
 264 fi
 265 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 266
 267 AC_SUBST([SIMGRID_DEP])
 268
 269 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 270 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 271
 272 AC_MSG_CHECKING(for extra dependencies of libgras)
 273 case $host_os in
 274   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 275             AC_SUBST(AM_CFLAGS,-DDLL_EXPORT)
 276             AC_DEFINE(CONTEXT_THREADS,1);;
 277 esac
 278
 279 if test "x$GRAS_DEP" = x; then
 280    AC_MSG_RESULT(none)
 281 else
 282    AC_MSG_RESULT($GRAS_DEP)
 283 fi
 284 AC_SUBST([GRAS_DEP])
 285
 286 ##############################################
 287 ## Enhance maintainer mode and SUBST variables
 288 ## (must be placed after any compilation tests since our overprotective flags
 289 ##  let some tests fail)
 290
 291 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 292 # Next line is modified by sed when building gramine source tree
 293 gramine_mode=no
 294 if test x$gramine_mode = xyes
 295 then
 296   USE_MAINTAINER_MODE=no
 297 fi
 298 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 299
 300
 301 AM_MAINTAINER_MODE
 302 if test x$USE_MAINTAINER_MODE = xyes
 303 then
 304    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 305    enable_compile_warnings=yes
 306 fi
 307 SG_COMPILE_FLAGS
 308
 309 AC_SUBST(CFLAGS)
 310 AC_SUBST(CPPFLAGS)
 311 AC_SUBST(LDFLAGS)
 312 AC_SUBST([abs_builddir])
 313 AC_SUBST([abs_srcdir])
 314 AC_SUBST([abs_top_builddir])
 315 AC_SUBST([abs_top_srcdir])
 316
 317
 318
 319 SG_CONFIGURE_PART(Check for Java bindings...)
 320 # Java cruft
 321 AC_ARG_ENABLE(java,
 322               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
 323               want_java=$enableval,want_java=yes)
 324 if test "x$want_java" != "xyes" ; then
 325    AC_MSG_CHECKING(whether to compile java bindings)
 326    AC_MSG_RESULT(disabled by user)
 327    use_java="disabled by user"
 328 else
 329   AC_PATH_PROG([JAVAC], [javac], `which javac`)
 330   AC_PATH_PROG([JAVA],  [java] , `which java`)
 331   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
 332   AC_CHECK_HEADERS(jni.h)
 333   AC_MSG_CHECKING(whether to compile java bindings)
 334   if test -n "$JAVAC"   \
 335      && test -n "$JAVA" \
 336      && test -n "$JAR"  \
 337      && test "x$ac_cv_header_jni_h" = "xyes" ; then
 338
 339      use_java="yes"
 340   else
 341      use_java="no"
 342   fi
 343   AC_MSG_RESULT($use_java)
 344 fi
 345 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
 346
 347 #####################
 348 ## Check for programs
 349 ##
 350
 351 SG_CONFIGURE_PART(Check for programs...)
 352 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 353 WARNING="This file is generated, do not edit"
 354 AC_SUBST(WARNING)
 355
 356
 357 # Can we rebuild the parsers?
 358 # We really want flex and refuse other lex. So, the parser is portable and
 359 # does not induce extra lib dependency
 360 AC_PROG_FLEX(2.5.30)
 361
 362 # Can we rebuild the xml-lexers from the XML specification?
 363 # if not, simply touch the flex source files (which are distributed in
 364 #  tarballs even if generated by flexml) and hope for the best.
 365 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 366 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 367
 368 if test x$USE_MAINTAINER_MODE = xyes
 369 then
 370    # Check for doxygen when in maintainer mode since dist* targets fail
 371    # without it
 372    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 373    if test x$DOXYGEN = x ; then
 374      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 375    fi
 376 fi
 377
 378 # Can we extract really usable backtraces? (also need the popen function)
 379 AC_PATH_PROG(ADDR2LINE, addr2line)
 380 if test x$ADDR2LINE != x ; then
 381   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 382 fi
 383
 384 AC_SUBST(ac_configure_args)
 385 # Can we make status line about the compilation result?
 386 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 387 if test x$MD5SUM != xno ; then
 388   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 389                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 390 else
 391   build_version="no_md5sum_binary"
 392 fi
 393 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 394 AC_SUBST(build_id)
 395
 396 ###################
 397 ## Makes the output
 398 ##
 399
 400
 401 #
 402 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 403 #  src/amok/Makefile
 404
 405 SG_CONFIGURE_PART(Generating files...)
 406
 407 # Core of the libraries
 408
 409 AC_CONFIG_FILES([
 410   Makefile
 411   include/Makefile
 412   src/Makefile
 413   src/ucontext_stack.h
 414 ])
 415
 416 # Tools being embeeded in gramine (stub generator)
 417 AC_CONFIG_FILES([
 418   tools/Makefile
 419     tools/gras/Makefile
 420     tools/tesh/Makefile
 421 ])
 422
 423
 424 # GRAMINE_CUT_BEGIN
 425
 426 # Tools NOT being embeeded in gramine
 427 AC_CONFIG_FILES([
 428   tools/graspe-slave
 429 ],[
 430     for file in                                                 \
 431      tools/graspe-slave           tools/graspe-master           \
 432     ; do                                                        \
 433       test -e $file && chmod +x $file;                          \
 434     done
 435 ])
 436
 437 # Testsuite
 438
 439 AC_CONFIG_FILES([
 440   testsuite/Makefile
 441   testsuite/run_tests
 442   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 443 ],[
 444     for file in                                                 \
 445      testsuite/run_tests                                        \
 446      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 447     ; do                                                        \
 448       test -e $file && chmod +x $file;                          \
 449     done
 450 ])
 451
 452 # Documentation
 453 AC_CONFIG_FILES([
 454   doc/Makefile
 455   doc/Doxyfile
 456 ])
 457
 458 # Examples
 459
 460 #      examples/gras/p2p/Makefile
 461 #      examples/gras/p2p/chord/Makefile
 462 #      examples/gras/p2p/can/Makefile
 463
 464 if test "x$use_java" = "xyes" ; then
 465 AC_CONFIG_FILES([
 466     examples/java/Makefile
 467       examples/java/basic/Makefile
 468       examples/java/comm_time/Makefile
 469       examples/java/suspend/Makefile
 470       examples/java/ping_pong/Makefile
 471 ])
 472 fi
 473
 474 AC_CONFIG_FILES([
 475   examples/Makefile
 476     examples/msg/Makefile
 477     examples/simdag/Makefile        examples/simdag/test_simdag
 478     examples/gras/Makefile
 479       examples/gras/ping/Makefile
 480       examples/gras/rpc/Makefile
 481       examples/gras/spawn/Makefile
 482       examples/gras/synchro/Makefile
 483       examples/gras/timer/Makefile
 484       examples/gras/chrono/Makefile
 485       examples/gras/mutual_exclusion/simple_token/Makefile
 486       examples/gras/mmrpc/Makefile
 487       examples/gras/pmm/Makefile
 488       examples/gras/all2all/Makefile
 489     examples/amok/Makefile
 490       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 491       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 492 ],[
 493     for file in                                                 \
 494      \
 495      examples/simdag/test_simdag                                \
 496      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 497      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 498     ; do                                                        \
 499       test -e $file && chmod +x $file;                          \
 500     done
 501 ])
 502
 503
 504 # GRAMINE_CUT_END
 505
 506 AC_OUTPUT
 507
 508 echo "
 509
 510 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 511
 512         Compiler:        ${CC} (version: ${GCC_VERSION})
 513
 514         CFlags:          ${CFLAGS}
 515         CPPFlags:        ${CPPFLAGS}
 516         LDFlags:         ${LDFLAGS}
 517
 518         Context backend: ${with_context}
 519 "
 520
 521 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 522   echo "WARNING:"
 523   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 524   echo "WARNING: You won't be able to build archives that way (make dist is likely to fail). "
 525   echo "WARNING: If you want to enable the maintainer mode, juste specify it like this:"
 526   echo "WARNING:"
 527   echo "WARNING: ./configure '--enable-maintainer-mode' $ac_configure_args"
 528   echo "WARNING:"
 529 fi
 530 echo $build_id > stamp.configure
 531
 532 exit 0;