tools/cmake/GCCFlags.cmake

   1 ##
   2 ## This file is in charge of setting our paranoid flags with regard to warnings and optimization.
   3 ##
   4 ##   It is only used for gcc and clang. MSVC builds don't load this file.
   5 ##
   6 ##   These flags do break some classical CMake tests, so you don't
   7 ##   want to do so before the very end of the configuration.
   8 ##
   9 ##   Other compiler flags (C/C++ standard version) are tested and set
  10 ##   by the beginning of the configuration, directly in ~/CMakeList.txt
  11
  12 set(warnCFLAGS "")
  13 set(optCFLAGS "")
  14 set(warnCXXFLAGS "")
  15
  16 if(enable_compile_warnings)
  17   set(warnCFLAGS "-fno-common -Wall -Wunused -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
  18   if(CMAKE_COMPILER_IS_GNUCC AND (NOT (CMAKE_C_COMPILER_VERSION VERSION_LESS "5.0")))
  19     set(warnCFLAGS "${warnCFLAGS} -Wformat-signedness")
  20   endif()
  21   if(CMAKE_C_COMPILER_ID MATCHES "Clang|GCC")
  22     set(warnCFLAGS "${warnCFLAGS} -Wno-format-nonliteral")
  23   endif()
  24   if(CMAKE_COMPILER_IS_GNUCC)
  25     set(warnCFLAGS "${warnCFLAGS} -Wclobbered -Wno-error=clobbered  -Wno-unused-local-typedefs -Wno-error=attributes")
  26   endif()
  27   if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
  28     # ignore remark  #1418: external function definition with no prior declaration
  29     # 3179: deprecated conversion of string literal to char* (should be const char*)
  30     # 191: type qualifier is meaningless on cast type
  31     # 597: entity-kind "entity" will not be called for implicit or explicit conversions
  32     set(warnCFLAGS "${warnCFLAGS} -wd1418 -wd191 -wd3179 -ww597")
  33   endif()
  34
  35   set(warnCXXFLAGS "${warnCFLAGS} -Wall -Wextra -Wunused -Wmissing-declarations -Wpointer-arith -Wchar-subscripts -Wcomment -Wformat -Wwrite-strings -Wno-unused-function -Wno-unused-parameter -Wno-strict-aliasing")
  36   if(CMAKE_COMPILER_IS_GNUCXX AND (NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "5.0")))
  37     set(warnCFLAGS "${warnCFLAGS} -Wformat-signedness")
  38   endif()
  39   if(CMAKE_CXX_COMPILER_ID MATCHES "Clang|GCC")
  40     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-format-nonliteral")
  41   endif()
  42   if(CMAKE_COMPILER_IS_GNUCXX)
  43     set(warnCXXFLAGS "${warnCXXFLAGS} -Wclobbered -Wno-error=clobbered  -Wno-unused-local-typedefs -Wno-error=attributes")
  44   endif()
  45   if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  46     # don't care about class that become struct, avoid issue of empty C structs
  47     # size (coming from libunwind.h)
  48     set(warnCXXFLAGS "${warnCXXFLAGS} -Wno-mismatched-tags -Wno-extern-c-compat")
  49   endif()
  50
  51   # the one specific to C but refused by C++
  52   set(warnCFLAGS "${warnCFLAGS} -Wmissing-prototypes")
  53
  54   if(CMAKE_Fortran_COMPILER_ID MATCHES "GCC|PGI")
  55     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -Wall")
  56   endif()
  57   if(CMAKE_Fortran_COMPILER_ID MATCHES "Intel")
  58     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -warn all")
  59   endif()
  60   set(CMAKE_JAVA_COMPILE_FLAGS "-Xlint")
  61 endif()
  62
  63 # NDEBUG gives a lot of "initialized but unused variables" errors. Don't die anyway.
  64 if(enable_compile_warnings AND enable_debug)
  65   set(warnCFLAGS "${warnCFLAGS} -Werror")
  66   set(warnCXXFLAGS "${warnCXXFLAGS} -Werror")
  67 endif()
  68
  69 # Activate the warnings on #if FOOBAR when FOOBAR has no value
  70 # It breaks on FreeBSD within Boost headers, so activate this only in Pure Hardcore debug mode.
  71 if(enable_maintainer_mode)
  72   set(warnCFLAGS "${warnCFLAGS} -Wundef")
  73   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wundef")
  74 endif()
  75
  76 # Se the optimisation flags
  77 # NOTE, we should CMAKE_BUILD_TYPE for this
  78 if(enable_compile_optimizations)
  79   set(optCFLAGS "-O3 -funroll-loops -fno-strict-aliasing ")
  80 else()
  81   set(optCFLAGS "-O0 ")
  82 endif()
  83 if(enable_compile_optimizations AND CMAKE_COMPILER_IS_GNUCC
  84     AND (NOT enable_model-checking))
  85   # This is redundant (already in -03):
  86   set(optCFLAGS "${optCFLAGS} -finline-functions ")
  87 endif()
  88 if (CMAKE_C_COMPILER_ID MATCHES "Intel")
  89   # honor parentheses when determining the order of expression evaluation.
  90   set(optCFLAGS "${optCFLAGS} -fprotect-parens ")
  91 endif()
  92
  93 # Do not leak the current directory into the binaries
  94 if(CMAKE_COMPILER_IS_GNUCC)
  95   execute_process(COMMAND realpath --relative-to=${CMAKE_BINARY_DIR} ${CMAKE_SOURCE_DIR}
  96     RESULT_VARIABLE RESULT OUTPUT_VARIABLE RELATIVE_SOURCE_DIR ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
  97   if(RESULT EQUAL 0)
  98     message(STATUS "Relative source directory is \"${RELATIVE_SOURCE_DIR}\".")
  99   else()
 100     message(WARNING "Failed to find relative source directory. Using \".\".")
 101     set(RELATIVE_SOURCE_DIR ".")
 102   endif()
 103   set(optCFLAGS "${optCFLAGS} -fdebug-prefix-map=${CMAKE_SOURCE_DIR}=${RELATIVE_SOURCE_DIR}")
 104 endif()
 105
 106 # Configure LTO
 107 # NOTE, cmake 3.0 has a INTERPROCEDURAL_OPTIMIZATION target
 108 #       property for this (http://www.cmake.org/cmake/help/v3.0/prop_tgt/INTERPROCEDURAL_OPTIMIZATION.html)
 109 if(enable_lto) # User wants LTO. Try if we can do that
 110   set(enable_lto OFF)
 111   if(enable_compile_optimizations
 112       AND CMAKE_COMPILER_IS_GNUCC
 113       AND (NOT enable_model-checking))
 114     # On windows, we need 4.8 or higher to enable lto because of http://gcc.gnu.org/bugzilla/show_bug.cgi?id=50293
 115     #   We are experiencing assertion failures even with 4.8 on MinGW.
 116     #   Push the support forward: will see if 4.9 works when we test it.
 117     #
 118     # On Linux, we got the following with GCC 4.8.4 on Centos and Ubuntu
 119     #    lto1: internal compiler error: in output_die, at dwarf2out.c:8478
 120     #    Please submit a full bug report, with preprocessed source if appropriate.
 121     # So instead, we push the support forward
 122
 123     if ( (CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8.5")
 124          AND (LINKER_VERSION VERSION_GREATER "2.22"))
 125       set(enable_lto ON)
 126     endif()
 127   endif()
 128   if(enable_lto)
 129     message(STATUS "LTO seems usable.")
 130   else()
 131     if(NOT enable_compile_optimizations)
 132       message(STATUS "LTO disabled: Compile-time optimizations turned off.")
 133     else()
 134       if(enable_model-checking)
 135         message(STATUS "LTO disabled when compiling with model-checking.")
 136       else()
 137         message(STATUS "LTO does not seem usable -- try updating your build chain.")
 138       endif()
 139     endif()
 140   endif()
 141 else()
 142   message(STATUS "LTO disabled on the command line.")
 143 endif()
 144 if(enable_lto) # User wants LTO, and it seems usable. Go for it
 145   set(optCFLAGS "${optCFLAGS} -flto ")
 146   # See https://gcc.gnu.org/wiki/LinkTimeOptimizationFAQ#ar.2C_nm_and_ranlib:
 147   # "Since version 4.9 gcc produces slim object files that only contain
 148   # the intermediate representation. In order to handle archives of
 149   # these objects you have to use the gcc wrappers:
 150   # gcc-ar, gcc-nm and gcc-ranlib."
 151   if(${CMAKE_C_COMPILER_ID} STREQUAL "GNU"
 152       AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "4.8")
 153     set (CMAKE_AR gcc-ar)
 154     set (CMAKE_RANLIB gcc-ranlib)
 155   endif()
 156 endif()
 157
 158 if(enable_model-checking AND enable_compile_optimizations)
 159   # Forget it, do not optimize the code (because it confuses the MC):
 160   set(optCFLAGS "-O0 ")
 161   # But you can still optimize this:
 162   foreach(s
 163       src/kernel/lmm/fair_bottleneck.cpp src/kernel/lmm/lagrange.cpp src/kernel/lmm/maxmin.cpp
 164       src/xbt/mmalloc/mm.c
 165       src/xbt/log.c src/xbt/xbt_log_appender_file.c
 166       src/xbt/xbt_log_layout_format.c src/xbt/xbt_log_layout_simple.c
 167       src/xbt/dict.cpp src/xbt/dict_elm.c src/xbt/dict_cursor.c
 168       src/xbt/dynar.cpp
 169       src/xbt/xbt_str.cpp src/xbt/snprintf.c
 170       src/xbt/xbt_os_time.c src/xbt/xbt_os_thread.c
 171       src/xbt/backtrace_linux.cpp
 172       ${MC_SRC_BASE} ${MC_SRC})
 173       set (mcCFLAGS "-O3  -funroll-loops -fno-strict-aliasing")
 174        if(CMAKE_COMPILER_IS_GNUCC)
 175          set (mcCFLAGS "${mcCFLAGS} -finline-functions")
 176       endif()
 177       set_source_files_properties(${s} PROPERTIES COMPILE_FLAGS ${mcCFLAGS})
 178   endforeach()
 179 endif()
 180
 181 if(NOT enable_debug)
 182   set(CMAKE_C_FLAGS "-DNDEBUG ${CMAKE_C_FLAGS}")
 183   set(CMAKE_CXX_FLAGS "-DNDEBUG ${CMAKE_CXX_FLAGS}")
 184 endif()
 185
 186 set(CMAKE_C_FLAGS   "${warnCFLAGS} ${CMAKE_C_FLAGS}   ${optCFLAGS}")
 187 set(CMAKE_CXX_FLAGS "${warnCXXFLAGS} ${CMAKE_CXX_FLAGS} ${optCFLAGS}")
 188
 189 # Try to make Mac a bit more complient to open source standards
 190 if(CMAKE_SYSTEM_NAME MATCHES "Darwin")
 191   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_XOPEN_SOURCE=700 -D_DARWIN_C_SOURCE")
 192 endif()
 193
 194 # Avoid a failure seen with gcc 7.2.0 and ns3 3.27
 195 if(enable_ns3)
 196   set_source_files_properties(src/surf/network_ns3.cpp PROPERTIES COMPILE_FLAGS " -Wno-unused-local-typedef")
 197 endif()
 198
 199 set(TESH_OPTION "")
 200 if(enable_coverage)
 201   find_program(GCOV_PATH gcov)
 202   if(GCOV_PATH)
 203     set(COVERAGE_COMMAND "${GCOV_PATH}" CACHE TYPE FILEPATH FORCE)
 204     set(COVERAGE_EXTRA_FLAGS "-l -p")
 205     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DCOVERAGE")
 206     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fprofile-arcs -ftest-coverage")
 207     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fprofile-arcs -ftest-coverage")
 208     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -fprofile-arcs -ftest-coverage")
 209     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fprofile-arcs -ftest-coverage")
 210     add_definitions(-fprofile-arcs -ftest-coverage)
 211   endif()
 212 endif()
 213
 214 if(enable_address_sanitizer)
 215     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 216     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer")
 217     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=address")
 218     set(TESH_OPTION --enable-sanitizers)
 219     try_compile(HAVE_SANITIZE_ADDRESS ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp)
 220     try_compile(HAVE_SANITIZE_ADDRESS_FIBER_SUPPORT ${CMAKE_BINARY_DIR} ${CMAKE_HOME_DIRECTORY}/tools/cmake/test_prog/prog_asan.cpp
 221       COMPILE_DEFINITIONS -DCHECK_FIBER_SUPPORT)
 222 else()
 223     set(HAVE_SANITIZE_ADDRESS FALSE CACHE INTERNAL "")
 224     set(HAVE_SANITIZE_ADDRESS_FIBER_SUPPORT FALSE CACHE INTERNAL "")
 225 endif()
 226
 227 if(enable_thread_sanitizer)
 228     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 229     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=thread -fno-omit-frame-pointer -no-pie")
 230     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=thread -no-pie")
 231 endif()
 232
 233 if(enable_undefined_sanitizer)
 234     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 235     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=undefined -fno-omit-frame-pointer")
 236     set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -fsanitize=undefined")
 237 endif()
 238
 239 if(NOT $ENV{CFLAGS} STREQUAL "")
 240   message(STATUS "Add CFLAGS: \"$ENV{CFLAGS}\" to CMAKE_C_FLAGS")
 241   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} $ENV{CFLAGS}")
 242 endif()
 243
 244 if(NOT $ENV{CXXFLAGS} STREQUAL "")
 245   message(STATUS "Add CXXFLAGS: \"$ENV{CXXFLAGS}\" to CMAKE_CXX_FLAGS")
 246   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} $ENV{CXXFLAGS}")
 247 endif()
 248
 249 if(NOT $ENV{LDFLAGS} STREQUAL "")
 250   message(STATUS "Add LDFLAGS: \"$ENV{LDFLAGS}\" to CMAKE_C_LINK_FLAGS")
 251   set(CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} $ENV{LDFLAGS}")
 252 endif()
 253
 254 if(MINGW)
 255   # http://stackoverflow.com/questions/10452262/create-64-bit-jni-under-windows
 256   # We don't want to ship libgcc_s_seh-1.dll nor libstdc++-6.dll
 257   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -static-libgcc")
 258   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -static-libgcc -static-libstdc++")
 259   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS   "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -static-libgcc")
 260   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -static-libgcc -static-libstdc++")
 261
 262   # JNI searches for stdcalls
 263   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -Wl,--add-stdcall-alias")
 264   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wl,--add-stdcall-alias")
 265   set(CMAKE_SHARED_LIBRARY_LINK_C_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_C_FLAGS} -Wl,--add-stdcall-alias")
 266   set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS} -Wl,--add-stdcall-alias")
 267
 268   # Specify the data model that we are using (yeah it may help Java)
 269   if(CMAKE_SIZEOF_VOID_P EQUAL 4) # 32 bits
 270     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m32")
 271     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m32")
 272   else()
 273     set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS}   -m64")
 274     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m64")
 275   endif()
 276 endif()