tools/cmake/Java.cmake

   1 ##
   2 ## The Cmake definitions for the use of Java (and Scala)
   3 ##   This file is loaded only if the Java option is activated
   4 ##
   5
   6 cmake_minimum_required(VERSION 2.8.6)
   7
   8 find_package(Java 1.7 REQUIRED)
   9 include(UseJava)
  10
  11 # Rules to build libsimgrid-java
  12 #
  13 add_library(simgrid-java SHARED ${JMSG_C_SRC})
  14 set_target_properties(simgrid-java PROPERTIES VERSION ${libsimgrid-java_version})
  15 if (CMAKE_VERSION VERSION_LESS "2.8.8")
  16   include_directories(${JNI_INCLUDE_DIRS})
  17
  18   message("[Java] Try to workaround missing feature in older CMake. You should better update CMake to version 2.8.8 or above.")
  19   get_directory_property(CHECK_INCLUDES INCLUDE_DIRECTORIES)
  20 else()
  21   get_target_property(COMMON_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  22   if (COMMON_INCLUDES)
  23     set_target_properties(simgrid-java PROPERTIES
  24       INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  25   else()
  26     set_target_properties(simgrid-java PROPERTIES
  27       INCLUDE_DIRECTORIES "${JNI_INCLUDE_DIRS}")
  28   endif()
  29
  30   get_target_property(CHECK_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  31 endif()
  32 message("-- [Java] simgrid-java includes: ${CHECK_INCLUDES}")
  33
  34 target_link_libraries(simgrid-java simgrid)
  35
  36
  37 if(WIN32)
  38   exec_program("java -d32 -version"
  39                 OUTPUT_VARIABLE IS_32_BITS_JVM)
  40   STRING( FIND ${IS_32_BITS_JVM} "Error" POSITION )
  41   if(NOT ${POSITION} GREATER -1)
  42     message(fatal_error "SimGrid can only use Java 64 bits")
  43   endif()
  44
  45 # Already passed to all targets in GCCFlags.cmake
  46 #  set_target_properties(simgrid-java PROPERTIES
  47 #    LINK_FLAGS "-Wl,--subsystem,windows,--kill-at")
  48 #  set_target_properties(surf-java PROPERTIES
  49 #    LINK_FLAGS "-Wl,--subsystem,windows,--kill-at")
  50 endif()
  51
  52 # Rules to build simgrid.jar
  53 #
  54
  55 ## Files to include in simgrid.jar
  56 ##
  57 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  58 set(MANIFEST_IN_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.MF.in")
  59 set(MANIFEST_FILE "${CMAKE_BINARY_DIR}/src/bindings/java/MANIFEST.MF")
  60
  61 set(LIBSIMGRID_SO
  62   libsimgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  63 set(LIBSIMGRID_JAVA_SO
  64   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  65 set(LIBSURF_JAVA_SO
  66   ${CMAKE_SHARED_LIBRARY_PREFIX}surf-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  67
  68 ## Here is how to build simgrid.jar
  69 ##
  70 if(CMAKE_VERSION VERSION_LESS "2.8.12")
  71   set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  72   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC})
  73 else()
  74   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC} OUTPUT_NAME simgrid)
  75 endif()
  76
  77 add_custom_command(
  78   TARGET simgrid-java_jar POST_BUILD
  79   COMMENT "Add the documentation into simgrid.jar..."
  80   DEPENDS ${MANIFEST_IN_FILE}
  81           ${CMAKE_HOME_DIRECTORY}/COPYING
  82           ${CMAKE_HOME_DIRECTORY}/ChangeLog
  83           ${CMAKE_HOME_DIRECTORY}/NEWS
  84           ${CMAKE_HOME_DIRECTORY}/ChangeLog.SimGrid-java
  85           ${CMAKE_HOME_DIRECTORY}/LICENSE-LGPL-2.1
  86
  87   COMMAND ${CMAKE_COMMAND} -E copy ${MANIFEST_IN_FILE} ${MANIFEST_FILE}
  88   COMMAND ${CMAKE_COMMAND} -E echo "Specification-Version: \\\"${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}\\\"" >> ${MANIFEST_FILE}
  89   COMMAND ${CMAKE_COMMAND} -E echo "Implementation-Version: \\\"${GIT_VERSION}\\\"" >> ${MANIFEST_FILE}
  90
  91   COMMAND ${Java_JAVADOC_EXECUTABLE} -quiet -d doc/javadoc -sourcepath ${CMAKE_HOME_DIRECTORY}/src/bindings/java/ org.simgrid.msg org.simgrid.surf org.simgrid.trace
  92
  93   COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} doc/javadoc -C ${CMAKE_HOME_DIRECTORY} COPYING ChangeLog ChangeLog.SimGrid-java LICENSE-LGPL-2.1 NEWS
  94   )
  95
  96 ###
  97 ### Pack the java libraries into the jarfile if asked to do so
  98 ###
  99
 100 if(enable_lib_in_jar)
 101   find_program(STRIP_COMMAND strip)
 102   if(NOT STRIP_COMMAND)
 103     set(STRIP_COMMAND "cmake -E echo (strip not found)")
 104   endif()
 105   if(WIN32)
 106     set(STRIP_COMMAND "cmake -E echo (dont strip on windows)")
 107   endif()
 108
 109   set(JAVA_NATIVE_PATH NATIVE/${CMAKE_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR})
 110   if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "^i[3-6]86$")
 111     set(JAVA_NATIVE_PATH NATIVE/${CMAKE_SYSTEM_NAME}/x86)
 112   endif()
 113   if(  (${CMAKE_SYSTEM_PROCESSOR} MATCHES "x86_64") OR
 114        (${CMAKE_SYSTEM_PROCESSOR} MATCHES "AMD64")     )
 115     set(JAVA_NATIVE_PATH NATIVE/${CMAKE_SYSTEM_NAME}/amd64)
 116   endif()
 117
 118   add_custom_command(
 119     TARGET simgrid-java_jar POST_BUILD
 120     COMMENT "Add the native libs into simgrid.jar..."
 121     DEPENDS simgrid-java
 122             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 123             ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO}
 124             ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}
 125
 126     COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 127     COMMAND ${CMAKE_COMMAND} -E make_directory                                     ${JAVA_NATIVE_PATH}
 128     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}      ${JAVA_NATIVE_PATH}
 129     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO} ${JAVA_NATIVE_PATH}
 130     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_BINARY_DIR}/lib/${LIBSURF_JAVA_SO}    ${JAVA_NATIVE_PATH}
 131
 132     # strip seems to fail on Mac on binaries that are already stripped.
 133     # It then spits: "symbols referenced by indirect symbol table entries that can't be stripped"
 134     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_SO}      || true
 135     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_JAVA_SO} || true
 136     COMMAND ${STRIP_COMMAND} ${JAVA_NATIVE_PATH}/${LIBSURF_JAVA_SO}    || true
 137
 138     COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 139     COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 140
 141     COMMAND ${CMAKE_COMMAND} -E echo "-- Cmake put the native code in ${JAVA_NATIVE_PATH}"
 142     COMMAND "${Java_JAVA_EXECUTABLE}" -classpath "${SIMGRID_JAR}" org.simgrid.NativeLib
 143     )
 144   #if(MINGW)
 145   #  find_library(WINPTHREAD_DLL
 146   #    NAME winpthread winpthread-1
 147   #    PATHS C:\\MinGW C:\\MinGW64 C:\\MinGW\\bin C:\\MinGW64\\bin
 148   #  )
 149   #  add_custom_command(
 150   #    TARGET simgrid-java_jar POST_BUILD
 151   #    COMMENT "Add the MinGW libs into simgrid.jar..."
 152   #    DEPENDS ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}
 153   #
 154   #    COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 155   #    COMMAND ${CMAKE_COMMAND} -E make_directory          ${JAVA_NATIVE_PATH}
 156   #    COMMAND ${CMAKE_COMMAND} -E copy ${WINPTHREAD_DLL}  ${JAVA_NATIVE_PATH}
 157   #
 158   #    COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  NATIVE
 159   #    COMMAND ${CMAKE_COMMAND} -E remove_directory NATIVE
 160   #  )
 161   #endif(MINGW)
 162 endif(enable_lib_in_jar)
 163
 164 include_directories(${JNI_INCLUDE_DIRS} ${JAVA_INCLUDE_PATH} ${JAVA_INCLUDE_PATH2})
 165
 166 if(enable_maintainer_mode)
 167   set(CMAKE_SWIG_FLAGS "-package" "org.simgrid.surf")
 168   set(CMAKE_SWIG_OUTDIR "${CMAKE_HOME_DIRECTORY}/src/bindings/java/org/simgrid/surf")
 169
 170   set_source_files_properties(${JSURF_SWIG_SRC} PROPERTIES CPLUSPLUS 1)
 171
 172   swig_add_module(surf-java java ${JSURF_SWIG_SRC} ${JSURF_JAVA_C_SRC})
 173   swig_link_libraries(surf-java simgrid)
 174 else()
 175   add_library(surf-java SHARED ${JSURF_C_SRC})
 176   target_link_libraries(surf-java simgrid)
 177 endif()
 178
 179 set_target_properties(surf-java PROPERTIES SKIP_BUILD_RPATH ON)
 180 set_target_properties(simgrid-java PROPERTIES SKIP_BUILD_RPATH ON)
 181
 182 add_dependencies(simgrid-java surf-java)
 183 add_dependencies(simgrid-java_jar surf-java)
 184