tools/cmake/MakeJava.cmake

   1 include(UseJava)
   2
   3 # Rules to build libsimgrid-java
   4 #
   5 add_library(simgrid-java SHARED ${JMSG_C_SRC})
   6 set_target_properties(simgrid-java PROPERTIES VERSION ${libsimgrid-java_version})
   7 get_target_property(COMMON_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
   8 if (COMMON_INCLUDES)
   9   set_target_properties(simgrid-java PROPERTIES
  10     INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  11 else()
  12   set_target_properties(simgrid-java PROPERTIES
  13     INCLUDE_DIRECTORIES "${JNI_INCLUDE_DIRS}")
  14 endif()
  15
  16 get_target_property(CHECK_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  17 message("-- [Java] simgrid-java includes: ${CHECK_INCLUDES}")
  18
  19 target_link_libraries(simgrid-java simgrid)
  20
  21
  22 if(WIN32)
  23   exec_program("java -d32 -version"
  24                 OUTPUT_VARIABLE IS_32_BITS_JVM)
  25   STRING( FIND ${IS_32_BITS_JVM} "Error" POSITION )
  26   if(${POSITION} GREATER -1)
  27     message("POTENTIAL ERROR: Java JVM needs to be 32 bits to be able to run with Simgrid on Windows for now")
  28   endif()
  29
  30   set_target_properties(simgrid-java PROPERTIES
  31     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at"
  32     PREFIX "")
  33   find_path(PEXPORTS_PATH NAMES pexports.exe PATHS NO_DEFAULT_PATHS)
  34   message(STATUS "pexports: ${PEXPORTS_PATH}")
  35   if(PEXPORTS_PATH)
  36     add_custom_command(TARGET simgrid-java POST_BUILD
  37       COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/lib/simgrid-java.dll > ${CMAKE_BINARY_DIR}/lib/simgrid-java.def)
  38   endif(PEXPORTS_PATH)
  39 endif()
  40
  41 # Rules to build simgrid.jar
  42 #
  43
  44 ## Files to include in simgrid.jar
  45 ##
  46 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  47 set(SIMGRID_FULL_JAR "${CMAKE_BINARY_DIR}/simgrid_full.jar")
  48 set(MANIFEST_IN_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF.in")
  49 set(MANIFEST_FILE "${CMAKE_BINARY_DIR}/src/bindings/java/MANIFEST.MF")
  50
  51
  52 set(LIBSIMGRID_SO
  53   libsimgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  54 set(LIBSIMGRID_JAVA_SO
  55   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  56 set(LIBSURF_JAVA_SO
  57   ${CMAKE_SHARED_LIBRARY_PREFIX}surf-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  58
  59 ## Don't strip libraries if not in release mode
  60 ##
  61 if(release)
  62   set(STRIP_COMMAND "${CMAKE_STRIP}")
  63 else()
  64   set(STRIP_COMMAND "true")
  65 endif()
  66
  67 ## Here is how to build simgrid.jar
  68 ##
  69 add_jar(simgrid-java_pre_jar ${JMSG_JAVA_SRC} OUTPUT_NAME simgrid)
  70
  71 set(JAVA_BUNDLE "${CMAKE_HOME_DIRECTORY}/tools/cmake/Scripts/java_bundle.sh")
  72 set(JAVA_BUNDLE_SO_FILES
  73   ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
  74   ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO}
  75   ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}
  76   )
  77 set(JAVA_BUNDLE_TXT_FILES
  78   ${CMAKE_HOME_DIRECTORY}/COPYING
  79   ${CMAKE_HOME_DIRECTORY}/ChangeLog
  80   ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  81   ${CMAKE_HOME_DIRECTORY}/LICENSE-LGPL-2.1
  82   )
  83 add_custom_command(
  84   COMMENT "Finalize simgrid.jar..."
  85   OUTPUT ${SIMGRID_JAR}_finalized
  86   DEPENDS simgrid simgrid-java simgrid-java_pre_jar
  87           ${SIMGRID_JAR} ${MANIFEST_IN_FILE}
  88           ${JAVA_BUNDLE_SO_FILES} ${JAVA_BUNDLE_TXT_FILES}
  89   COMMAND ${JAVA_BUNDLE} "${SIMGRID_JAR}" "${Java_JAVA_EXECUTABLE}" "${STRIP_COMMAND}" -so ${JAVA_BUNDLE_SO_FILES} -txt ${JAVA_BUNDLE_TXT_FILES}
  90   COMMAND ${CMAKE_COMMAND} -E copy ${MANIFEST_IN_FILE} ${MANIFEST_FILE}
  91   COMMAND ${CMAKE_COMMAND} -E echo "Specification-Version: \\\"${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}\\\"" >> ${MANIFEST_FILE}
  92   COMMAND ${CMAKE_COMMAND} -E echo "Implementation-Version: \\\"${GIT_VERSION}\\\"" >> ${MANIFEST_FILE}
  93   COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR}
  94   COMMAND ${CMAKE_COMMAND} -E copy ${SIMGRID_JAR} ${SIMGRID_FULL_JAR}
  95   COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_FULL_JAR} "NATIVE"
  96   COMMAND ${CMAKE_COMMAND} -E remove ${SIMGRID_JAR}_finalized
  97   COMMAND ${CMAKE_COMMAND} -E touch ${SIMGRID_JAR}_finalized
  98   COMMAND ${Java_JAVADOC_EXECUTABLE} -quiet -d doc/javadoc ${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/*.java ${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/*/*.java
  99   COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_FULL_JAR} doc/javadoc
 100   )
 101 add_custom_target(simgrid-java_jar ALL DEPENDS ${SIMGRID_JAR}_finalized)
 102
 103 include_directories(${JNI_INCLUDE_DIRS} ${JAVA_INCLUDE_PATH} ${JAVA_INCLUDE_PATH2})
 104
 105 if(enable_maintainer_mode)
 106   set(CMAKE_SWIG_FLAGS "-package" "org.simgrid.surf")
 107   set(CMAKE_SWIG_OUTDIR "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf")
 108
 109   set_source_files_properties(${JSURF_SWIG_SRC} PROPERTIES CPLUSPLUS 1)
 110
 111   swig_add_module(surf-java java ${JSURF_SWIG_SRC} ${JSURF_JAVA_C_SRC})
 112
 113   if(NOT "${CMAKE_BINARY_DIR}" STREQUAL "${CMAKE_BINARY_DIR}")
 114     add_custom_command(TARGET surf-java POST_BUILD
 115       COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/src/bindings/java/org/simgrid/surf/surfJAVA_wrap.cxx" "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf/surfJAVA_wrap.cxx"
 116       COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/src/bindings/java/org/simgrid/surf/surfJAVA_wrap.h" "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf/surfJAVA_wrap.h"
 117     )
 118   endif()
 119
 120   swig_link_libraries(surf-java simgrid)
 121 else()
 122   add_library(surf-java SHARED ${JSURF_C_SRC})
 123   target_link_libraries(surf-java simgrid)
 124 endif()
 125
 126 set_target_properties(surf-java PROPERTIES SKIP_BUILD_RPATH ON)
 127 set_target_properties(simgrid-java PROPERTIES SKIP_BUILD_RPATH ON)
 128
 129 add_dependencies(simgrid-java surf-java)
 130 add_dependencies(simgrid-java_pre_jar surf-java)
 131
 132 if(WIN32)
 133   set_target_properties(surf-java PROPERTIES
 134     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at"
 135     PREFIX "")
 136   if(PEXPORTS_PATH)
 137     add_custom_command(TARGET surf-java POST_BUILD
 138       COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/lib/surf-java.dll > ${CMAKE_BINARY_DIR}/lib/surf-java.def)
 139   endif(PEXPORTS_PATH)
 140 endif()