tools/cmake/Tests.cmake

   1 SET(TESH_OPTION "--ignore-jenkins")
   2 SET(TESH_COMMAND "${PYTHON_EXECUTABLE}" ${CMAKE_BINARY_DIR}/bin/tesh)
   3
   4 SET(TESH_LIBRARY_PATH "${CMAKE_BINARY_DIR}/lib")
   5 if(NOT $ENV{LD_LIBRARY_PATH} STREQUAL "")
   6   SET(TESH_LIBRARY_PATH "${TESH_LIBRARY_PATH}:$ENV{LD_LIBRARY_PATH}")
   7 endif()
   8
   9 IF(enable_memcheck)
  10   INCLUDE(FindValgrind)
  11
  12   if (NOT VALGRIND_EXE MATCHES "NOTFOUND")
  13     execute_process(COMMAND ${VALGRIND_EXE} --version  OUTPUT_VARIABLE "VALGRIND_VERSION")
  14     message(STATUS "Valgrind version: ${VALGRIND_VERSION}")
  15
  16     set(TESH_WRAPPER ${CMAKE_HOME_DIRECTORY}/tools/cmake/scripts/my_valgrind.pl)
  17     set(TESH_WRAPPER ${TESH_WRAPPER}\ --trace-children=yes\ --trace-children-skip=/usr/bin/*,/bin/*\ --leak-check=full\ --show-reachable=yes\ --track-origins=no\ --read-var-info=no\ --num-callers=20\ --suppressions=${CMAKE_HOME_DIRECTORY}/tools/simgrid.supp\ )
  18     if(enable_memcheck_xml)
  19       SET(TESH_WRAPPER ${TESH_WRAPPER}\ --xml=yes\ --xml-file=memcheck_test_%p.memcheck\ --child-silent-after-fork=yes\ )
  20     endif()
  21     set(TESH_OPTION ${TESH_OPTION} --setenv VALGRIND_NO_LEAK_CHECK=--leak-check=no\ --show-leak-kinds=none)
  22
  23 #    message(STATUS "tesh wrapper: ${TESH_WRAPPER}")
  24
  25     mark_as_advanced(TESH_WRAPPER)
  26   else()
  27     set(enable_memcheck false)
  28     message(STATUS "Error: Command valgrind not found --> enable_memcheck autoset to false.")
  29   endif()
  30 ENDIF()
  31 SET(TESH_WRAPPER_UNBOXED "${TESH_WRAPPER}")
  32 SEPARATE_ARGUMENTS(TESH_WRAPPER_UNBOXED)
  33
  34 #some tests may take forever on non futexes systems, using busy_wait with n cores < n workers
  35 # default to posix for these tests if futexes are not supported
  36 IF(NOT HAVE_FUTEX_H)
  37   SET(CONTEXTS_SYNCHRO --cfg contexts/synchro:posix)
  38 ENDIF()
  39
  40 MACRO(ADD_TESH NAME)
  41   SET(ARGT ${ARGV})
  42   LIST(REMOVE_AT ARGT 0)
  43   IF(WIN32)
  44     STRING(REPLACE "§" "\;" ARGT "${ARGT}")
  45   ENDIF()
  46   if(TESH_WRAPPER)
  47     ADD_TEST(${NAME} ${TESH_COMMAND} --wrapper "${TESH_WRAPPER}" ${TESH_OPTION} ${ARGT})
  48   else()
  49     ADD_TEST(${NAME} ${TESH_COMMAND} ${TESH_OPTION} ${ARGT})
  50   endif()
  51 ENDMACRO()
  52
  53 MACRO(ADD_TESH_FACTORIES NAME FACTORIES)
  54   SET(ARGR ${ARGV})
  55   LIST(REMOVE_AT ARGR 0) # remove name
  56   FOREACH(I ${FACTORIES}) # remove all factories
  57     LIST(REMOVE_AT ARGR 0)
  58   ENDFOREACH()
  59   FOREACH(FACTORY ${FACTORIES})
  60     if ((${FACTORY} STREQUAL "thread" ) OR # Always available, thanks to C++11 threads
  61         (${FACTORY} STREQUAL "boost" AND HAVE_BOOST_CONTEXTS) OR
  62         (${FACTORY} STREQUAL "raw" AND HAVE_RAW_CONTEXTS) OR
  63         (${FACTORY} STREQUAL "ucontext" AND HAVE_UCONTEXT_CONTEXTS))
  64       ADD_TESH("${NAME}-${FACTORY}" "--cfg" "contexts/factory:${FACTORY}" ${ARGR})
  65     endif()
  66     if ((NOT ${FACTORY} STREQUAL "thread") AND
  67         (NOT ${FACTORY} STREQUAL "boost") AND
  68         (NOT ${FACTORY} STREQUAL "raw") AND
  69         (NOT ${FACTORY} STREQUAL "ucontext"))
  70         message(FATAL_ERROR "Cannot add a tesh for an unknown factory: ${FACTORY}")
  71     endif()
  72   ENDFOREACH()
  73 ENDMACRO()
  74
  75 MACRO(SET_TESH_PROPERTIES NAME FACTORIES)
  76   SET(ARGR ${ARGV})
  77   LIST(REMOVE_AT ARGR 0) # remove name
  78   FOREACH(I ${FACTORIES}) # remove all factories
  79     LIST(REMOVE_AT ARGR 0)
  80   ENDFOREACH()
  81   FOREACH(FACTORY ${FACTORIES})
  82     if ((${FACTORY} STREQUAL "thread" ) OR # Always available, thanks to C++11 threads
  83         (${FACTORY} STREQUAL "boost" AND HAVE_BOOST_CONTEXTS) OR
  84         (${FACTORY} STREQUAL "raw" AND HAVE_RAW_CONTEXTS) OR
  85         (${FACTORY} STREQUAL "ucontext" AND HAVE_UCONTEXT_CONTEXTS))
  86       set_tests_properties("${NAME}-${FACTORY}" PROPERTIES ${ARGR})
  87     endif()
  88   ENDFOREACH()
  89 ENDMACRO()
  90
  91 IF(enable_java)
  92   IF(WIN32)
  93     SET(TESH_CLASSPATH "${CMAKE_BINARY_DIR}/examples/deprecated/java/\;${CMAKE_BINARY_DIR}/teshsuite/java/\;${SIMGRID_JAR}")
  94     STRING(REPLACE "\;" "§" TESH_CLASSPATH "${TESH_CLASSPATH}")
  95   ELSE()
  96     SET(TESH_CLASSPATH "${CMAKE_BINARY_DIR}/examples/deprecated/java/:${CMAKE_BINARY_DIR}/teshsuite/java/:${SIMGRID_JAR}")
  97   ENDIF()
  98 ENDIF()
  99
 100 # New tests should use the Catch Framework
 101 set(UNIT_TESTS  src/xbt/unit-tests_main.cpp
 102                 src/kernel/resource/profile/Profile_test.cpp
 103                 src/xbt/config_test.cpp
 104                 src/xbt/dict_test.cpp
 105                 src/xbt/dynar_test.cpp
 106                 src/xbt/random_test.cpp
 107                 src/xbt/xbt_str_test.cpp
 108                 src/kernel/lmm/maxmin_test.cpp)
 109 if (SIMGRID_HAVE_MC)
 110   set(UNIT_TESTS ${UNIT_TESTS} src/mc/sosp/Snapshot_test.cpp src/mc/sosp/PageStore_test.cpp)
 111 else()
 112   set(EXTRA_DIST ${EXTRA_DIST} src/mc/sosp/Snapshot_test.cpp src/mc/sosp/PageStore_test.cpp)
 113 endif()
 114
 115 add_executable       (unit-tests EXCLUDE_FROM_ALL ${UNIT_TESTS})
 116 add_dependencies     (tests unit-tests)
 117 target_link_libraries(unit-tests simgrid)
 118 ADD_TEST(unit-tests ${CMAKE_BINARY_DIR}/unit-tests)
 119 set_property(TARGET unit-tests APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}")
 120 set(EXTRA_DIST ${EXTRA_DIST} ${UNIT_TESTS})
 121
 122 unset(UNIT_TESTS)