examples/cpp/CMakeLists.txt

   1 # Regular examples: with only one source and tested with all factories by default
   2 #################################################################################
   3 ### Define the examples' specificities
   4
   5 set(_app-bittorrent_sources app-bittorrent/s4u-bittorrent.cpp app-bittorrent/s4u-bittorrent.hpp
   6                             app-bittorrent/s4u-peer.cpp app-bittorrent/s4u-peer.hpp
   7                             app-bittorrent/s4u-tracker.cpp app-bittorrent/s4u-tracker.hpp)
   8 set(_dht-chord_sources    dht-chord/s4u-dht-chord.cpp dht-chord/s4u-dht-chord.hpp dht-chord/s4u-dht-chord-node.cpp)
   9 set(_dht-kademlia_sources dht-kademlia/s4u-dht-kademlia.cpp dht-kademlia/s4u-dht-kademlia.hpp
  10                           dht-kademlia/node.cpp dht-kademlia/node.hpp
  11                           dht-kademlia/routing_table.cpp dht-kademlia/routing_table.hpp
  12                           dht-kademlia/answer.cpp dht-kademlia/answer.hpp dht-kademlia/message.hpp)
  13
  14 set(_actor-stacksize_factories "^thread") # Threads ignore modifications of the stack size
  15
  16 # The maestro-set example only works for threads
  17 set(_maestro-set_factories "thread")
  18
  19 if(SIMGRID_HAVE_MC)
  20   # These tests timeout with threads, not sure why
  21   foreach(example mc-bugged1 mc-bugged2 mc-failing-assert mc-electric-fence)
  22     set(_${example}_factories "^thread") # Timeout
  23     add_dependencies(tests-mc s4u-${example})
  24   endforeach()
  25
  26   if(enable_coverage)
  27     foreach (example mc-bugged1 mc-bugged2 mc-electric-fence mc-failing-assert)
  28       ADD_TEST(cover-${example} ${CMAKE_CURRENT_BINARY_DIR}/${example}/s4u-${example} ${CMAKE_HOME_DIRECTORY}/examples/platforms/model_checker_platform.xml)
  29     endforeach()
  30   endif()
  31 else()
  32   foreach (example mc-bugged1 mc-bugged2  mc-centralized-mutex mc-failing-assert mc-electric-fence)
  33     set(_${example}_disable 1)
  34   endforeach()
  35 endif()
  36
  37 set(tesh_files ${tesh_files} ${CMAKE_CURRENT_SOURCE_DIR}/synchro-mutex/s4u-mc-synchro-mutex-stateful.tesh)
  38 if(SIMGRID_HAVE_STATEFUL_MC)
  39   if(HAVE_C_STACK_CLEANER)
  40     add_executable       (s4u-mc-bugged1-liveness-cleaner-on  EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  41     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-on  simgrid)
  42     set_target_properties(s4u-mc-bugged1-liveness-cleaner-on  PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fstack-cleaner")
  43     add_dependencies(tests-mc s4u-mc-bugged1-liveness-cleaner-on)
  44
  45     add_executable       (s4u-mc-bugged1-liveness-cleaner-off EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  46     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-off simgrid)
  47     set_target_properties(s4u-mc-bugged1-liveness-cleaner-off PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fno-stack-cleaner")
  48     add_dependencies(tests-mc s4u-mc-bugged1-liveness-cleaner-off)
  49   endif()
  50
  51   ADD_TESH(s4u-mc-synchro-mutex-stateful
  52      --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/synchro-mutex
  53      --setenv libdir=${CMAKE_BINARY_DIR}/lib
  54      --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  55      --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/synchro-mutex
  56      --cd ${CMAKE_CURRENT_SOURCE_DIR}/synchro-mutex
  57       ${CMAKE_HOME_DIRECTORY}/examples/cpp/synchro-mutex/s4u-mc-synchro-mutex-stateful.tesh)
  58
  59   # Model-checking liveness
  60   if(HAVE_UCONTEXT_CONTEXTS AND SIMGRID_PROCESSOR_x86_64)
  61     # liveness model-checking works only on 64bits (for now ...)
  62     set(_mc-bugged1-liveness_factories "ucontext")
  63     add_dependencies(tests-mc s4u-mc-bugged1-liveness)
  64     set(_mc-bugged2-liveness_factories "ucontext")
  65
  66     # This example never ends, disable it for now
  67     set(_mc-bugged2-liveness_disable 1)
  68
  69     ADD_TESH(s4u-mc-bugged1-liveness-visited-ucontext --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness
  70                                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  71                                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness
  72                                                        ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh)
  73     IF(HAVE_C_STACK_CLEANER)
  74       add_dependencies(tests-mc s4u-mc-bugged1-liveness-stack-cleaner)
  75       # This test checks if the stack cleaner is making a difference:
  76       ADD_TEST(s4u-mc-bugged1-liveness-stack-cleaner ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
  77                                                      ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/
  78                                                      ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/)
  79     ENDIF()
  80   else()
  81     set(_mc-bugged1-liveness_disable 1)
  82     set(_mc-bugged2-liveness_disable 1)
  83   endif()
  84
  85   if(enable_coverage)
  86     ADD_TEST(cover-mc-bugged1-liveness ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness ${CMAKE_HOME_DIRECTORY}/examples/platforms/small_platform.xml 1 1001)
  87   endif()
  88
  89 else()
  90   foreach (example mc-bugged1-liveness mc-bugged2-liveness)
  91     set(_${example}_disable 1)
  92   endforeach()
  93 endif()
  94
  95 # Hijack some regular tests to run them on top of the MC
  96 foreach (example synchro-barrier synchro-mutex synchro-semaphore)
  97   set(tesh_files ${tesh_files} ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-mc-${example}.tesh)
  98
  99   if (SIMGRID_HAVE_MC)
 100     ADD_TESH(s4u-mc-${example}
 101               --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 102               --setenv libdir=${CMAKE_BINARY_DIR}/lib
 103               --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 104               --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 105               --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 106               ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-mc-${example}.tesh)
 107
 108     add_dependencies(tests-mc s4u-${example})
 109   endif()
 110 endforeach()
 111
 112 if (SIMGRID_HAVE_MC)
 113   # Dependency on the regular tests
 114   foreach(example mc-centralized-mutex)
 115     add_dependencies(tests-mc s4u-${example})
 116   endforeach()
 117 endif()
 118
 119 if(NOT HAVE_GRAPHVIZ)
 120   set(_dag-from-dot_disable 1)
 121   set(_dag-from-dot-simple_disable 1)
 122 endif()
 123
 124 if (NOT SIMGRID_HAVE_JSON)
 125   set(_dag-from-json-simple_disable 1)
 126 endif()
 127
 128 if(SIMGRID_HAVE_NS3)
 129   if(NS3_VERSION VERSION_GREATER_EQUAL 3.37)
 130     set(_network-ns3_teshfile         ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-timed.tesh)
 131     set(tesh_files    ${tesh_files}   ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-notime.tesh)
 132   else()
 133     set(_network-ns3_teshfile         ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-notime.tesh)
 134     set(tesh_files    ${tesh_files}   ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-timed.tesh)
 135   endif()
 136
 137 foreach (example network-ns3 network-ns3-wifi)
 138   add_dependencies(tests-ns3 s4u-${example})
 139 endforeach()
 140
 141 else()
 142   # Even if ns3 is not found, we need to override the teshfile name and make sure that everything gets included in the archive
 143   set(_network-ns3_teshfile         ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-notime.tesh)
 144   set(tesh_files    ${tesh_files}   ${CMAKE_HOME_DIRECTORY}/examples/cpp/network-ns3/s4u-network-ns3-timed.tesh)
 145
 146   foreach (example network-ns3 network-ns3-wifi)
 147     set(_${example}_disable 1)
 148   endforeach()
 149 endif()
 150
 151 # Deal with each example
 152
 153 foreach (example activity-testany activity-waitany
 154                  actor-create actor-daemon actor-exiting actor-join actor-kill
 155                  actor-lifetime actor-migrate actor-suspend actor-yield actor-stacksize
 156                  app-bittorrent app-chainsend app-token-ring
 157                  battery-degradation battery-simple battery-energy
 158                  comm-pingpong comm-ready comm-suspend comm-testany comm-wait comm-waitany comm-waitall comm-waituntil
 159                  comm-dependent comm-host2host comm-failure comm-throttling
 160                  cloud-capping cloud-migration cloud-simple
 161                  dag-comm dag-from-json-simple dag-from-dax-simple dag-from-dax dag-from-dot-simple dag-from-dot dag-failure dag-io dag-scheduling dag-simple dag-tuto
 162                  dht-chord dht-kademlia
 163                  energy-exec energy-boot energy-link energy-vm energy-exec-ptask energy-wifi
 164                  engine-filtering engine-run-partial
 165                  exec-async exec-basic exec-dvfs exec-remote exec-waitany exec-waitfor exec-dependent exec-unassigned
 166                  exec-ptask-multicore exec-ptask-multicore-latency exec-cpu-nonlinear exec-cpu-factors exec-failure exec-threads
 167                  maestro-set
 168                  mc-bugged1 mc-bugged1-liveness mc-bugged2 mc-bugged2-liveness mc-centralized-mutex mc-electric-fence mc-failing-assert
 169                  network-ns3 network-ns3-wifi network-wifi
 170                  io-async io-priority io-degradation io-file-system io-file-remote io-disk-raw io-dependent
 171                  task-io task-simple task-variable-load task-switch-host
 172                  photovoltaic-simple
 173                  platform-comm-serialize platform-failures platform-profile platform-properties
 174                  plugin-host-load plugin-link-load plugin-prodcons
 175                  replay-comm replay-io
 176                  routing-get-clusters
 177                  synchro-barrier synchro-condition-variable synchro-condition-variable-waituntil synchro-mutex synchro-semaphore
 178                  clusters-multicpu network-factors network-nonlinear)
 179
 180   # Use default source file unless specified otherwise
 181   if(NOT DEFINED _${example}_sources)
 182     set(_${example}_sources ${example}/s4u-${example}.cpp)
 183   endif()
 184
 185   # Use default tesh file unless specified otherwise
 186   if(NOT DEFINED _${example}_teshfile)
 187     set(_${example}_teshfile ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 188   endif()
 189
 190   if(NOT DEFINED _${example}_disable)
 191     add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${_${example}_sources})
 192     add_dependencies     (tests s4u-${example})
 193     add_dependencies     (s4u-${example} platf_cpp)
 194     target_link_libraries(s4u-${example} simgrid)
 195     set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 196
 197     # Use default factories unless specified otherwise
 198     if(NOT DEFINED _${example}_factories)
 199       set(_${example}_factories "*")
 200     endif()
 201 #    message("Factories of ${example}: ${_${example}_factories}")
 202
 203     ADD_TESH_FACTORIES(s4u-${example} "${_${example}_factories}"
 204                                       --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 205                                       --setenv libdir=${CMAKE_BINARY_DIR}/lib
 206                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 207                                       --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 208                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 209                                       ${_${example}_teshfile})
 210   else()
 211     message(STATUS "Example ${example} disabled, thus not compiled.")
 212     unset(_${example}_disable)
 213   endif()
 214
 215   set(tesh_files    ${tesh_files}    ${_${example}_teshfile})
 216   foreach(file ${_${example}_sources})
 217     set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/${file})
 218   endforeach()
 219
 220   unset(_${example}_factories)
 221   unset(_${example}_sources)
 222   unset(_${example}_teshfile)
 223 endforeach()
 224
 225
 226 # Specific examples
 227 ###################
 228
 229 # MASTERWORKERS EXAMPLE
 230 foreach(variant fun class)
 231   add_executable       (s4u-app-masterworkers-${variant} EXCLUDE_FROM_ALL app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 232   target_link_libraries(s4u-app-masterworkers-${variant} simgrid)
 233   set_target_properties(s4u-app-masterworkers-${variant} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-masterworkers)
 234   add_dependencies(tests s4u-app-masterworkers-${variant})
 235
 236   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 237 endforeach()
 238 set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers.tesh)
 239
 240 # The tests the parallel variant of of DHTs
 241
 242 if(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_PROCESSOR STREQUAL "i386" AND CMAKE_SIZEOF_VOID_P EQUAL 8)
 243   # Thread-local storage (TLS) is needed for parallel execution, but it doesn't
 244   # play well with Ucontexts on 64bit SunOS (at least on x86_64).
 245   set(parallel-factories "^ucontext")
 246 else()
 247   set(parallel-factories "*")
 248 endif()
 249
 250 foreach(example app-bittorrent app-masterworkers
 251                 dht-chord dht-kademlia
 252                 )
 253   ADD_TESH_FACTORIES(s4u-${example}-parallel "${parallel-factories}" --cfg contexts/nthreads:4 ${CONTEXTS_SYNCHRO}
 254                                              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 255                                              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 256                                              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 257                                              ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 258 endforeach()
 259
 260 # Test non-DPOR reductions on a given MC test
 261 foreach(example mc-failing-assert)
 262 # State equality is not tested because it would take about 15 hours to run that test on my machine.
 263 # We should first optimize mmalloc_heap_differ() which takes ~4sec for each pair to compare (maybe {175 x 174/ 2} pairs here)
 264 # See the comment on mmalloc_heap_differ() in compare.cpp for more info on why it's hard to optimize.
 265 #
 266 #  if(SIMGRID_HAVE_STATEFUL_MC)
 267 #    ADD_TESH(s4u-${example}-statequality  --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 268 #                                      --setenv libdir=${CMAKE_BINARY_DIR}/lib
 269 #                                      --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 270 #                                      --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 271 #                                      --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 272 #                                      ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}-statequality.tesh)
 273 #  endif()
 274
 275   if(SIMGRID_HAVE_MC)
 276     ADD_TESH(s4u-${example}-nodpor    --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 277                                       --setenv libdir=${CMAKE_BINARY_DIR}/lib
 278                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 279                                       --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 280                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 281                                       ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}-nodpor.tesh)
 282   endif()
 283   set(tesh_files    ${tesh_files}   ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}-statequality.tesh)
 284   set(tesh_files    ${tesh_files}   ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}-nodpor.tesh)
 285 endforeach()
 286
 287 # Examples not accepting factories
 288 ##################################
 289
 290 foreach (example exec-ptask trace-categories trace-masterworkers trace-platform trace-process-migration
 291                  trace-host-user-variables trace-link-user-variables trace-route-user-variables)
 292   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 293   target_link_libraries(s4u-${example} simgrid)
 294   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 295   add_dependencies(tests s4u-${example})
 296
 297   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 298   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 299
 300   ADD_TESH(s4u-${example} --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 301                           --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 302                           --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 303                           --cd ${CMAKE_CURRENT_BINARY_DIR}/${example}
 304                           ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 305 endforeach()
 306
 307 if (NOT enable_memcheck)
 308   ADD_TESH(debug-breakpoint --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/comm-pingpong
 309                             --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 310                             ${CMAKE_CURRENT_SOURCE_DIR}/comm-pingpong/debug-breakpoint.tesh)
 311 endif()
 312
 313 # Add all extra files to the archive
 314 ####################################
 315 set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp        PARENT_SCOPE)
 316 set(tesh_files    ${tesh_files}   ${CMAKE_CURRENT_SOURCE_DIR}/comm-pingpong/debug-breakpoint.tesh
 317                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.tesh
 318                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh  PARENT_SCOPE)
 319 set(xml_files     ${xml_files}    ${CMAKE_CURRENT_SOURCE_DIR}/actor-create/s4u-actor-create_d.xml
 320                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-lifetime/s4u-actor-lifetime_d.xml
 321                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent_d.xml
 322                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers_d.xml
 323                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-scheduling/Montage_25.xml
 324                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord_d.xml
 325                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia_d.xml
 326                                   ${CMAKE_CURRENT_SOURCE_DIR}/io-file-remote/s4u-io-file-remote_d.xml
 327                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-failures/s4u-platform-failures_d.xml
 328                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split_d.xml
 329                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm_d.xml
 330                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io_d.xml
 331                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3hosts_2links_d.xml
 332                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links-timer_d.xml
 333                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links_d.xml
 334                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/crosstraffic_d.xml
 335                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/dogbone_d.xml
 336                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/onelink_d.xml
 337                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/one_cluster_d.xml                PARENT_SCOPE)
 338 set(bin_files     ${bin_files}    ${CMAKE_CURRENT_SOURCE_DIR}/battery-degradation/plot_battery_degradation.py
 339                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/generate.py
 340                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
 341                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/promela_bugged1_liveness
 342                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged2-liveness/promela_bugged2_liveness PARENT_SCOPE)
 343 set(txt_files     ${txt_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax/simple_dax_with_cycle.xml
 344                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax/smalldax.xml
 345                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax-simple/dag.xml
 346                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot/dag.dot
 347                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot-simple/dag.dot
 348                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot/dag_with_cycle.dot
 349                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-json-simple/dag.json
 350                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p0.txt
 351                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p1.txt
 352                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm.txt
 353                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io.txt                  PARENT_SCOPE)