tools/cmake/Java.cmake

   1 ##
   2 ## The Cmake definitions for the use of Java (and Scala)
   3 ##   This file is loaded only if the Java option is activated
   4 ##
   5
   6 cmake_minimum_required(VERSION 2.8.6)
   7
   8 find_package(Java 1.7 REQUIRED)
   9 include(UseJava)
  10
  11 # Rules to build libsimgrid-java
  12 #
  13 add_library(simgrid-java SHARED ${JMSG_C_SRC})
  14 set_target_properties(simgrid-java PROPERTIES VERSION ${libsimgrid-java_version})
  15 if (CMAKE_VERSION VERSION_LESS "2.8.8")
  16   include_directories(${JNI_INCLUDE_DIRS})
  17
  18   message("[Java] Try to workaround missing feature in older CMake. You should better update CMake to version 2.8.8 or above.")
  19   get_directory_property(CHECK_INCLUDES INCLUDE_DIRECTORIES)
  20 else()
  21   get_target_property(COMMON_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  22   if (COMMON_INCLUDES)
  23     set_target_properties(simgrid-java PROPERTIES
  24       INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  25   else()
  26     set_target_properties(simgrid-java PROPERTIES
  27       INCLUDE_DIRECTORIES "${JNI_INCLUDE_DIRS}")
  28   endif()
  29
  30   get_target_property(CHECK_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  31 endif()
  32 message("-- [Java] simgrid-java includes: ${CHECK_INCLUDES}")
  33
  34 target_link_libraries(simgrid-java simgrid)
  35
  36
  37 if(WIN32)
  38   exec_program("java -d32 -version"
  39                 OUTPUT_VARIABLE IS_32_BITS_JVM)
  40   STRING( FIND ${IS_32_BITS_JVM} "Error" POSITION )
  41   if(${POSITION} GREATER -1)
  42     message("POTENTIAL ERROR: Java JVM needs to be 32 bits to be able to run with Simgrid on Windows for now")
  43   endif()
  44
  45   set_target_properties(simgrid-java PROPERTIES
  46     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at")
  47 endif()
  48
  49 # Rules to build simgrid.jar
  50 #
  51
  52 ## Files to include in simgrid.jar
  53 ##
  54 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  55 set(MANIFEST_IN_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF.in")
  56 set(MANIFEST_FILE "${CMAKE_BINARY_DIR}/src/bindings/java/MANIFEST.MF")
  57
  58 set(LIBSIMGRID_SO
  59   libsimgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  60 set(LIBSIMGRID_JAVA_SO
  61   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  62 set(LIBSURF_JAVA_SO
  63   ${CMAKE_SHARED_LIBRARY_PREFIX}surf-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  64
  65 ## Here is how to build simgrid.jar
  66 ##
  67 if(CMAKE_VERSION VERSION_LESS "2.8.12")
  68   set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  69   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC})
  70 else()
  71   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC} OUTPUT_NAME simgrid)
  72 endif()
  73
  74 add_custom_command(
  75   TARGET simgrid-java_jar POST_BUILD
  76   COMMENT "Add the documentation into simgrid.jar..."
  77   DEPENDS ${MANIFEST_IN_FILE}
  78           ${CMAKE_HOME_DIRECTORY}/COPYING
  79           ${CMAKE_HOME_DIRECTORY}/ChangeLog
  80           ${CMAKE_HOME_DIRECTORY}/NEWS
  81           ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  82           ${CMAKE_HOME_DIRECTORY}/LICENSE-LGPL-2.1
  83
  84   COMMAND ${CMAKE_COMMAND} -E copy ${MANIFEST_IN_FILE} ${MANIFEST_FILE}
  85   COMMAND ${CMAKE_COMMAND} -E echo "Specification-Version: \\\"${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}\\\"" >> ${MANIFEST_FILE}
  86   COMMAND ${CMAKE_COMMAND} -E echo "Implementation-Version: \\\"${GIT_VERSION}\\\"" >> ${MANIFEST_FILE}
  87
  88   COMMAND ${Java_JAVADOC_EXECUTABLE} -quiet -d doc/javadoc -sourcepath ${CMAKE_HOME_DIRECTORY}/src/bindings/java/ org.simgrid.msg org.simgrid.surf org.simgrid.trace
  89
  90   COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} doc/javadoc -C ${CMAKE_HOME_DIRECTORY} COPYING ChangeLog ChangeLog.SimGrid-java LICENSE-LGPL-2.1 NEWS
  91   )
  92
  93 ###
  94 ### Pack the java libraries into the jarfile if asked to do so
  95 ###
  96
  97 if(enable_lib_in_jar)
  98   find_program(STRIP_COMMAND strip)
  99   if(NOT STRIP_COMMAND)
 100     set(STRIP_COMMAND "cmake -E echo (strip not found)")
 101   endif()
 102   if(WIN32)
 103     set(STRIP_COMMAND "cmake -E echo (dont strip on windows)")
 104   endif()
 105
 106   set(JAVA_NATIVE_PATH NATIVE/${CMAKE_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR})
 107   if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "^i[3-6]86$")
 108     set(JAVA_NATIVE_PATH NATIVE/${CMAKE_SYSTEM_NAME}/x86)
 109   endif()
 110   if(  (${CMAKE_SYSTEM_PROCESSOR} MATCHES "x86_64") OR
 111        (${CMAKE_SYSTEM_PROCESSOR} MATCHES "AMD64")     )
 112     set(JAVA_NATIVE_PATH NATIVE/${CMAKE_SYSTEM_NAME}/amd64)
 113   endif()
 114
 115   add_custom_command(
 116     TARGET simgrid-java_jar POST_BUILD
 117     COMMENT "Add the native libs into simgrid.jar..."
 118     DEPENDS simgrid-java
 119             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 120             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO}
 121             ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}
 122
 123     COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 124     COMMAND ${CMAKE_COMMAND} -E make_directory                                     ${JAVA_NATIVE_PATH}
 125     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}      ${JAVA_NATIVE_PATH}
 126     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO} ${JAVA_NATIVE_PATH}
 127     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}    ${JAVA_NATIVE_PATH}
 128
 129     # strip seems to fail on Mac on binaries that are already stripped.
 130     # It then spits: "symbols referenced by indirect symbol table entries that can't be stripped"
 131     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_SO}      || true
 132     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_JAVA_SO} || true
 133     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSURF_JAVA_SO}    || true
 134
 135     COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 136     COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 137
 138     COMMAND ${CMAKE_COMMAND} -E echo "-- Cmake put the native code in ${JAVA_NATIVE_PATH}"
 139     COMMAND "${Java_JAVA_EXECUTABLE}" -classpath "${SIMGRID_JAR}" org.simgrid.NativeLib
 140     )
 141   if(MINGW)
 142     find_library(WINPTHREAD_DLL
 143       NAME winpthread winpthread-1
 144       PATHS C:\\MinGW C:\\MinGW64 C:\\MinGW\\bin C:\\MinGW64\\bin
 145     )
 146     add_custom_command(
 147       TARGET simgrid-java_jar POST_BUILD
 148       COMMENT "Add the MinGW libs into simgrid.jar..."
 149       DEPENDS ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 150
 151       COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 152       COMMAND ${CMAKE_COMMAND} -E make_directory          ${JAVA_NATIVE_PATH}
 153       COMMAND ${CMAKE_COMMAND} -E copy ${WINPTHREAD_DLL}  ${JAVA_NATIVE_PATH}
 154
 155       COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 156       COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 157     )
 158   endif(MINGW)
 159 endif(enable_lib_in_jar)
 160
 161 include_directories(${JNI_INCLUDE_DIRS} ${JAVA_INCLUDE_PATH} ${JAVA_INCLUDE_PATH2})
 162
 163 if(enable_maintainer_mode)
 164   set(CMAKE_SWIG_FLAGS "-package" "org.simgrid.surf")
 165   set(CMAKE_SWIG_OUTDIR "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf")
 166
 167   set_source_files_properties(${JSURF_SWIG_SRC} PROPERTIES CPLUSPLUS 1)
 168
 169   swig_add_module(surf-java java ${JSURF_SWIG_SRC} ${JSURF_JAVA_C_SRC})
 170   swig_link_libraries(surf-java simgrid)
 171 else()
 172   add_library(surf-java SHARED ${JSURF_C_SRC})
 173   target_link_libraries(surf-java simgrid)
 174 endif()
 175
 176 set_target_properties(surf-java PROPERTIES SKIP_BUILD_RPATH ON)
 177 set_target_properties(simgrid-java PROPERTIES SKIP_BUILD_RPATH ON)
 178
 179 add_dependencies(simgrid-java surf-java)
 180 add_dependencies(simgrid-java_jar surf-java)
 181
 182 if(WIN32)
 183   set_target_properties(surf-java PROPERTIES
 184     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at")
 185 endif()