tools/cmake/MakeLib.cmake

   1 ### Make Libs
   2
   3 # On macOS, specify that rpath is useful to look for the dependencies
   4 # See https://gitlab.kitware.com/cmake/community/wikis/doc/cmake/RPATH-handling and Java.cmake
   5 set(CMAKE_MACOSX_RPATH TRUE)
   6 if(APPLE)
   7   SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE) # When installed, use system path
   8   set(CMAKE_SKIP_BUILD_RPATH FALSE)         # When executing from build tree, take the lib from the build path if exists
   9   set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE) # When executing from build tree, take the lib from the system path if exists
  10
  11   # add the current location of libsimgrid-java.dynlib as a location for libsimgrid.dynlib
  12   # (useful when unpacking the native libraries from the jarfile)
  13   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_FULL_LIBDIR}")
  14 endif()
  15
  16 ###############################
  17 # Declare the library content #
  18 ###############################
  19
  20 # Actually declare our libraries
  21 add_library(simgrid SHARED ${simgrid_sources})
  22 set_target_properties(simgrid PROPERTIES VERSION ${libsimgrid_version})
  23 # The library can obviously use the internal headers
  24 set_property(TARGET simgrid
  25              APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}")
  26
  27 add_dependencies(simgrid maintainer_files)
  28
  29 if(enable_model-checking)
  30   add_executable(simgrid-mc ${MC_SIMGRID_MC_SRC})
  31   target_link_libraries(simgrid-mc simgrid)
  32   set_target_properties(simgrid-mc
  33                         PROPERTIES RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
  34   set_property(TARGET simgrid-mc
  35                APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}")
  36   install(TARGETS simgrid-mc # install that binary without breaking the rpath on Mac
  37     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  38   add_dependencies(tests-mc simgrid-mc)
  39 endif()
  40
  41
  42 # Compute the dependencies of SimGrid
  43 #####################################
  44 # search for dlopen
  45 if("${CMAKE_SYSTEM_NAME}" MATCHES "kFreeBSD|Linux|SunOS")
  46   find_library(DL_LIBRARY dl)
  47 endif()
  48 mark_as_advanced(DL_LIBRARY)
  49
  50 if (HAVE_BOOST_CONTEXTS)
  51   target_link_libraries(simgrid ${Boost_CONTEXT_LIBRARY})
  52 endif()
  53
  54 if (HAVE_BOOST_STACKTRACE_BACKTRACE)
  55   target_link_libraries(simgrid ${Boost_STACKTRACE_BACKTRACE_LIBRARY})
  56 endif()
  57
  58 if (HAVE_BOOST_ADDR2LINE_BACKTRACE)
  59   target_link_libraries(simgrid ${Boost_STACKTRACE_ADDR2LINE_LIBRARY})
  60 endif()
  61
  62 if(CMAKE_USE_PTHREADS_INIT)
  63   target_link_libraries(simgrid ${CMAKE_THREAD_LIBS_INIT})
  64 endif()
  65
  66 if(SIMGRID_HAVE_LUA)
  67   ADD_CUSTOM_TARGET(link_simgrid_lua ALL
  68     DEPENDS     simgrid
  69     )
  70   SET(SIMGRID_DEP "${SIMGRID_DEP} ${LUA_LIBRARY}")
  71 endif()
  72
  73 if(HAVE_PAPI)
  74   SET(SIMGRID_DEP "${SIMGRID_DEP} -lpapi")
  75 endif()
  76
  77 if(HAVE_GRAPHVIZ)
  78   if(HAVE_CGRAPH_LIB)
  79     SET(SIMGRID_DEP "${SIMGRID_DEP} -lcgraph")
  80   else()
  81     if(HAVE_AGRAPH_LIB)
  82       SET(SIMGRID_DEP "${SIMGRID_DEP} -lagraph -lcdt")
  83     endif()
  84   endif()
  85 endif()
  86
  87 if(NOT ${DL_LIBRARY} STREQUAL "")
  88   SET(SIMGRID_DEP "${SIMGRID_DEP} ${DL_LIBRARY}")
  89 endif()
  90
  91 if(HAVE_POSIX_GETTIME)
  92   SET(SIMGRID_DEP "${SIMGRID_DEP} -lrt")
  93 endif()
  94
  95 if("${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD")
  96   set(SIMGRID_DEP "${SIMGRID_DEP} -lprocstat")
  97 endif()
  98
  99 # Compute the dependencies of SMPI
 100 ##################################
 101
 102 if(enable_smpi)
 103   add_executable(smpimain src/smpi/smpi_main.c)
 104   target_link_libraries(smpimain simgrid)
 105   set_target_properties(smpimain
 106     PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib/simgrid)
 107   install(TARGETS smpimain # install that binary without breaking the rpath on Mac
 108     RUNTIME DESTINATION ${CMAKE_INSTALL_LIBDIR}/simgrid)
 109   add_dependencies(tests smpimain)
 110
 111   add_executable(smpireplaymain src/smpi/smpi_replay_main.cpp)
 112   target_compile_options(smpireplaymain PRIVATE -fpic)
 113   target_link_libraries(smpireplaymain simgrid -fpic -shared)
 114   set_target_properties(smpireplaymain
 115     PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib/simgrid)
 116   install(TARGETS smpireplaymain # install that binary without breaking the rpath on Mac
 117     RUNTIME DESTINATION ${CMAKE_INSTALL_LIBDIR}/simgrid)
 118   add_dependencies(tests smpireplaymain)
 119
 120   if(SMPI_FORTRAN)
 121     if(CMAKE_Fortran_COMPILER_ID MATCHES "GNU")
 122       SET(SIMGRID_DEP "${SIMGRID_DEP} -lgfortran")
 123     elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
 124       SET(SIMGRID_DEP "${SIMGRID_DEP} -lifcore")
 125     elseif(CMAKE_Fortran_COMPILER_ID MATCHES "PGI|Flang")
 126       SET(SIMGRID_DEP "${SIMGRID_DEP} -lflang")
 127       if("${CMAKE_SYSTEM}" MATCHES "FreeBSD")
 128         set(SIMGRID_DEP "${SIMGRID_DEP} -lexecinfo")
 129         if ("${CMAKE_SYSTEM_VERSION}" STRGREATER_EQUAL "12")
 130             set(SIMGRID_DEP "${SIMGRID_DEP} -lpgmath")
 131         endif()
 132         if ("${CMAKE_SYSTEM_VERSION}" MATCHES "12\.1")
 133             set(SIMGRID_DEP "${SIMGRID_DEP} -lomp")
 134         endif()
 135       endif()
 136     endif()
 137   endif()
 138
 139 endif()
 140
 141 if(enable_smpi AND APPLE)
 142   set(SIMGRID_DEP "${SIMGRID_DEP} -Wl,-U -Wl,_smpi_simulated_main")
 143 endif()
 144
 145 # See https://github.com/HewlettPackard/foedus_code/blob/master/foedus-core/cmake/FindGccAtomic.cmake
 146 FIND_LIBRARY(GCCLIBATOMIC_LIBRARY NAMES atomic atomic.so.1 libatomic.so.1
 147   HINTS
 148     $ENV{HOME}/local/lib64
 149     $ENV{HOME}/local/lib
 150     /usr/local/lib64
 151     /usr/local/lib
 152     /opt/local/lib64
 153     /opt/local/lib
 154     /usr/lib64
 155     /usr/lib
 156     /lib64
 157     /lib
 158 )
 159
 160 # Fix a FTBFS on armel, mips, mipsel and friends (Debian's #872881)
 161 if(CMAKE_COMPILER_IS_GNUCC AND GCCLIBATOMIC_LIBRARY)
 162     set(SIMGRID_DEP   "${SIMGRID_DEP}   -Wl,--as-needed -latomic -Wl,--no-as-needed")
 163 endif()
 164 mark_as_advanced(GCCLIBATOMIC_LIBRARY)
 165
 166 if(enable_model-checking AND (NOT LINKER_VERSION VERSION_LESS "2.30"))
 167     set(SIMGRID_DEP   "${SIMGRID_DEP}   -Wl,-znorelro -Wl,-znoseparate-code")
 168 endif()
 169
 170 target_link_libraries(simgrid   ${SIMGRID_DEP})
 171
 172 # Dependencies from maintainer mode
 173 ###################################
 174 if(enable_maintainer_mode)
 175   add_dependencies(simgrid smpi_generated_headers_call_location_tracing)
 176 endif()
 177 if(enable_maintainer_mode AND PYTHON_EXE)
 178   add_dependencies(simgrid simcalls_generated_src)
 179 endif()
 180 if(enable_maintainer_mode AND BISON_EXE AND LEX_EXE)
 181   add_dependencies(simgrid automaton_generated_src)
 182 endif()