tools/cmake/Modules/FindNS3.cmake

   1 # Try to find the ns-3 library.
   2 #
   3 # The user can hint a path using the NS3_HINT option.
   4 #
   5 # Once done, the following will be defined:
   6 #
   7 #  NS3_INCLUDE_DIRS - the ns-3 include directories
   8 #  NS3_LIBRARY_PATH - path to the libs
   9 #  NS3_LIBRARIES - link these to use ns-3 (full path to libs)
  10 #
  11 # This could be improved in many ways (patches welcome):
  12 #  - No way to specify a minimal version (v3.26 is hardcoded).
  13 #  - No proper find_package() integration
  14
  15 ## ADDING A ns-3 VERSION.
  16 #   - Add "ns3.${version}-core ns3.${version}-core-debug ns3.${version}-core-optimized" to the NAME line of the find_library below
  17 #   - Add "include/ns3{version}" to the PATH_SUFFIXES line of the find_path below
  18
  19 set(SIMGRID_HAVE_NS3 0)
  20 set(NS3_HINT ${ns3_path} CACHE PATH "Path to search for NS3 lib and include")
  21
  22 find_library(NS3_LIBRARIES
  23   NAME ns3-core
  24        ns3.22-core ns3.22-core-optimized ns3.22-core-debug
  25        ns3.23-core ns3.23-core-optimized ns3.23-core-debug
  26        ns3.24-core ns3.24-core-optimized ns3.24-core-debug
  27        ns3.25-core ns3.25-core-optimized ns3.25-core-debug
  28        ns3.26-core ns3.26-core-optimized ns3.26-core-debug
  29        ns3.27-core ns3.27-core-optimized ns3.27-core-debug
  30        ns3.28-core ns3.28-core-optimized ns3.28-core-debug
  31        ns3.29-core ns3.29-core-optimized ns3.29-core-debug
  32        ns3.30-core ns3.30-core-optimized ns3.30-core-debug
  33        ns3.31-core ns3.31-core-optimized ns3.31-core-debug
  34        ns3.32-core ns3.32-core-optimized ns3.32-core-debug
  35        ns3.33-core ns3.33-core-optimized ns3.33-core-debug
  36        ns3.34-core ns3.34-core-optimized ns3.34-core-debug
  37   PATH_SUFFIXES lib64 lib ns3/lib
  38   PATHS
  39   ${NS3_HINT}
  40   )
  41
  42 find_path(NS3_INCLUDE_DIR
  43   NAME ns3/core-module.h
  44   PATH_SUFFIXES include ns3/include
  45                 include/ns3.22 include/ns3.23 include/ns3.24 include/ns3.25 include/ns3.26 include/ns3.27 include/ns3.28 include/ns3.29 include/ns3.30
  46                 include/ns3.31 include/ns3.32 include/ns3.33 include/ns3.34
  47   PATHS
  48   ${NS3_HINT}
  49   )
  50
  51 if(NS3_INCLUDE_DIR)
  52   message(STATUS "Looking for ns3/core-module.h - found")
  53 else()
  54   message(STATUS "Looking for ns3/core-module.h - not found")
  55 endif()
  56 mark_as_advanced(NS3_INCLUDE_DIR)
  57
  58 message(STATUS "Looking for lib ns3-core")
  59 if(NS3_LIBRARIES)
  60   message(STATUS "Looking for lib ns3-core - found")
  61 else()
  62   message(STATUS "Looking for lib ns3-core - not found")
  63 endif()
  64 mark_as_advanced(NS3_LIBRARIES)
  65
  66 if(NS3_INCLUDE_DIR)
  67   if(NS3_LIBRARIES)
  68     set(SIMGRID_HAVE_NS3 1)
  69     if(NS3_LIBRARIES MATCHES "-optimized")
  70       set (NS3_SUFFIX "-optimized")
  71     elseif(NS3_LIBRARIES MATCHES "-debug")
  72       set (NS3_SUFFIX "-debug")
  73     else()
  74       set (NS3_SUFFIX "")
  75     endif()
  76
  77     string(REGEX REPLACE ".*ns([.0-9]+)-core.*" "\\1" NS3_VERSION "${NS3_LIBRARIES}")
  78     get_filename_component(NS3_LIBRARY_PATH "${NS3_LIBRARIES}" PATH)
  79
  80     # Compute NS3_PATH
  81     string(REGEX REPLACE "(.*)/lib" "\\1" NS3_PATH "${NS3_LIBRARY_PATH}")
  82
  83     message(STATUS "ns-3 found (v${NS3_VERSION}; incl:${NS3_INCLUDE_DIR}; lib: ${NS3_LIBRARY_PATH}).")
  84
  85     if (NOT NS3_LIBRARY_PATH STREQUAL "/usr/lib")
  86       string(REGEX MATCH "${NS3_LIBRARY_PATH}" MatchResult "$ENV{LD_LIBRARY_PATH}")
  87       if(NOT MatchResult)
  88         message(STATUS "Warning: NS3 not installed in system path, and not listed in LD_LIBRARY_PATH."
  89                        "         You want to: export LD_LIBRARY_PATH=${NS3_LIBRARY_PATH}\${LD_LIBRARY_PATH:+:\$LD_LIBRARY_PATH}")
  90       endif()
  91     endif()
  92   endif()
  93 endif()
  94 mark_as_advanced(NS3_LIBRARY_PATH)
  95
  96 if(SIMGRID_HAVE_NS3)
  97   link_directories(${NS3_LIBRARY_PATH})
  98   include_directories(${NS3_INCLUDE_DIR})
  99 else()
 100   message(STATUS "Warning: Please install ns-3 (version 3.22 or higher -- http://www.nsnam.org/releases/) or disable this feature.")
 101 endif()