tools/cmake/Flags.cmake

   1 ##
   2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
   3 ##
   4 ##   It is only used for gcc and clang. MSVC builds don't load this file.
   5 ##
   6 ##   These flags do break some classical CMake tests, so you don't
   7 ##   want to do so before the very end of the configuration.
   8 ##
   9 ##   Other compiler flags (C/C++ standard version) are tested and set
  10 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
  11
  12 set(warnCFLAGS "")
  13 set(optCFLAGS "")
  14 set(warnCXXFLAGS "")
  15
  16 if(enable_compile_warnings)
  17   set(warnCFLAGS "-fno-common -Wall -Wextra -Wunused -Wmissing-declarations -Wpointer-arith -Wwrite-strings -Wno-unused-function -Wno-unused-local-typedefs -Wno-unused-parameter -Wno-strict-aliasing")
  18
  19   if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  20     # ignore remarks:
  21     # 191: type qualifier is meaningless on cast type
  22     # 1418: external function definition with no prior declaration
  23     # 2196: routine is both "inline" and "noinline"
  24     # 2651: attribute does not apply to any entity
  25     # 3179: deprecated conversion of string literal to char* (should be const char*)
  26     # set as warning:
  27     # 597: entity-kind "entity" will not be called for implicit or explicit conversions
  28     # 2330: argument of type "type" is incompatible with parameter of type "type" (dropping qualifiers)
  29     # 11003: no IR in object file xxxx; was the source file compiled with xxxx
  30     set(warnCFLAGS "${warnCFLAGS} -diag-disable=191,1418,2196,2651,3179 -diag-warning=597,2330,11003")
  31   endif()
  32   set(warnCXXFLAGS "${warnCFLAGS}")
  33
  34   if(CMAKE_COMPILER_IS_GNUCC)
  35     set(warnCFLAGS "${warnCFLAGS} -Wclobbered -Wformat-signedness -Wno-error=clobbered -Wno-error=attributes -Wno-error=maybe-uninitialized")
  36   endif()
  37
  38   if(CMAKE_COMPILER_IS_GNUCXX)
  39     set(warnCXXFLAGS "${warnCXXFLAGS} -Wclobbered -Wformat-signedness -Wno-error=clobbered -Wno-free-nonheap-object -Wno-unused-local-typedefs -Wno-error=attributes -Wno-error=maybe-uninitialized")
  40     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "8.0")
  41       # workaround for https://gcc.gnu.org/bugzilla/show_bug.cgi?id=81767
  42       set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-error=unused-variable")
  43     endif()
  44   endif()
  45
  46   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  47     # don't care about class that become struct, avoid issue of empty C structs
  48     # size (coming from libunwind.h)
  49     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-mismatched-tags -Wno-extern-c-compat")
  50     # also ignore deprecated builtins (seen with clang 15 + boost 1.79)
  51     if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL "15.0")
  52       set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-deprecated-builtins")
  53     endif()
  54   endif()
  55
  56   # the one specific to C but refused by C++
  57   set(warnCFLAGS "${warnCFLAGS} -Wmissing-prototypes")
  58
  59   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC|PGI")
  60     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
  61   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Flang")
  62     # flang >= 7 has a bug with common and debug flags. Ignore cmake-added -g in this case.
  63     # https://github.com/flang-compiler/flang/issues/671
  64     set(CMAKE_Fortran_FLAGS "-Wall")
  65   elseif(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
  66     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -warn all")
  67   endif()
  68 endif()
  69
  70 # NDEBUG gives a lot of "initialized but unused variables" errors. Don't die anyway.
  71 if(enable_compile_warnings AND enable_debug)
  72   set(warnCFLAGS "${warnCFLAGS} -Werror")
  73   set(warnCXXFLAGS "${warnCXXFLAGS} -Werror")
  74   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC")
  75     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Werror -Werror=format-security")
  76   endif()
  77 endif()
  78
  79 # Activate the warnings on #if FOOBAR when FOOBAR has no value
  80 # It breaks on FreeBSD within Boost headers, so activate this only in Pure Hardcore debug mode.
  81 if(enable_maintainer_mode)
  82   set(warnCFLAGS "${warnCFLAGS} -Wundef")
  83   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wundef")
  84 endif()
  85
  86 # Se the optimisation flags
  87 # NOTE, we should CMAKE_BUILD_TYPE for this
  88 if(enable_compile_optimizations)
  89   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
  90 else()
  91   set(optCFLAGS "-O0 ")
  92 endif()
  93
  94 #ARM platforms have signed char by default, switch to unsigned for consistancy
  95 if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "aarch64")
  96   set(optCFLAGS "${optCFLAGS} -fsigned-char")
  97 endif()
  98
  99 if(enable_compile_optimizations AND CMAKE_COMPILER_IS_GNUCC
 100     AND (NOT enable_model-checking))
 101   # This is redundant (already in -03):
 102   set(optCFLAGS "${optCFLAGS} -finline-functions ")
 103 endif()
 104
 105 # Do not leak the current directory into the binaries
 106 if(CMAKE_COMPILER_IS_GNUCC AND NOT enable_coverage)
 107   if (CMAKE_VERSION VERSION_LESS "3.20")
 108     file(RELATIVE_PATH RELATIVE_SOURCE_DIR ${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR})
 109   else() # cmake >= 3.20
 110     cmake_path(RELATIVE_PATH CMAKE_SOURCE_DIR BASE_DIRECTORY ${CMAKE_BINARY_DIR} OUTPUT_VARIABLE RELATIVE_SOURCE_DIR)
 111   endif()
 112   message(STATUS "Relative source directory is \"${RELATIVE_SOURCE_DIR}\".")
 113   if (CMAKE_C_COMPILER_VERSION VERSION_LESS "8.0")
 114     set(optCFLAGS "${optCFLAGS} -fdebug-prefix-map=\"${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}\"")
 115   else()
 116     set(optCFLAGS "${optCFLAGS} -ffile-prefix-map=\"${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}\"")
 117   endif()
 118 endif()
 119
 120 # Configure LTO
 121 if(enable_lto) # User wants LTO. Try if we can do that
 122   set(enable_lto OFF)
 123   if(enable_compile_optimizations
 124       AND (NOT enable_model-checking))
 125     if(CMAKE_VERSION VERSION_LESS "3.9")
 126       if ( CMAKE_COMPILER_IS_GNUCC
 127          AND (CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8.5")
 128          AND (LINKER_VERSION VERSION_GREATER "2.22"))
 129         set(enable_lto ON)
 130       endif()
 131     else()
 132       include(CheckIPOSupported)
 133       check_ipo_supported(RESULT ipo LANGUAGES C CXX)
 134       if(ipo)
 135         set(enable_lto ON)
 136       endif()
 137     endif()
 138   endif()
 139
 140   if(enable_lto)
 141     message(STATUS "LTO seems usable.")
 142   else()
 143     if(NOT enable_compile_optimizations)
 144       message(STATUS "LTO disabled: Compile-time optimizations turned off.")
 145     else()
 146       if(enable_model-checking)
 147         message(STATUS "LTO disabled when compiling with model-checking.")
 148       else()
 149         message(STATUS "LTO does not seem usable -- try updating your build chain.")
 150       endif()
 151     endif()
 152   endif()
 153 else()
 154   message(STATUS "LTO disabled on the command line.")
 155 endif()
 156 if(enable_lto) # User wants LTO, and it seems usable. Go for it
 157   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
 158   if(LTO_EXTRA_FLAG AND CMAKE_COMPILER_IS_GNUCC)
 159     list(APPEND CMAKE_C_COMPILE_OPTIONS_IPO "-flto=${LTO_EXTRA_FLAG}")
 160     list(APPEND CMAKE_CXX_COMPILE_OPTIONS_IPO "-flto=${LTO_EXTRA_FLAG}")
 161   endif()
 162
 163   # Activate fat-lto-objects in case LD and gfortran differ too much.
 164   # Only test with GNU as it's the only case I know (clang+gfortran+lld)
 165   execute_process(COMMAND ${CMAKE_LINKER} -v OUTPUT_VARIABLE LINKER_ID ERROR_VARIABLE LINKER_ID)
 166   string(REGEX MATCH "GNU" LINKER_ID "${LINKER_ID}")
 167   if(${CMAKE_Fortran_COMPILER_ID} MATCHES "GNU"
 168      AND NOT "${LINKER_ID}" MATCHES "GNU")
 169        list(APPEND CMAKE_Fortran_COMPILE_OPTIONS_IPO "-ffat-lto-objects")
 170   endif()
 171
 172   # "Since version 4.9 gcc produces slim object files that only contain
 173   # the intermediate representation. In order to handle archives of
 174   # these objects you have to use the gcc wrappers:
 175   # gcc-ar, gcc-nm and gcc-ranlib."
 176   if(${CMAKE_C_COMPILER_ID} STREQUAL "GNU"
 177       AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8")
 178     set (CMAKE_AR gcc-ar)
 179     set (CMAKE_RANLIB gcc-ranlib)
 180   endif()
 181 endif()
 182
 183 if(enable_model-checking AND enable_compile_optimizations)
 184   # Forget it, do not optimize the code (because it confuses the MC):
 185   set(optCFLAGS "-O0")
 186   # But you can still optimize this:
 187   set(src_list ${simgrid_sources})
 188   # except...
 189   list(FILTER src_list EXCLUDE REGEX "^src/kernel/activity/")
 190   list(FILTER src_list EXCLUDE REGEX "^src/kernel/actor/")
 191   list(FILTER src_list EXCLUDE REGEX "^src/kernel/context/")
 192   list(FILTER src_list EXCLUDE REGEX "^src/s4u/")
 193   foreach(src ${src_list})
 194       set (mcCFLAGS "-O3 -funroll-loops -fno-strict-aliasing")
 195       if(CMAKE_COMPILER_IS_GNUCC)
 196         set (mcCFLAGS "${mcCFLAGS} -finline-functions")
 197       endif()
 198       set_source_files_properties(${src} PROPERTIES COMPILE_FLAGS ${mcCFLAGS})
 199   endforeach()
 200 endif()
 201
 202 if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 203   # honor parentheses when determining the order of expression evaluation.
 204   # disallow optimizations for floating-point arithmetic with Nans or +-Infs (breaks Eigen3)
 205   set(optCFLAGS "${optCFLAGS} -fprotect-parens -fno-finite-math-only")
 206 endif()
 207
 208 if(NOT enable_debug)
 209   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
 210   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
 211 endif()
 212
 213 set(CMAKE_C_FLAGS   "${warnCFLAGS} ${CMAKE_C_FLAGS}   ${optCFLAGS}")
 214 set(CMAKE_CXX_FLAGS "${warnCXXFLAGS} ${CMAKE_CXX_FLAGS} ${optCFLAGS}")
 215
 216 # Try to make Mac a bit more compliant to open source standards
 217 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 218   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 219 endif()
 220
 221 set(TESH_OPTION "")
 222 if(enable_coverage)
 223   find_program(GCOV_PATH NAMES ENV{GCOV} gcov)
 224   if(GCOV_PATH)
 225     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE FILEPATH "Coverage testing tool (gcov)" FORCE)
 226     set(COVERAGE_BUILD_FLAGS "-fprofile-arcs -ftest-coverage -fprofile-abs-path")
 227     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE ${COVERAGE_BUILD_FLAGS}")
 228     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${COVERAGE_BUILD_FLAGS}")
 229     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} ${COVERAGE_BUILD_FLAGS}")
 230     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DCOVERAGE ${COVERAGE_BUILD_FLAGS}")
 231     add_definitions(${COVERAGE_BUILD_FLAGS})
 232   endif()
 233 endif()
 234
 235 if(enable_address_sanitizer)
 236     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 237     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 238     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=address")
 239     set(TESH_OPTION --enable-sanitizers)
 240     try_compile(HAVE_SANITIZER_ADDRESS ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp)
 241     try_compile(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp
 242       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 243 else()
 244     set(HAVE_SANITIZER_ADDRESS FALSE CACHE INTERNAL "")
 245     set(HAVE_SANITIZER_ADDRESS_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 246 endif()
 247
 248 if(enable_thread_sanitizer)
 249     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 250     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 251     if(CMAKE_COMPILER_IS_GNUCXX AND (NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "12.0")))
 252         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=tsan")
 253     endif()
 254     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=thread -no-pie")
 255     try_compile(HAVE_SANITIZER_THREAD ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp)
 256     try_compile(HAVE_SANITIZER_THREAD_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_tsan.cpp
 257       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 258 else()
 259     set(HAVE_SANITIZER_THREAD FALSE CACHE INTERNAL "")
 260     set(HAVE_SANITIZER_THREAD_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 261 endif()
 262
 263 if(enable_undefined_sanitizer)
 264     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 265     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 266     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=undefined")
 267 endif()
 268
 269 if(NOT $ENV{CFLAGS} STREQUAL "")
 270   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
 271   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
 272 endif()
 273
 274 if(NOT $ENV{CXXFLAGS} STREQUAL "")
 275   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
 276   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
 277 endif()
 278
 279 if(NOT $ENV{LDFLAGS} STREQUAL "")
 280   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
 281   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
 282 endif()