tools/cmake/Modules/FindNS3.cmake

   1 # Try to find the ns-3 library.
   2 #
   3 # The user can hint a path using the NS3_HINT option.
   4 #
   5 # Once done, the following will be defined:
   6 #
   7 #  NS3_INCLUDE_DIRS - the ns-3 include directories
   8 #  NS3_LIBRARY_PATH - path to the libs
   9 #  NS3_LIBRARIES - link these to use ns-3 (full path to libs)
  10 #
  11 # This could be improved in many ways (patches welcome):
  12 #  - No way to specify a minimal version (v3.26 is hardcoded).
  13 #  - No proper find_package() integration
  14
  15 ## ADDING A ns-3 VERSION.
  16 #   - Add "ns3.${version}-core ns3.${version}-core-debug ns3.${version}-core-optimized" to the NAME line of the find_library below
  17 #   - Add "include/ns3{version}" to the PATH_SUFFIXES line of the find_path below
  18
  19 set(SIMGRID_HAVE_NS3 0)
  20 set(NS3_HINT ${ns3_path} CACHE PATH "Path to search for NS3 lib and include")
  21
  22 find_library(NS3_LIBRARIES
  23   NAME ns3-core
  24        ns3.26-core ns3.26-core-optimized ns3.26-core-debug
  25        ns3.27-core ns3.27-core-optimized ns3.27-core-debug
  26        ns3.28-core ns3.28-core-optimized ns3.28-core-debug
  27        ns3.29-core ns3.29-core-optimized ns3.29-core-debug
  28        ns3.30-core ns3.30-core-optimized ns3.30-core-debug
  29        ns3.31-core ns3.31-core-optimized ns3.31-core-debug
  30        ns3.32-core ns3.32-core-optimized ns3.32-core-debug
  31        ns3.33-core ns3.33-core-optimized ns3.33-core-debug
  32        ns3.34-core ns3.34-core-optimized ns3.34-core-debug
  33   PATH_SUFFIXES lib64 lib ns3/lib
  34   PATHS
  35   ${NS3_HINT}
  36   )
  37
  38 find_path(NS3_INCLUDE_DIR
  39   NAME ns3/core-module.h
  40   PATH_SUFFIXES include ns3/include include/ns3.26 include/ns3.27 include/ns3.28 include/ns3.29 include/ns3.30 include/ns3.31 include/ns3.32 include/ns3.33 include/ns3.34
  41   PATHS
  42   ${NS3_HINT}
  43   )
  44
  45 if(NS3_INCLUDE_DIR)
  46   message(STATUS "Looking for ns3/core-module.h - found")
  47 else()
  48   message(STATUS "Looking for ns3/core-module.h - not found")
  49 endif()
  50 mark_as_advanced(NS3_INCLUDE_DIR)
  51
  52 message(STATUS "Looking for lib ns3-core")
  53 if(NS3_LIBRARIES)
  54   message(STATUS "Looking for lib ns3-core - found")
  55 else()
  56   message(STATUS "Looking for lib ns3-core - not found")
  57 endif()
  58 mark_as_advanced(NS3_LIBRARIES)
  59
  60 if(NS3_INCLUDE_DIR)
  61   if(NS3_LIBRARIES)
  62     set(SIMGRID_HAVE_NS3 1)
  63     if(NS3_LIBRARIES MATCHES "-optimized")
  64       set (NS3_SUFFIX "-optimized")
  65     elseif(NS3_LIBRARIES MATCHES "-debug")
  66       set (NS3_SUFFIX "-debug")
  67     else()
  68       set (NS3_SUFFIX "")
  69     endif()
  70
  71     string(REGEX REPLACE ".*ns([.0-9]+)-core.*" "\\1" NS3_VERSION "${NS3_LIBRARIES}")
  72     get_filename_component(NS3_LIBRARY_PATH "${NS3_LIBRARIES}" PATH)
  73
  74     # Compute NS3_PATH
  75     string(REGEX REPLACE "(.*)/lib" "\\1" NS3_PATH "${NS3_LIBRARY_PATH}")
  76
  77     message(STATUS "NS-3 found (v${NS3_VERSION}; incl:${NS3_INCLUDE_DIR}; lib: ${NS3_LIBRARY_PATH}).")
  78
  79     if (NOT NS3_LIBRARY_PATH STREQUAL "/usr/lib")
  80       string(REGEX MATCH "${NS3_LIBRARY_PATH}" MatchResult "$ENV{LD_LIBRARY_PATH}")
  81       if(NOT MatchResult)
  82         message(STATUS "Warning: NS3 not installed in system path, and not listed in LD_LIBRARY_PATH."
  83                        "         You want to: export LD_LIBRARY_PATH=${NS3_LIBRARY_PATH}\${LD_LIBRARY_PATH:+:\$LD_LIBRARY_PATH}")
  84       endif()
  85     endif()
  86   endif()
  87 endif()
  88 mark_as_advanced(NS3_LIBRARY_PATH)
  89
  90 if(SIMGRID_HAVE_NS3)
  91   link_directories(${NS3_LIBRARY_PATH})
  92   include_directories(${NS3_INCLUDE_DIR})
  93 else()
  94   message(STATUS "Warning: To use ns-3 in SimGrid, please install ns-3 at least version 3.26 (http://www.nsnam.org/releases/)")
  95 endif()