tools/cmake/Flags.cmake

   1 ##
   2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
   3 ##
   4 ##   It is only used for gcc, clang and Intel compilers.
   5 ##
   6 ##   These flags do break some classical CMake tests, so you don't
   7 ##   want to do so before the very end of the configuration.
   8 ##
   9 ##   Other compiler flags (C/C++ standard version) are tested and set
  10 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
  11
  12 set(warnCFLAGS "")
  13 set(optCFLAGS "")
  14 set(warnCXXFLAGS "")
  15
  16 if(enable_compile_warnings)
  17   set(warnCFLAGS "-fno-common -Wall -Wextra -Wunused -Wmissing-declarations -Wpointer-arith -Wwrite-strings -Wno-unused-function -Wno-unused-local-typedefs -Wno-unused-parameter -Wno-strict-aliasing")
  18
  19   if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  20     # ignore remarks:
  21     # 191: type qualifier is meaningless on cast type
  22     # 1418: external function definition with no prior declaration
  23     # 2196: routine is both "inline" and "noinline"
  24     # 2651: attribute does not apply to any entity
  25     # 3179: deprecated conversion of string literal to char* (should be const char*)
  26     # set as warning:
  27     # 597: entity-kind "entity" will not be called for implicit or explicit conversions
  28     # 2330: argument of type "type" is incompatible with parameter of type "type" (dropping qualifiers)
  29     # 11003: no IR in object file xxxx; was the source file compiled with xxxx
  30     set(warnCFLAGS "${warnCFLAGS} -diag-disable=191,1418,2196,2651,3179 -diag-warning=597,2330,11003")
  31   endif()
  32   set(warnCXXFLAGS "${warnCFLAGS}")
  33
  34   if(CMAKE_COMPILER_IS_GNUCC)
  35     set(warnCFLAGS "${warnCFLAGS} -Wclobbered -Wformat-signedness -Wno-error=clobbered -Wno-error=attributes -Wno-error=maybe-uninitialized")
  36   endif()
  37
  38   if(CMAKE_COMPILER_IS_GNUCXX)
  39     set(warnCXXFLAGS "${warnCXXFLAGS} -Wclobbered -Wformat-signedness -Wno-error=clobbered -Wno-free-nonheap-object -Wno-unused-local-typedefs -Wno-error=attributes -Wno-error=maybe-uninitialized")
  40     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "8.0")
  41       # workaround for https://gcc.gnu.org/bugzilla/show_bug.cgi?id=81767
  42       set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-error=unused-variable")
  43     endif()
  44   endif()
  45
  46   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  47     # don't care about class that become struct, avoid issue of empty C structs
  48     # size (coming from libunwind.h)
  49     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-mismatched-tags -Wno-extern-c-compat")
  50     # also ignore deprecated builtins (seen with clang 15 + boost 1.79)
  51     if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL "15.0")
  52       set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-deprecated-builtins")
  53     endif()
  54   endif()
  55
  56   # the one specific to C but refused by C++
  57   set(warnCFLAGS "${warnCFLAGS} -Wmissing-prototypes")
  58
  59   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC|PGI")
  60     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
  61   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Flang")
  62     # flang >= 7 has a bug with common and debug flags. Ignore cmake-added -g in this case.
  63     # https://github.com/flang-compiler/flang/issues/671
  64     set(CMAKE_Fortran_FLAGS "-Wall")
  65   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
  66     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -warn all")
  67   endif()
  68 endif()
  69
  70 # NDEBUG gives a lot of "initialized but unused variables" errors. Don't die anyway.
  71 if(enable_compile_warnings AND enable_debug)
  72   set(warnCFLAGS "${warnCFLAGS} -Werror")
  73   set(warnCXXFLAGS "${warnCXXFLAGS} -Werror")
  74   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC")
  75     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Werror -Werror=format-security")
  76   endif()
  77 endif()
  78
  79 # Activate the warnings on #if FOOBAR when FOOBAR has no value
  80 if("${CMAKE_SYSTEM}" MATCHES "Linux") # Breaks on FreeBSD within Boost headers :(
  81   set(warnCFLAGS "${warnCFLAGS} -Wundef")
  82   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wundef")
  83 endif()
  84
  85 # Set the optimisation flags
  86 # NOTE, we should CMAKE_BUILD_TYPE for this
  87 if(enable_compile_optimizations)
  88   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
  89 else()
  90   set(optCFLAGS "-O0 ")
  91 endif()
  92
  93 # ARM platforms have signed char by default, switch to unsigned for consistancy
  94 if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "aarch64")
  95   set(optCFLAGS "${optCFLAGS} -fsigned-char")
  96 endif()
  97
  98 if(enable_compile_optimizations AND CMAKE_COMPILER_IS_GNUCC)
  99   # This is redundant (already in -03):
 100   set(optCFLAGS "${optCFLAGS} -finline-functions ")
 101 endif()
 102
 103 # Do not leak the current directory into the binaries
 104 if(CMAKE_COMPILER_IS_GNUCC AND NOT enable_coverage)
 105   if (CMAKE_VERSION VERSION_LESS "3.20")
 106     file(RELATIVE_PATH RELATIVE_SOURCE_DIR ${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR})
 107   else() # cmake >= 3.20
 108     cmake_path(RELATIVE_PATH CMAKE_SOURCE_DIR BASE_DIRECTORY ${CMAKE_BINARY_DIR} OUTPUT_VARIABLE RELATIVE_SOURCE_DIR)
 109   endif()
 110   message(STATUS "Relative source directory is \"${RELATIVE_SOURCE_DIR}\".")
 111   if (CMAKE_C_COMPILER_VERSION VERSION_LESS "8.0")
 112     set(optCFLAGS "${optCFLAGS} -fdebug-prefix-map=\"${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}\"")
 113   else()
 114     set(optCFLAGS "${optCFLAGS} -ffile-prefix-map=\"${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}\"")
 115   endif()
 116 endif()
 117
 118 # Configure LTO
 119 if(enable_lto) # User wants LTO. Try if we can do that
 120   set(enable_lto OFF)
 121   if(enable_compile_optimizations)
 122     include(CheckIPOSupported)
 123     check_ipo_supported(RESULT ipo LANGUAGES C CXX)
 124     if(ipo)
 125       set(enable_lto ON)
 126     endif()
 127   endif()
 128
 129   if(enable_lto)
 130     message(STATUS "LTO seems usable.")
 131   else()
 132     if(NOT enable_compile_optimizations)
 133       message(STATUS "LTO disabled: Compile-time optimizations turned off.")
 134     else()
 135       message(STATUS "LTO does not seem usable -- try updating your build chain.")
 136     endif()
 137   endif()
 138 else()
 139   message(STATUS "LTO disabled on the command line.")
 140 endif()
 141 if(enable_lto) # User wants LTO, and it seems usable. Go for it
 142   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
 143   if(LTO_EXTRA_FLAG AND CMAKE_COMPILER_IS_GNUCC)
 144     list(APPEND CMAKE_C_COMPILE_OPTIONS_IPO "-flto=${LTO_EXTRA_FLAG}")
 145     list(APPEND CMAKE_CXX_COMPILE_OPTIONS_IPO "-flto=${LTO_EXTRA_FLAG}")
 146   endif()
 147
 148   # Activate fat-lto-objects in case LD and gfortran differ too much.
 149   # Only test with GNU as it's the only case I know (clang+gfortran+lld)
 150   execute_process(COMMAND ${CMAKE_LINKER} -v OUTPUT_VARIABLE LINKER_ID ERROR_VARIABLE LINKER_ID)
 151   string(REGEX MATCH "GNU" LINKER_ID "${LINKER_ID}")
 152   if(${CMAKE_Fortran_COMPILER_ID} MATCHES "GNU"
 153      AND NOT "${LINKER_ID}" MATCHES "GNU")
 154        list(APPEND CMAKE_Fortran_COMPILE_OPTIONS_IPO "-ffat-lto-objects")
 155   endif()
 156
 157   # "Since version 4.9 gcc produces slim object files that only contain
 158   # the intermediate representation. In order to handle archives of
 159   # these objects you have to use the gcc wrappers:
 160   # gcc-ar, gcc-nm and gcc-ranlib."
 161   if(${CMAKE_C_COMPILER_ID} STREQUAL "GNU"
 162       AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8")
 163     set (CMAKE_AR gcc-ar)
 164     set (CMAKE_RANLIB gcc-ranlib)
 165   endif()
 166 endif()
 167
 168 if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 169   # honor parentheses when determining the order of expression evaluation.
 170   # disallow optimizations for floating-point arithmetic with Nans or +-Infs (breaks Eigen3)
 171   set(optCFLAGS "${optCFLAGS} -fprotect-parens -fno-finite-math-only")
 172 endif()
 173
 174 if(NOT enable_debug)
 175   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
 176   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
 177 endif()
 178
 179 set(CMAKE_C_FLAGS   "${warnCFLAGS} ${CMAKE_C_FLAGS}   ${optCFLAGS}")
 180 set(CMAKE_CXX_FLAGS "${warnCXXFLAGS} ${CMAKE_CXX_FLAGS} ${optCFLAGS}")
 181
 182 # Try to make Mac a bit more compliant to open source standards
 183 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 184   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 185 endif()
 186
 187 set(TESH_OPTION "")
 188 if(enable_coverage)
 189   find_program(GCOV_PATH NAMES ENV{GCOV} gcov)
 190   if(GCOV_PATH)
 191     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE FILEPATH "Coverage testing tool (gcov)" FORCE)
 192     set(COVERAGE_BUILD_FLAGS "-fprofile-arcs -ftest-coverage -fprofile-abs-path")
 193     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE ${COVERAGE_BUILD_FLAGS}")
 194     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${COVERAGE_BUILD_FLAGS}")
 195     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} ${COVERAGE_BUILD_FLAGS}")
 196     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCOVERAGE ${COVERAGE_BUILD_FLAGS}")
 197     add_definitions(${COVERAGE_BUILD_FLAGS})
 198   endif()
 199 endif()
 200
 201 if(enable_address_sanitizer)
 202     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 203     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 204     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=address")
 205     set(TESH_OPTION --enable-sanitizers)
 206     try_compile(HAVE_SANITIZER_ADDRESS ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp)
 207     try_compile(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp
 208       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 209 else()
 210     set(HAVE_SANITIZER_ADDRESS FALSE CACHE INTERNAL "")
 211     set(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 212 endif()
 213
 214 if(enable_thread_sanitizer)
 215     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 216     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 217     if(CMAKE_COMPILER_IS_GNUCXX AND (NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "12.0")))
 218         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=tsan")
 219     endif()
 220     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=thread -no-pie")
 221     try_compile(HAVE_SANITIZER_THREAD ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp)
 222     try_compile(HAVE_SANITIZER_THREAD_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp
 223       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 224 else()
 225     set(HAVE_SANITIZER_THREAD FALSE CACHE INTERNAL "")
 226     set(HAVE_SANITIZER_THREAD_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 227 endif()
 228
 229 if(enable_undefined_sanitizer)
 230     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 231     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 232     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=undefined")
 233 endif()
 234
 235 if(NOT $ENV{CFLAGS} STREQUAL "")
 236   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
 237   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
 238 endif()
 239
 240 if(NOT $ENV{CXXFLAGS} STREQUAL "")
 241   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
 242   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
 243 endif()
 244
 245 if(NOT $ENV{LDFLAGS} STREQUAL "")
 246   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
 247   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
 248 endif()