tools/cmake/Tests.cmake

   1 SET(TESH_OPTION "--ignore-jenkins")
   2 SET(TESH_COMMAND "${PYTHON_EXECUTABLE}" ${CMAKE_BINARY_DIR}/bin/tesh)
   3
   4 SET(TESH_LIBRARY_PATH "${CMAKE_BINARY_DIR}/lib")
   5 if(NOT $ENV{LD_LIBRARY_PATH} STREQUAL "")
   6   SET(TESH_LIBRARY_PATH "${TESH_LIBRARY_PATH}:$ENV{LD_LIBRARY_PATH}")
   7 endif()
   8
   9 IF(enable_memcheck)
  10   INCLUDE(FindValgrind)
  11
  12   if (NOT VALGRIND_EXE MATCHES "NOTFOUND")
  13     execute_process(COMMAND ${VALGRIND_EXE} --version  OUTPUT_VARIABLE "VALGRIND_VERSION")
  14     message(STATUS "Valgrind version: ${VALGRIND_VERSION}")
  15
  16     set(VALGRIND_WRAPPER ${CMAKE_HOME_DIRECTORY}/tools/cmake/scripts/my_valgrind.pl)
  17     set(VALGRIND_WRAPPER ${VALGRIND_WRAPPER}\ --trace-children=yes\ --trace-children-skip=/usr/bin/*,/bin/*\ --leak-check=full\ --show-reachable=yes\ --track-origins=no\ --read-var-info=no\ --num-callers=20\ --suppressions=${CMAKE_HOME_DIRECTORY}/tools/simgrid.supp\ )
  18     if(enable_memcheck_xml)
  19       SET(VALGRIND_WRAPPER ${VALGRIND_WRAPPER}\ --xml=yes\ --xml-file=memcheck_test_%p.memcheck\ --child-silent-after-fork=yes\ )
  20     endif()
  21     set(TESH_OPTION ${TESH_OPTION} --setenv VALGRIND_NO_LEAK_CHECK=--leak-check=no\ --show-leak-kinds=none)
  22
  23 #    message(STATUS "tesh wrapper: ${VALGRIND_WRAPPER}")
  24
  25     mark_as_advanced(VALGRIND_WRAPPER)
  26   else()
  27     set(enable_memcheck false)
  28     message(STATUS "Error: Command valgrind not found --> enable_memcheck autoset to false.")
  29   endif()
  30 ENDIF()
  31 SET(VALGRIND_WRAPPER_UNBOXED "${VALGRIND_WRAPPER}")
  32 SEPARATE_ARGUMENTS(VALGRIND_WRAPPER_UNBOXED)
  33
  34 #some tests may take forever on non futexes systems, using busy_wait with n cores < n workers
  35 # default to posix for these tests if futexes are not supported
  36 IF(NOT HAVE_FUTEX_H)
  37   SET(CONTEXTS_SYNCHRO --cfg contexts/synchro:posix)
  38 ENDIF()
  39
  40 MACRO(ADD_TESH NAME)
  41   SET(ARGT ${ARGV})
  42   LIST(REMOVE_AT ARGT 0)
  43   if(VALGRIND_WRAPPER)
  44     ADD_TEST(${NAME} ${TESH_COMMAND} --wrapper "${VALGRIND_WRAPPER}" ${TESH_OPTION} ${ARGT})
  45   else()
  46     ADD_TEST(${NAME} ${TESH_COMMAND} ${TESH_OPTION} ${ARGT})
  47   endif()
  48 ENDMACRO()
  49
  50 # Build a list variable named FACTORIES_LIST with the given arguments, but:
  51 # - replace wildcard "*" with all known factories
  52 # - if the list begins with "^", take the complement
  53 # - finally remove unsupported factories
  54 #
  55 # Used by ADD_TESH_FACTORIES, and SET_TESH_PROPERTIES
  56 MACRO(SETUP_FACTORIES_LIST)
  57   set(ALL_KNOWN_FACTORIES "thread;boost;raw;ucontext")
  58
  59   if("${ARGV}" STREQUAL "*")    # take all known factories
  60     SET(FACTORIES_LIST ${ALL_KNOWN_FACTORIES})
  61   elseif("${ARGV}" MATCHES "^\\^") # exclude given factories
  62     SET(FACTORIES_LIST ${ALL_KNOWN_FACTORIES})
  63     STRING(SUBSTRING "${ARGV}" 1 -1 EXCLUDED)
  64     LIST(REMOVE_ITEM FACTORIES_LIST ${EXCLUDED})
  65   else()                        # take given factories
  66     SET(FACTORIES_LIST "${ARGV}")
  67   endif()
  68
  69   # Exclude unsupported factories. Threads are always available, thanks to C++11 threads.
  70   if(NOT HAVE_BOOST_CONTEXTS)
  71     LIST(REMOVE_ITEM FACTORIES_LIST "boost")
  72   endif()
  73   if(NOT HAVE_RAW_CONTEXTS)
  74     LIST(REMOVE_ITEM FACTORIES_LIST "raw")
  75   endif()
  76   if(NOT HAVE_UCONTEXT_CONTEXTS)
  77     LIST(REMOVE_ITEM FACTORIES_LIST "ucontext")
  78   endif()
  79
  80   # Check that there is no unknown factory
  81   FOREACH(FACTORY ${FACTORIES_LIST})
  82     if(NOT FACTORY IN_LIST ALL_KNOWN_FACTORIES)
  83       message(FATAL_ERROR "Unknown factory: ${FACTORY}")
  84     endif()
  85   ENDFOREACH()
  86 ENDMACRO()
  87
  88 MACRO(ADD_TESH_FACTORIES NAME FACTORIES)
  89   SET(ARGR ${ARGV})
  90   LIST(REMOVE_AT ARGR 0) # remove name
  91   FOREACH(I ${FACTORIES}) # remove all factories
  92     LIST(REMOVE_AT ARGR 0)
  93   ENDFOREACH()
  94   SETUP_FACTORIES_LIST(${FACTORIES})
  95   FOREACH(FACTORY ${FACTORIES_LIST})
  96     ADD_TESH("${NAME}-${FACTORY}" "--cfg" "contexts/factory:${FACTORY}" ${ARGR})
  97   ENDFOREACH()
  98 ENDMACRO()
  99
 100 MACRO(SET_TESH_PROPERTIES NAME FACTORIES)
 101   SET(ARGR ${ARGV})
 102   LIST(REMOVE_AT ARGR 0) # remove name
 103   FOREACH(I ${FACTORIES}) # remove all factories
 104     LIST(REMOVE_AT ARGR 0)
 105   ENDFOREACH()
 106   SETUP_FACTORIES_LIST(${FACTORIES})
 107   FOREACH(FACTORY ${FACTORIES_LIST})
 108     set_tests_properties("${NAME}-${FACTORY}" PROPERTIES ${ARGR})
 109   ENDFOREACH()
 110 ENDMACRO()
 111
 112 # New tests should use the Catch Framework
 113 set(UNIT_TESTS  src/xbt/unit-tests_main.cpp
 114                 src/kernel/resource/NetworkModelFactors_test.cpp
 115                 src/kernel/resource/SplitDuplexLinkImpl_test.cpp
 116                 src/kernel/resource/profile/Profile_test.cpp
 117                 src/kernel/routing/DijkstraZone_test.cpp
 118                 src/kernel/routing/DragonflyZone_test.cpp
 119                 src/kernel/routing/FatTreeZone_test.cpp
 120                 src/kernel/routing/FloydZone_test.cpp
 121                 src/kernel/routing/FullZone_test.cpp
 122                 src/kernel/routing/StarZone_test.cpp
 123                 src/kernel/routing/TorusZone_test.cpp
 124                 src/xbt/config_test.cpp
 125                 src/xbt/dict_test.cpp
 126                 src/xbt/dynar_test.cpp
 127                 src/xbt/random_test.cpp
 128                 src/xbt/xbt_str_test.cpp
 129                 src/kernel/lmm/maxmin_test.cpp)
 130
 131 set(MC_UNIT_TESTS src/mc/sosp/Snapshot_test.cpp
 132                   src/mc/sosp/PageStore_test.cpp
 133                   src/mc/explo/udpor/EventSet_test.cpp
 134                   src/mc/explo/udpor/Unfolding_test.cpp
 135                   src/mc/explo/udpor/UnfoldingEvent_test.cpp
 136                   src/mc/explo/udpor/History_test.cpp
 137                   src/mc/explo/udpor/Configuration_test.cpp)
 138 if (SIMGRID_HAVE_MC)
 139   set(UNIT_TESTS ${UNIT_TESTS} ${MC_UNIT_TESTS})
 140 else()
 141   set(EXTRA_DIST ${EXTRA_DIST} ${MC_UNIT_TESTS})
 142 endif()
 143 if (SIMGRID_HAVE_EIGEN3)
 144   set(UNIT_TESTS ${UNIT_TESTS} src/kernel/lmm/bmf_test.cpp)
 145 else()
 146   set(EXTRA_DIST ${EXTRA_DIST} src/kernel/lmm/bmf_test.cpp)
 147 endif()
 148 set(EXTRA_DIST ${EXTRA_DIST} src/kernel/routing/NetZone_test.hpp)
 149
 150 add_executable       (unit-tests EXCLUDE_FROM_ALL ${UNIT_TESTS})
 151 add_dependencies     (tests unit-tests)
 152 target_link_libraries(unit-tests simgrid)
 153 ADD_TEST(unit-tests ${VALGRIND_WRAPPER_UNBOXED} ${CMAKE_BINARY_DIR}/unit-tests)
 154 set_property(TARGET unit-tests APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}")
 155 set(EXTRA_DIST ${EXTRA_DIST} ${UNIT_TESTS})
 156
 157 unset(UNIT_TESTS)