examples/cpp/CMakeLists.txt

   1 # Regular examples: with only one source and tested with all factories by default
   2 #################################################################################
   3 ### Define the examples' specificities
   4
   5 set(_app-bittorrent_sources app-bittorrent/s4u-bittorrent.cpp app-bittorrent/s4u-bittorrent.hpp
   6                             app-bittorrent/s4u-peer.cpp app-bittorrent/s4u-peer.hpp
   7                             app-bittorrent/s4u-tracker.cpp app-bittorrent/s4u-tracker.hpp)
   8 set(_dht-chord_sources    dht-chord/s4u-dht-chord.cpp dht-chord/s4u-dht-chord.hpp dht-chord/s4u-dht-chord-node.cpp)
   9 set(_dht-kademlia_sources dht-kademlia/s4u-dht-kademlia.cpp dht-kademlia/s4u-dht-kademlia.hpp
  10                           dht-kademlia/node.cpp dht-kademlia/node.hpp
  11                           dht-kademlia/routing_table.cpp dht-kademlia/routing_table.hpp
  12                           dht-kademlia/answer.cpp dht-kademlia/answer.hpp dht-kademlia/message.hpp)
  13
  14 set(_actor-stacksize_factories "^thread") # Threads ignore modifications of the stack size
  15
  16 # The maestro-set example only works for threads and when not using windows.
  17 set(_maestro-set_factories "thread")
  18 if(WIN32)
  19   set(_maestro-set_disable 1)
  20 endif()
  21
  22 if(SIMGRID_HAVE_MC)
  23   # These tests timeout with threads, maybe because of dwarf parsing? not sure
  24   foreach(example mc-bugged1 mc-bugged2 mc-failing-assert mc-electric-fence)
  25      set(_${example}_factories "^thread") # Timeout
  26      add_dependencies(tests-mc s4u-${example})
  27   endforeach()
  28
  29   if(HAVE_C_STACK_CLEANER)
  30     add_executable       (s4u-mc-bugged1-liveness-cleaner-on  EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  31     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-on  simgrid)
  32     set_target_properties(s4u-mc-bugged1-liveness-cleaner-on  PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fstack-cleaner")
  33     add_dependencies(tests-mc s4u-mc-bugged1-liveness-cleaner-on)
  34
  35     add_executable       (s4u-mc-bugged1-liveness-cleaner-off EXCLUDE_FROM_ALL s4u-mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp)
  36     target_link_libraries(s4u-mc-bugged1-liveness-cleaner-off simgrid)
  37     set_target_properties(s4u-mc-bugged1-liveness-cleaner-off PROPERTIES COMPILE_FLAGS "-DGARBAGE_STACK -fno-stack-cleaner")
  38     add_dependencies(tests-mc s4u-mc-bugged1-liveness-cleaner-off)
  39   endif()
  40
  41   # Model-checking liveness
  42   if(HAVE_UCONTEXT_CONTEXTS AND SIMGRID_PROCESSOR_x86_64)
  43     # liveness model-checking works only on 64bits (for now ...)
  44     set(_mc-bugged1-liveness_factories "ucontext")
  45     add_dependencies(tests-mc s4u-mc-bugged1-liveness)
  46     set(_mc-bugged2-liveness_factories "ucontext")
  47   else()
  48     set(_mc-bugged1-liveness_disable 1)
  49   endif()
  50
  51   # This example never ends, disable it for now
  52   set(_mc-bugged2-liveness_disable 1)
  53
  54   ADD_TESH(s4u-mc-bugged1-liveness-visited-ucontext --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness
  55                                                     --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  56                                                     --cd ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness
  57                                                      ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh)
  58   IF(HAVE_C_STACK_CLEANER)
  59     add_dependencies(tests-mc s4u-mc-bugged1-liveness-stack-cleaner)
  60     # This test checks if the stack cleaner is making a difference:
  61     ADD_TEST(s4u-mc-bugged1-liveness-stack-cleaner ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
  62                                                    ${CMAKE_HOME_DIRECTORY}/examples/cpp/mc-bugged1-liveness/
  63                                                    ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/)
  64   ENDIF()
  65
  66   if(enable_coverage)
  67     foreach (example mc-bugged1 mc-bugged2 mc-electric-fence mc-failing-assert)
  68       ADD_TEST(cover-${example} ${CMAKE_CURRENT_BINARY_DIR}/${example}/s4u-${example} ${CMAKE_HOME_DIRECTORY}/examples/platforms/model_checker_platform.xml)
  69     endforeach()
  70     ADD_TEST(cover-mc-bugged1-liveness ${CMAKE_CURRENT_BINARY_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness ${CMAKE_HOME_DIRECTORY}/examples/platforms/small_platform.xml 1 1001)
  71   endif()
  72
  73 else()
  74   foreach (example mc-bugged1 mc-bugged2  mc-centralized-mutex mc-failing-assert mc-electric-fence
  75                    mc-bugged1-liveness mc-bugged2-liveness)
  76     set(_${example}_disable 1)
  77   endforeach()
  78 endif()
  79
  80 # Hijack some regular tests to run them on top of the MC
  81 foreach (example synchro-barrier synchro-mutex synchro-semaphore)
  82   set(tesh_files ${tesh_files} ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-mc-${example}.tesh)
  83
  84   if (SIMGRID_HAVE_MC)
  85     ADD_TESH(s4u-mc-${example}
  86              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
  87              --setenv libdir=${CMAKE_BINARY_DIR}/lib
  88              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
  89              --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
  90              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
  91              ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-mc-${example}.tesh)
  92   endif()
  93 endforeach()
  94
  95
  96 if(NOT HAVE_GRAPHVIZ)
  97   set(_dag-from-dot_disable 1)
  98 endif()
  99
 100 if(NOT SIMGRID_HAVE_NS3)
 101   foreach (example network-ns3 network-ns3-wifi)
 102     set(_${example}_disable 1)
 103   endforeach()
 104 endif()
 105
 106 # Deal with each example
 107
 108 foreach (example activity-testany activity-waitany
 109                  actor-create actor-daemon actor-exiting actor-join actor-kill
 110                  actor-lifetime actor-migrate actor-suspend actor-yield actor-stacksize
 111                  app-bittorrent app-chainsend app-token-ring
 112                  comm-pingpong comm-ready comm-serialize comm-suspend comm-testany comm-wait comm-waitany comm-waitall comm-waituntil
 113                  comm-dependent comm-host2host comm-failure comm-throttling
 114                  cloud-capping cloud-migration cloud-simple
 115                  dag-comm dag-from-dax dag-from-dot dag-failure dag-io dag-scheduling dag-simple
 116                  dht-chord dht-kademlia
 117                  energy-exec energy-boot energy-link energy-vm energy-exec-ptask energy-wifi
 118                  engine-filtering engine-run-partial
 119                  exec-async exec-basic exec-dvfs exec-remote exec-waitany exec-waitfor exec-dependent exec-unassigned
 120                  exec-ptask-multicore exec-ptask-multicore-latency exec-cpu-nonlinear exec-cpu-factors exec-failure exec-threads
 121                  maestro-set
 122                  mc-bugged1 mc-bugged1-liveness mc-bugged2 mc-bugged2-liveness mc-centralized-mutex mc-electric-fence mc-failing-assert
 123                  network-ns3 network-ns3-wifi network-wifi
 124                  io-async io-priority io-degradation io-file-system io-file-remote io-disk-raw io-dependent
 125                  platform-failures platform-profile platform-properties
 126                  plugin-host-load plugin-link-load plugin-prodcons
 127                  replay-comm replay-io
 128                  routing-get-clusters
 129                  synchro-barrier synchro-condition-variable synchro-condition-variable-waituntil synchro-mutex synchro-semaphore
 130                  clusters-multicpu network-factors network-nonlinear)
 131
 132   # Use default source file unless specified otherwise
 133   if(NOT DEFINED _${example}_sources)
 134     set(_${example}_sources ${example}/s4u-${example}.cpp)
 135   endif()
 136
 137   if(NOT DEFINED _${example}_disable)
 138     add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${_${example}_sources})
 139     add_dependencies     (tests s4u-${example})
 140     add_dependencies     (s4u-${example} platf_cpp)
 141     target_link_libraries(s4u-${example} simgrid)
 142     set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 143
 144     # Use default factories unless specified otherwise
 145     if(NOT DEFINED _${example}_factories)
 146       set(_${example}_factories "*")
 147     endif()
 148 #    message("Factories of ${example}: ${_${example}_factories}")
 149
 150     ADD_TESH_FACTORIES(s4u-${example} "${_${example}_factories}"
 151                                       --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 152                                       --setenv libdir=${CMAKE_BINARY_DIR}/lib
 153                                       --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 154                                       --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 155                                       --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 156                                       ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 157   else()
 158     message(STATUS "Example ${example} disabled, thus not compiled.")
 159     unset(_${example}_disable)
 160   endif()
 161
 162   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 163   foreach(file ${_${example}_sources})
 164     set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/${file})
 165   endforeach()
 166
 167   unset(_${example}_factories)
 168   unset(_${example}_sources)
 169 endforeach()
 170
 171
 172 # Specific examples
 173 ###################
 174
 175 # MASTERWORKERS EXAMPLE
 176 foreach(variant fun class)
 177   add_executable       (s4u-app-masterworkers-${variant} EXCLUDE_FROM_ALL app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 178   target_link_libraries(s4u-app-masterworkers-${variant} simgrid)
 179   set_target_properties(s4u-app-masterworkers-${variant} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/app-masterworkers)
 180   add_dependencies(tests s4u-app-masterworkers-${variant})
 181
 182   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers-${variant}.cpp)
 183 endforeach()
 184 set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers.tesh)
 185
 186 # The tests the parallel variant of of DHTs
 187
 188 if(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_PROCESSOR STREQUAL "i386" AND CMAKE_SIZEOF_VOID_P EQUAL 8)
 189   # Thread-local storage (TLS) is needed for parallel execution, but it doesn't
 190   # play well with Ucontexts on 64bit SunOS (at least on x86_64).
 191   set(parallel-factories "^ucontext")
 192 else()
 193   set(parallel-factories "*")
 194 endif()
 195
 196 foreach(example app-bittorrent app-masterworkers
 197                 dht-chord dht-kademlia
 198                 )
 199   ADD_TESH_FACTORIES(s4u-${example}-parallel "${parallel-factories}" --cfg contexts/nthreads:4 ${CONTEXTS_SYNCHRO}
 200                                              --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 201                                              --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 202                                              --cd ${CMAKE_CURRENT_SOURCE_DIR}/${example}
 203                                              ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 204 endforeach()
 205
 206 # Examples not accepting factories
 207 ##################################
 208
 209 foreach (example exec-ptask trace-categories trace-masterworkers trace-platform trace-process-migration
 210                  trace-host-user-variables trace-link-user-variables trace-route-user-variables)
 211   add_executable       (s4u-${example} EXCLUDE_FROM_ALL ${example}/s4u-${example}.cpp)
 212   target_link_libraries(s4u-${example} simgrid)
 213   set_target_properties(s4u-${example} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${example})
 214   add_dependencies(tests s4u-${example})
 215
 216   set(tesh_files    ${tesh_files}    ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.tesh)
 217   set(examples_src  ${examples_src}  ${CMAKE_CURRENT_SOURCE_DIR}/${example}/s4u-${example}.cpp)
 218
 219   ADD_TESH(s4u-${example} --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/${example}
 220                           --setenv srcdir=${CMAKE_CURRENT_SOURCE_DIR}/${example}
 221                           --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 222                           --cd ${CMAKE_CURRENT_BINARY_DIR}/${example}
 223                           ${CMAKE_HOME_DIRECTORY}/examples/cpp/${example}/s4u-${example}.tesh)
 224 endforeach()
 225
 226 if (NOT enable_memcheck AND NOT WIN32)
 227   ADD_TESH(debug-breakpoint --setenv bindir=${CMAKE_CURRENT_BINARY_DIR}/comm-pingpong
 228                             --setenv platfdir=${CMAKE_HOME_DIRECTORY}/examples/platforms
 229                             ${CMAKE_CURRENT_SOURCE_DIR}/comm-pingpong/debug-breakpoint.tesh)
 230 endif()
 231
 232 # Add all extra files to the archive
 233 ####################################
 234 set(examples_src  ${examples_src} ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.cpp        PARENT_SCOPE)
 235 set(tesh_files    ${tesh_files}   ${CMAKE_CURRENT_SOURCE_DIR}/comm-pingpong/debug-breakpoint.tesh
 236                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness.tesh
 237                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-visited.tesh  PARENT_SCOPE)
 238 set(xml_files     ${xml_files}    ${CMAKE_CURRENT_SOURCE_DIR}/actor-create/s4u-actor-create_d.xml
 239                                   ${CMAKE_CURRENT_SOURCE_DIR}/actor-lifetime/s4u-actor-lifetime_d.xml
 240                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-bittorrent/s4u-app-bittorrent_d.xml
 241                                   ${CMAKE_CURRENT_SOURCE_DIR}/app-masterworkers/s4u-app-masterworkers_d.xml
 242                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-scheduling/Montage_25.xml
 243                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-chord/s4u-dht-chord_d.xml
 244                                   ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/s4u-dht-kademlia_d.xml
 245                                   ${CMAKE_CURRENT_SOURCE_DIR}/io-file-remote/s4u-io-file-remote_d.xml
 246                                   ${CMAKE_CURRENT_SOURCE_DIR}/platform-failures/s4u-platform-failures_d.xml
 247                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split_d.xml
 248                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm_d.xml
 249                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io_d.xml
 250                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3hosts_2links_d.xml
 251                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links-timer_d.xml
 252                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/3links_d.xml
 253                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/crosstraffic_d.xml
 254                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/dogbone_d.xml
 255                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/onelink_d.xml
 256                                   ${CMAKE_CURRENT_SOURCE_DIR}/network-ns3/one_cluster_d.xml                PARENT_SCOPE)
 257 set(bin_files     ${bin_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dht-kademlia/generate.py
 258                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/s4u-mc-bugged1-liveness-stack-cleaner
 259                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged1-liveness/promela_bugged1_liveness
 260                                   ${CMAKE_CURRENT_SOURCE_DIR}/mc-bugged2-liveness/promela_bugged2_liveness PARENT_SCOPE)
 261 set(txt_files     ${txt_files}    ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax/simple_dax_with_cycle.xml
 262                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dax/smalldax.xml
 263                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot/dag.dot
 264                                   ${CMAKE_CURRENT_SOURCE_DIR}/dag-from-dot/dag_with_cycle.dot
 265                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p0.txt
 266                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm-split-p1.txt
 267                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-comm/s4u-replay-comm.txt
 268                                   ${CMAKE_CURRENT_SOURCE_DIR}/replay-io/s4u-replay-io.txt                  PARENT_SCOPE)