tools/cmake/Flags.cmake

   1 ##
   2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
   3 ##
   4 ##   It is only used for gcc and clang. MSVC builds don't load this file.
   5 ##
   6 ##   These flags do break some classical CMake tests, so you don't
   7 ##   want to do so before the very end of the configuration.
   8 ##
   9 ##   Other compiler flags (C/C++ standard version) are tested and set
  10 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
  11
  12 set(warnCFLAGS "")
  13 set(optCFLAGS "")
  14 set(warnCXXFLAGS "")
  15
  16 if(enable_compile_warnings)
  17   set(warnCFLAGS "-fno-common -Wall -Wextra -Wunused -Wmissing-declarations -Wpointer-arith -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
  18
  19   if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  20     # ignore remarks:
  21     # 191: type qualifier is meaningless on cast type
  22     # 1418: external function definition with no prior declaration
  23     # 2196: routine is both "inline" and "noinline"
  24     # 2651: attribute does not apply to any entity
  25     # 3179: deprecated conversion of string literal to char* (should be const char*)
  26     # set as warning:
  27     # 597: entity-kind "entity" will not be called for implicit or explicit conversions
  28     # 2330: argument of type "type" is incompatible with parameter of type "type" (dropping qualifiers)
  29     # 11003: no IR in object file xxxx; was the source file compiled with xxxx
  30     set(warnCFLAGS "${warnCFLAGS} -diag-disable=191,1418,2196,2651,3179 -diag-warning=597,2330,11003")
  31   endif()
  32   set(warnCXXFLAGS "${warnCFLAGS}")
  33
  34   if(CMAKE_COMPILER_IS_GNUCC)
  35     set(warnCFLAGS "${warnCFLAGS} -Wclobbered -Wformat-signedness -Wno-error=clobbered -Wno-unused-local-typedefs -Wno-error=attributes -Wno-error=maybe-uninitialized")
  36   endif()
  37
  38   if(CMAKE_COMPILER_IS_GNUCXX)
  39     set(warnCXXFLAGS "${warnCXXFLAGS} -Wclobbered -Wformat-signedness -Wno-error=clobbered -Wno-free-nonheap-object -Wno-unused-local-typedefs -Wno-error=attributes -Wno-error=maybe-uninitialized")
  40     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "8.0")
  41       # workaround for https://gcc.gnu.org/bugzilla/show_bug.cgi?id=81767
  42       set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-error=unused-variable")
  43     endif()
  44   endif()
  45
  46   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  47     # don't care about class that become struct, avoid issue of empty C structs
  48     # size (coming from libunwind.h)
  49     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-mismatched-tags -Wno-extern-c-compat")
  50     # also ignore deprecated builtins (seen with clang 15 + boost 1.79)
  51     if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL "15.0")
  52       set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-deprecated-builtins")
  53     endif()
  54   endif()
  55
  56   # the one specific to C but refused by C++
  57   set(warnCFLAGS "${warnCFLAGS} -Wmissing-prototypes")
  58
  59   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC|PGI")
  60     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
  61   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Flang")
  62     # flang >= 7 has a bug with common and debug flags. Ignore cmake-added -g in this case.
  63     # https://github.com/flang-compiler/flang/issues/671
  64     set(CMAKE_Fortran_FLAGS "-Wall")
  65   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
  66     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -warn all")
  67   endif()
  68   set(CMAKE_JAVA_COMPILE_FLAGS "-Xlint")
  69 endif()
  70
  71 # NDEBUG gives a lot of "initialized but unused variables" errors. Don't die anyway.
  72 if(enable_compile_warnings AND enable_debug)
  73   set(warnCFLAGS "${warnCFLAGS} -Werror")
  74   set(warnCXXFLAGS "${warnCXXFLAGS} -Werror")
  75   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC")
  76     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Werror -Werror=format-security")
  77   endif()
  78 endif()
  79
  80 # Activate the warnings on #if FOOBAR when FOOBAR has no value
  81 # It breaks on FreeBSD within Boost headers, so activate this only in Pure Hardcore debug mode.
  82 if(enable_maintainer_mode)
  83   set(warnCFLAGS "${warnCFLAGS} -Wundef")
  84   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wundef")
  85 endif()
  86
  87 # Se the optimisation flags
  88 # NOTE, we should CMAKE_BUILD_TYPE for this
  89 if(enable_compile_optimizations)
  90   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
  91 else()
  92   set(optCFLAGS "-O0 ")
  93 endif()
  94
  95 #ARM platforms have signed char by default, switch to unsigned for consistancy
  96 if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "aarch64")
  97   set(optCFLAGS "${optCFLAGS} -fsigned-char")
  98 endif()
  99
 100 if(enable_compile_optimizations AND CMAKE_COMPILER_IS_GNUCC
 101     AND (NOT enable_model-checking))
 102   # This is redundant (already in -03):
 103   set(optCFLAGS "${optCFLAGS} -finline-functions ")
 104 endif()
 105
 106 # Do not leak the current directory into the binaries
 107 if(CMAKE_COMPILER_IS_GNUCC AND NOT enable_coverage)
 108   execute_process(COMMAND realpath --relative-to=${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}
 109     RESULT_VARIABLE RESULT OUTPUT_VARIABLE RELATIVE_SOURCE_DIR ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
 110   if(RESULT EQUAL 0)
 111     message(STATUS "Relative source directory is \"${RELATIVE_SOURCE_DIR}\".")
 112   else()
 113     message(WARNING "Failed to find relative source directory. Using \".\".")
 114     set(RELATIVE_SOURCE_DIR ".")
 115   endif()
 116   if (CMAKE_C_COMPILER_VERSION VERSION_LESS "8.0")
 117     set(optCFLAGS "${optCFLAGS} -fdebug-prefix-map=\"${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}\"")
 118   else()
 119     set(optCFLAGS "${optCFLAGS} -ffile-prefix-map=\"${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}\"")
 120   endif()
 121 endif()
 122
 123 # Configure LTO
 124 if(enable_lto) # User wants LTO. Try if we can do that
 125   set(enable_lto OFF)
 126   if(enable_compile_optimizations
 127       AND (NOT enable_model-checking))
 128     if(CMAKE_VERSION VERSION_LESS "3.9")
 129       if ( CMAKE_COMPILER_IS_GNUCC
 130          AND (CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8.5")
 131          AND (LINKER_VERSION VERSION_GREATER "2.22"))
 132         set(enable_lto ON)
 133       endif()
 134     else()
 135       include(CheckIPOSupported)
 136       check_ipo_supported(RESULT ipo LANGUAGES C CXX)
 137       if(ipo)
 138         set(enable_lto ON)
 139       endif()
 140     endif()
 141   endif()
 142
 143   if(enable_lto)
 144     message(STATUS "LTO seems usable.")
 145   else()
 146     if(NOT enable_compile_optimizations)
 147       message(STATUS "LTO disabled: Compile-time optimizations turned off.")
 148     else()
 149       if(enable_model-checking)
 150         message(STATUS "LTO disabled when compiling with model-checking.")
 151       else()
 152         message(STATUS "LTO does not seem usable -- try updating your build chain.")
 153       endif()
 154     endif()
 155   endif()
 156 else()
 157   message(STATUS "LTO disabled on the command line.")
 158 endif()
 159 if(enable_lto) # User wants LTO, and it seems usable. Go for it
 160   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
 161   if(LTO_EXTRA_FLAG AND CMAKE_COMPILER_IS_GNUCC)
 162     list(APPEND CMAKE_C_COMPILE_OPTIONS_IPO "-flto=${LTO_EXTRA_FLAG}")
 163     list(APPEND CMAKE_CXX_COMPILE_OPTIONS_IPO "-flto=${LTO_EXTRA_FLAG}")
 164   endif()
 165
 166   # Activate fat-lto-objects in case LD and gfortran differ too much.
 167   # Only test with GNU as it's the only case I know (clang+gfortran+lld)
 168   execute_process(COMMAND ${CMAKE_LINKER} -v OUTPUT_VARIABLE LINKER_ID ERROR_VARIABLE LINKER_ID)
 169   string(REGEX MATCH "GNU" LINKER_ID "${LINKER_ID}")
 170   if(${CMAKE_Fortran_COMPILER_ID} MATCHES "GNU"
 171      AND NOT "${LINKER_ID}" MATCHES "GNU")
 172        list(APPEND CMAKE_Fortran_COMPILE_OPTIONS_IPO "-ffat-lto-objects")
 173   endif()
 174
 175   # "Since version 4.9 gcc produces slim object files that only contain
 176   # the intermediate representation. In order to handle archives of
 177   # these objects you have to use the gcc wrappers:
 178   # gcc-ar, gcc-nm and gcc-ranlib."
 179   if(${CMAKE_C_COMPILER_ID} STREQUAL "GNU"
 180       AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8")
 181     set (CMAKE_AR gcc-ar)
 182     set (CMAKE_RANLIB gcc-ranlib)
 183   endif()
 184 endif()
 185
 186 if(enable_model-checking AND enable_compile_optimizations)
 187   # Forget it, do not optimize the code (because it confuses the MC):
 188   set(optCFLAGS "-O0")
 189   # But you can still optimize this:
 190   set(src_list ${simgrid_sources})
 191   # except...
 192   list(REMOVE_ITEM src_list ${SIMIX_SRC} ${S4U_SRC})
 193   # but...
 194   list(APPEND src_list
 195     src/kernel/actor/Simcall.cpp)
 196   foreach(src ${src_list})
 197       set (mcCFLAGS "-O3 -funroll-loops -fno-strict-aliasing")
 198       if(CMAKE_COMPILER_IS_GNUCC)
 199         set (mcCFLAGS "${mcCFLAGS} -finline-functions")
 200       endif()
 201       set_source_files_properties(${src} PROPERTIES COMPILE_FLAGS ${mcCFLAGS})
 202   endforeach()
 203 endif()
 204
 205 if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 206   # honor parentheses when determining the order of expression evaluation.
 207   # disallow optimizations for floating-point arithmetic with Nans or +-Infs (breaks Eigen3)
 208   set(optCFLAGS "${optCFLAGS} -fprotect-parens -fno-finite-math-only")
 209 endif()
 210
 211 if(NOT enable_debug)
 212   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
 213   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
 214 endif()
 215
 216 set(CMAKE_C_FLAGS   "${warnCFLAGS} ${CMAKE_C_FLAGS}   ${optCFLAGS}")
 217 set(CMAKE_CXX_FLAGS "${warnCXXFLAGS} ${CMAKE_CXX_FLAGS} ${optCFLAGS}")
 218
 219 # Try to make Mac a bit more compliant to open source standards
 220 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 221   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 222 endif()
 223
 224 # Avoid a failure seen with gcc 7.2.0 and ns3 3.27
 225 if(enable_ns3)
 226   set_source_files_properties(src/surf/network_ns3.cpp PROPERTIES COMPILE_FLAGS " -Wno-unused-local-typedef")
 227 endif()
 228
 229 set(TESH_OPTION "")
 230 if(enable_coverage)
 231   find_program(GCOV_PATH NAMES ENV{GCOV} gcov)
 232   if(GCOV_PATH)
 233     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE FILEPATH "Coverage testing tool (gcov)" FORCE)
 234     set(COVERAGE_BUILD_FLAGS "-fprofile-arcs -ftest-coverage -fprofile-abs-path")
 235     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE ${COVERAGE_BUILD_FLAGS}")
 236     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${COVERAGE_BUILD_FLAGS}")
 237     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} ${COVERAGE_BUILD_FLAGS}")
 238     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCOVERAGE ${COVERAGE_BUILD_FLAGS}")
 239     add_definitions(${COVERAGE_BUILD_FLAGS})
 240   endif()
 241 endif()
 242
 243 if(enable_address_sanitizer)
 244     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 245     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 246     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=address")
 247     set(TESH_OPTION --enable-sanitizers)
 248     try_compile(HAVE_SANITIZER_ADDRESS ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp)
 249     try_compile(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp
 250       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 251 else()
 252     set(HAVE_SANITIZER_ADDRESS FALSE CACHE INTERNAL "")
 253     set(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 254 endif()
 255
 256 if(enable_thread_sanitizer)
 257     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 258     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 259     if(CMAKE_COMPILER_IS_GNUCXX AND (NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "12.0")))
 260         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=tsan")
 261     endif()
 262     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=thread -no-pie")
 263     try_compile(HAVE_SANITIZER_THREAD ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp)
 264     try_compile(HAVE_SANITIZER_THREAD_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp
 265       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 266 else()
 267     set(HAVE_SANITIZER_THREAD FALSE CACHE INTERNAL "")
 268     set(HAVE_SANITIZER_THREAD_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 269 endif()
 270
 271 if(enable_undefined_sanitizer)
 272     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 273     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 274     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=undefined")
 275 endif()
 276
 277 if(NOT $ENV{CFLAGS} STREQUAL "")
 278   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
 279   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
 280 endif()
 281
 282 if(NOT $ENV{CXXFLAGS} STREQUAL "")
 283   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
 284   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
 285 endif()
 286
 287 if(NOT $ENV{LDFLAGS} STREQUAL "")
 288   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
 289   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
 290 endif()
 291
 292 if(MINGW)
 293   # http://stackoverflow.com/questions/10452262/create-64-bit-jni-under-windows
 294   # We don't want to ship libgcc_s_seh-1.dll nor libstdc++-6.dll
 295   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -static-libgcc")
 296   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -static-libgcc -static-libstdc++")
 297   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS   "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -static-libgcc")
 298   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -static-libgcc -static-libstdc++")
 299
 300   # JNI searches for stdcalls
 301   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -Wl,--add-stdcall-alias")
 302   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wl,--add-stdcall-alias")
 303   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -Wl,--add-stdcall-alias")
 304   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -Wl,--add-stdcall-alias")
 305
 306   # Specify the data model that we are using (yeah it may help Java)
 307   if(CMAKE_SIZEOF_VOID_P EQUAL 4) # 32 bits
 308     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m32")
 309     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 310   else()
 311     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m64")
 312     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m64")
 313   endif()
 314 endif()