buildtools/Cmake/MakeJava.cmake

   1 # Rules to build libSG_java
   2 #
   3 add_library(SG_java SHARED ${JMSG_C_SRC})
   4 set_target_properties(SG_java PROPERTIES VERSION ${libSG_java_version})
   5 get_target_property(COMMON_INCLUDES SG_java INCLUDE_DIRECTORIES)
   6 set_target_properties(SG_java PROPERTIES
   7   INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
   8 add_dependencies(SG_java simgrid)
   9
  10 if(WIN32)
  11   get_target_property(SIMGRID_LIB_NAME_NAME SG_java LIBRARY_OUTPUT_NAME)
  12   set_target_properties(SG_java PROPERTIES
  13     LINK_FLAGS "-Wl,--subsystem,windows,--kill-at ${SIMGRID_LIB_NAME}"
  14     PREFIX "")
  15   find_path(PEXPORTS_PATH NAMES pexports.exe PATHS NO_DEFAULT_PATHS)
  16   message(STATUS "pexports: ${PEXPORTS_PATH}")
  17   if(PEXPORTS_PATH)
  18     add_custom_command(TARGET SG_java POST_BUILD
  19       COMMAND ${PEXPORTS_PATH}/pexports.exe ${CMAKE_BINARY_DIR}/SG_java.dll > ${CMAKE_BINARY_DIR}/SG_java.def)
  20   endif(PEXPORTS_PATH)
  21 else()
  22   target_link_libraries(SG_java simgrid)
  23 endif()
  24
  25 # Rules to build simgrid.jar
  26 #
  27
  28 ## Files to include in simgrid.jar
  29 ##
  30 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  31 set(MANIFEST_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF")
  32 set(LIBSIMGRID_SO
  33   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  34 set(LIBSG_JAVA_SO
  35   ${CMAKE_SHARED_LIBRARY_PREFIX}SG_java${CMAKE_SHARED_LIBRARY_SUFFIX})
  36
  37 ## Name of the "NATIVE" folder in simgrid.jar
  38 ##
  39 if(CMAKE_SYSTEM_PROCESSOR MATCHES ".86")
  40   if(${ARCH_32_BITS})
  41     set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/x86/")
  42   else()
  43     set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/amd64/")
  44   endif()
  45 else()
  46   message(WARNING "Unknown system type. Processor: ${CMAKE_SYSTEM_PROCESSOR}; System: ${CMAKE_SYSTEM_NAME}")
  47   set(JSG_BUNDLE "NATIVE/${CMAKE_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR/")
  48 endif()
  49 message("Native libraries bundled into: ${JSG_BUNDLE}")
  50
  51 ## Don't strip libraries if not in release mode
  52 ##
  53 if(release)
  54   set(STRIP_COMMAND "${CMAKE_STRIP}")
  55 else()
  56   set(STRIP_COMMAND "true")
  57 endif()
  58
  59 ## Here is how to build simgrid.jar
  60 ##
  61 set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  62 add_jar(SG_java_pre_jar ${JMSG_JAVA_SRC})
  63
  64 add_custom_command(
  65   COMMENT "Finalize simgrid.jar..."
  66   OUTPUT ${SIMGRID_JAR}_finalized
  67   DEPENDS simgrid SG_java SG_java_pre_jar
  68           ${SIMGRID_JAR} ${MANIFEST_FILE}
  69           ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
  70           ${CMAKE_BINARY_DIR}/lib/${LIBSG_JAVA_SO}
  71           ${CMAKE_HOME_DIRECTORY}/COPYING
  72           ${CMAKE_HOME_DIRECTORY}/ChangeLog
  73           ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  74   COMMAND ${CMAKE_COMMAND} -E remove_directory "NATIVE"
  75   COMMAND ${CMAKE_COMMAND} -E make_directory "${JSG_BUNDLE}"
  76   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}" "${JSG_BUNDLE}"
  77   COMMAND ${STRIP_COMMAND} -S "${JSG_BUNDLE}/${LIBSIMGRID_SO}"
  78   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_BINARY_DIR}/lib/${LIBSG_JAVA_SO}" "${JSG_BUNDLE}"
  79   COMMAND ${STRIP_COMMAND} -S "${JSG_BUNDLE}/${LIBSG_JAVA_SO}"
  80   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/COPYING" "${JSG_BUNDLE}"
  81   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/ChangeLog" "${JSG_BUNDLE}"
  82   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java" "${JSG_BUNDLE}"
  83   COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} "NATIVE"
  84   COMMAND ${CMAKE_COMMAND} -E remove ${SIMGRID_JAR}_finalized
  85   COMMAND ${CMAKE_COMMAND} -E touch ${SIMGRID_JAR}_finalized
  86   )
  87 add_custom_target(SG_java_jar ALL DEPENDS ${SIMGRID_JAR}_finalized)