tools/cmake/Tests.cmake

   1 SET(TESH_OPTION "--ignore-jenkins")
   2 SET(TESH_COMMAND "${PYTHON_EXECUTABLE}" ${CMAKE_BINARY_DIR}/bin/tesh)
   3
   4 SET(TESH_LIBRARY_PATH "${CMAKE_BINARY_DIR}/lib")
   5 if(NOT $ENV{LD_LIBRARY_PATH} STREQUAL "")
   6   SET(TESH_LIBRARY_PATH "${TESH_LIBRARY_PATH}:$ENV{LD_LIBRARY_PATH}")
   7 endif()
   8
   9 IF(enable_memcheck)
  10   INCLUDE(FindValgrind)
  11
  12   if (NOT VALGRIND_EXE MATCHES "NOTFOUND")
  13     execute_process(COMMAND ${VALGRIND_EXE} --version  OUTPUT_VARIABLE "VALGRIND_VERSION")
  14     message(STATUS "Valgrind version: ${VALGRIND_VERSION}")
  15
  16     set(VALGRIND_WRAPPER ${CMAKE_HOME_DIRECTORY}/tools/cmake/scripts/my_valgrind.pl)
  17     set(VALGRIND_WRAPPER ${VALGRIND_WRAPPER}\ --trace-children=yes\ --trace-children-skip=/usr/bin/*,/bin/*\ --leak-check=full\ --show-reachable=yes\ --track-origins=no\ --read-var-info=no\ --num-callers=20\ --suppressions=${CMAKE_HOME_DIRECTORY}/tools/simgrid.supp\ )
  18     if(enable_memcheck_xml)
  19       SET(VALGRIND_WRAPPER ${VALGRIND_WRAPPER}\ --xml=yes\ --xml-file=memcheck_test_%p.memcheck\ --child-silent-after-fork=yes\ )
  20     endif()
  21     set(TESH_OPTION ${TESH_OPTION} --setenv VALGRIND_NO_LEAK_CHECK=--leak-check=no\ --show-leak-kinds=none)
  22     set(TESH_OPTION ${TESH_OPTION} --setenv VALGRIND_NO_TRACE_CHILDREN=--trace-children=no)
  23
  24 #    message(STATUS "tesh wrapper: ${VALGRIND_WRAPPER}")
  25
  26     mark_as_advanced(VALGRIND_WRAPPER)
  27   else()
  28     set(enable_memcheck false)
  29     message(STATUS "Error: Command valgrind not found --> enable_memcheck autoset to false.")
  30   endif()
  31 ENDIF()
  32 SET(VALGRIND_WRAPPER_UNBOXED "${VALGRIND_WRAPPER}")
  33 SEPARATE_ARGUMENTS(VALGRIND_WRAPPER_UNBOXED)
  34
  35 #some tests may take forever on non futexes systems, using busy_wait with n cores < n workers
  36 # default to posix for these tests if futexes are not supported
  37 IF(NOT HAVE_FUTEX_H)
  38   SET(CONTEXTS_SYNCHRO --cfg contexts/synchro:posix)
  39 ENDIF()
  40
  41 MACRO(ADD_TESH NAME)
  42   SET(ARGT ${ARGV})
  43   LIST(REMOVE_AT ARGT 0)
  44   if(VALGRIND_WRAPPER)
  45     ADD_TEST(${NAME} ${TESH_COMMAND} --wrapper "${VALGRIND_WRAPPER}" ${TESH_OPTION} ${ARGT})
  46   else()
  47     ADD_TEST(${NAME} ${TESH_COMMAND} ${TESH_OPTION} ${ARGT})
  48   endif()
  49 ENDMACRO()
  50
  51 # Build a list variable named FACTORIES_LIST with the given arguments, but:
  52 # - replace wildcard "*" with all known factories
  53 # - if the list begins with "^", take the complement
  54 # - finally remove unsupported factories
  55 #
  56 # Used by ADD_TESH_FACTORIES, and SET_TESH_PROPERTIES
  57 MACRO(SETUP_FACTORIES_LIST)
  58   set(ALL_KNOWN_FACTORIES "thread;boost;raw;ucontext")
  59
  60   if("${ARGV}" STREQUAL "*")    # take all known factories
  61     SET(FACTORIES_LIST ${ALL_KNOWN_FACTORIES})
  62   elseif("${ARGV}" MATCHES "^\\^") # exclude given factories
  63     SET(FACTORIES_LIST ${ALL_KNOWN_FACTORIES})
  64     STRING(SUBSTRING "${ARGV}" 1 -1 EXCLUDED)
  65     LIST(REMOVE_ITEM FACTORIES_LIST ${EXCLUDED})
  66   else()                        # take given factories
  67     SET(FACTORIES_LIST "${ARGV}")
  68   endif()
  69
  70   # Exclude unsupported factories. Threads are always available, thanks to C++11 threads.
  71   if(NOT HAVE_BOOST_CONTEXTS)
  72     LIST(REMOVE_ITEM FACTORIES_LIST "boost")
  73   endif()
  74   if(NOT HAVE_RAW_CONTEXTS)
  75     LIST(REMOVE_ITEM FACTORIES_LIST "raw")
  76   endif()
  77   if(NOT HAVE_UCONTEXT_CONTEXTS)
  78     LIST(REMOVE_ITEM FACTORIES_LIST "ucontext")
  79   endif()
  80
  81   # Check that there is no unknown factory
  82   FOREACH(FACTORY ${FACTORIES_LIST})
  83     if(NOT FACTORY IN_LIST ALL_KNOWN_FACTORIES)
  84       message(FATAL_ERROR "Unknown factory: ${FACTORY}")
  85     endif()
  86   ENDFOREACH()
  87 ENDMACRO()
  88
  89 MACRO(ADD_TESH_FACTORIES NAME FACTORIES)
  90   SET(ARGR ${ARGV})
  91   LIST(REMOVE_AT ARGR 0) # remove name
  92   FOREACH(I ${FACTORIES}) # remove all factories
  93     LIST(REMOVE_AT ARGR 0)
  94   ENDFOREACH()
  95   SETUP_FACTORIES_LIST(${FACTORIES})
  96   FOREACH(FACTORY ${FACTORIES_LIST})
  97     ADD_TESH("${NAME}-${FACTORY}" "--cfg" "contexts/factory:${FACTORY}" ${ARGR})
  98   ENDFOREACH()
  99 ENDMACRO()
 100
 101 MACRO(SET_TESH_PROPERTIES NAME FACTORIES)
 102   SET(ARGR ${ARGV})
 103   LIST(REMOVE_AT ARGR 0) # remove name
 104   FOREACH(I ${FACTORIES}) # remove all factories
 105     LIST(REMOVE_AT ARGR 0)
 106   ENDFOREACH()
 107   SETUP_FACTORIES_LIST(${FACTORIES})
 108   FOREACH(FACTORY ${FACTORIES_LIST})
 109     set_tests_properties("${NAME}-${FACTORY}" PROPERTIES ${ARGR})
 110   ENDFOREACH()
 111 ENDMACRO()
 112
 113 # New tests should use the Catch Framework
 114 set(UNIT_TESTS  src/xbt/unit-tests_main.cpp
 115                 src/kernel/resource/NetworkModelFactors_test.cpp
 116                 src/kernel/resource/SplitDuplexLinkImpl_test.cpp
 117                 src/kernel/resource/profile/Profile_test.cpp
 118                 src/kernel/routing/DijkstraZone_test.cpp
 119                 src/kernel/routing/DragonflyZone_test.cpp
 120                 src/kernel/routing/FatTreeZone_test.cpp
 121                 src/kernel/routing/FloydZone_test.cpp
 122                 src/kernel/routing/FullZone_test.cpp
 123                 src/kernel/routing/StarZone_test.cpp
 124                 src/kernel/routing/TorusZone_test.cpp
 125                 src/xbt/config_test.cpp
 126                 src/xbt/dict_test.cpp
 127                 src/xbt/dynar_test.cpp
 128                 src/xbt/random_test.cpp
 129                 src/xbt/xbt_str_test.cpp
 130                 src/xbt/utils/iter/subsets_tests.cpp
 131                 src/kernel/lmm/maxmin_test.cpp)
 132
 133 set(MC_UNIT_TESTS src/mc/explo/odpor/ClockVector_test.cpp
 134                   src/mc/explo/odpor/Execution_test.cpp
 135                   src/mc/explo/odpor/WakeupTree_test.cpp)
 136
 137 set(STATEFUL_MC_UNIT_TESTS src/mc/sosp/Snapshot_test.cpp
 138                            src/mc/sosp/PageStore_test.cpp
 139                            src/mc/explo/udpor/Unfolding_test.cpp
 140                            src/mc/explo/udpor/UnfoldingEvent_test.cpp
 141
 142                            src/mc/explo/udpor/EventSet_test.cpp
 143                            src/mc/explo/udpor/History_test.cpp
 144                            src/mc/explo/udpor/Configuration_test.cpp)
 145
 146 if (SIMGRID_HAVE_MC)
 147   set(UNIT_TESTS ${UNIT_TESTS} ${MC_UNIT_TESTS})
 148 else()
 149   set(EXTRA_DIST ${EXTRA_DIST} ${MC_UNIT_TESTS})
 150 endif()
 151 if (SIMGRID_HAVE_STATEFUL_MC)
 152   set(UNIT_TESTS ${UNIT_TESTS} ${STATEFUL_MC_UNIT_TESTS})
 153 else()
 154   set(EXTRA_DIST ${EXTRA_DIST} ${STATEFUL_MC_UNIT_TESTS})
 155 endif()
 156 if (SIMGRID_HAVE_EIGEN3)
 157   set(UNIT_TESTS ${UNIT_TESTS} src/kernel/lmm/bmf_test.cpp)
 158 else()
 159   set(EXTRA_DIST ${EXTRA_DIST} src/kernel/lmm/bmf_test.cpp)
 160 endif()
 161 set(EXTRA_DIST ${EXTRA_DIST} src/kernel/routing/NetZone_test.hpp)
 162
 163 add_executable       (unit-tests EXCLUDE_FROM_ALL ${UNIT_TESTS})
 164 add_dependencies     (tests unit-tests)
 165 target_link_libraries(unit-tests simgrid)
 166 ADD_TEST(unit-tests ${VALGRIND_WRAPPER_UNBOXED} ${CMAKE_BINARY_DIR}/unit-tests)
 167 set_property(TARGET unit-tests APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}")
 168 set(EXTRA_DIST ${EXTRA_DIST} ${UNIT_TESTS})
 169
 170 unset(UNIT_TESTS)