tools/cmake/Tests.cmake

   1 IF(enable_smpi AND NOT WIN32)
   2   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpicc)
   3   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpicxx)
   4   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpiff)
   5   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpif90)
   6   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpirun)
   7 ENDIF()
   8
   9 SET(TESH_OPTION "--ignore-jenkins")
  10 SET(TESH_COMMAND "${PYTHON_EXECUTABLE}" ${CMAKE_BINARY_DIR}/bin/tesh)
  11
  12 IF(enable_memcheck)
  13   INCLUDE(FindValgrind)
  14
  15   if (NOT VALGRIND_EXE MATCHES "NOTFOUND")
  16     execute_process(COMMAND ${VALGRIND_EXE} --version  OUTPUT_VARIABLE "VALGRIND_VERSION")
  17     message(STATUS "Valgrind version: ${VALGRIND_VERSION}")
  18
  19     set(TESH_WRAPPER ${CMAKE_HOME_DIRECTORY}/tools/cmake/scripts/my_valgrind.pl)
  20     set(TESH_WRAPPER ${TESH_WRAPPER}\ --trace-children=yes\ --trace-children-skip=/usr/bin/*,/bin/*\ --leak-check=full\ --show-reachable=yes\ --track-origins=no\ --read-var-info=no\ --num-callers=20\ --suppressions=${CMAKE_HOME_DIRECTORY}/tools/simgrid.supp\ )
  21     if(enable_memcheck_xml)
  22       SET(TESH_WRAPPER ${TESH_WRAPPER}\ --xml=yes\ --xml-file=memcheck_test_%p.memcheck\ --child-silent-after-fork=yes\ )
  23     endif()
  24
  25 #    message(STATUS "tesh wrapper: ${TESH_WRAPPER}")
  26
  27     mark_as_advanced(TESH_WRAPPER)
  28   else()
  29     set(enable_memcheck false)
  30     message(STATUS "Error: Command valgrind not found --> enable_memcheck autoset to false.")
  31   endif()
  32 ENDIF()
  33
  34 #some tests may take forever on non futexes systems, using busy_wait with n cores < n workers
  35 # default to posix for these tests if futexes are not supported
  36 IF(NOT HAVE_FUTEX_H)
  37   SET(CONTEXTS_SYNCHRO --cfg contexts/synchro:posix)
  38 ENDIF()
  39
  40 MACRO(ADD_TESH NAME)
  41   SET(ARGT ${ARGV})
  42   LIST(REMOVE_AT ARGT 0)
  43   IF(WIN32)
  44     STRING(REPLACE "§" "\;" ARGT "${ARGT}")
  45   ENDIF()
  46   if(TESH_WRAPPER)
  47     ADD_TEST(${NAME} ${TESH_COMMAND} --wrapper "${TESH_WRAPPER}" ${TESH_OPTION} ${ARGT})
  48   else()
  49     ADD_TEST(${NAME} ${TESH_COMMAND} ${TESH_OPTION} ${ARGT})
  50   endif()
  51 ENDMACRO()
  52
  53 MACRO(ADD_TESH_FACTORIES NAME FACTORIES)
  54   SET(ARGR ${ARGV})
  55   LIST(REMOVE_AT ARGR 0) # remove name
  56   FOREACH(I ${FACTORIES}) # remove all factories
  57     LIST(REMOVE_AT ARGR 0)
  58   ENDFOREACH()
  59   FOREACH(FACTORY ${FACTORIES})
  60     if ((${FACTORY} STREQUAL "thread" ) OR # Always available, thanks to C++11 threads
  61         (${FACTORY} STREQUAL "boost" AND HAVE_BOOST_CONTEXTS) OR
  62         (${FACTORY} STREQUAL "raw" AND HAVE_RAW_CONTEXTS) OR
  63         (${FACTORY} STREQUAL "ucontext" AND HAVE_UCONTEXT_CONTEXTS))
  64       ADD_TESH("${NAME}-${FACTORY}" "--cfg" "contexts/factory:${FACTORY}" ${ARGR})
  65     ENDIF()
  66   ENDFOREACH()
  67 ENDMACRO()
  68
  69 MACRO(SET_TESH_PROPERTIES NAME FACTORIES)
  70   SET(ARGR ${ARGV})
  71   LIST(REMOVE_AT ARGR 0) # remove name
  72   FOREACH(I ${FACTORIES}) # remove all factories
  73     LIST(REMOVE_AT ARGR 0)
  74   ENDFOREACH()
  75   FOREACH(FACTORY ${FACTORIES})
  76     if ((${FACTORY} STREQUAL "thread" ) OR # Always available, thanks to C++11 threads
  77         (${FACTORY} STREQUAL "boost" AND HAVE_BOOST_CONTEXTS) OR
  78         (${FACTORY} STREQUAL "raw" AND HAVE_RAW_CONTEXTS) OR
  79         (${FACTORY} STREQUAL "ucontext" AND HAVE_UCONTEXT_CONTEXTS))
  80       set_tests_properties("${NAME}-${FACTORY}" PROPERTIES ${ARGR})
  81     endif()
  82   ENDFOREACH()
  83 ENDMACRO()
  84
  85 IF(enable_java)
  86   IF(WIN32)
  87     SET(TESH_CLASSPATH "${CMAKE_BINARY_DIR}/examples/deprecated/java/\;${CMAKE_BINARY_DIR}/teshsuite/java/\;${SIMGRID_JAR}")
  88     STRING(REPLACE "\;" "§" TESH_CLASSPATH "${TESH_CLASSPATH}")
  89   ELSE()
  90     SET(TESH_CLASSPATH "${CMAKE_BINARY_DIR}/examples/deprecated/java/:${CMAKE_BINARY_DIR}/teshsuite/java/:${SIMGRID_JAR}")
  91   ENDIF()
  92 ENDIF()
  93
  94 # New tests should use the Catch Framework
  95 set(UNIT_TESTS  src/xbt/unit-tests_main.cpp
  96                 src/kernel/resource/profile/trace_mgr_test.cpp
  97                 src/xbt/config_test.cpp
  98                 src/xbt/dict_test.cpp
  99                 src/xbt/dynar_test.cpp
 100                 src/xbt/xbt_str_test.cpp)
 101 if (SIMGRID_HAVE_MC)
 102   set(UNIT_TESTS ${UNIT_TESTS} src/mc/sosp/mc_snapshot_test.cpp src/mc/sosp/PageStore_test.cpp)
 103 else()
 104   set(EXTRA_DIST ${EXTRA_DIST} src/mc/sosp/mc_snapshot_test.cpp src/mc/sosp/PageStore_test.cpp)
 105 endif()
 106
 107 add_executable       (unit-tests ${UNIT_TESTS})
 108 target_link_libraries(unit-tests simgrid)
 109 ADD_TEST(unit-tests ${CMAKE_BINARY_DIR}/unit-tests)
 110 set_property(TARGET unit-tests APPEND PROPERTY INCLUDE_DIRECTORIES "${INTERNAL_INCLUDES}")
 111 add_dependencies(tests unit-tests)
 112 set(EXTRA_DIST ${EXTRA_DIST} ${UNIT_TESTS})
 113
 114 unset(UNIT_TESTS)