Add the right macro to the CVS, sorry Arnaud

git-svn-id: svn+ssh://scm.gforge.inria.fr/svn/simgrid/simgrid/trunk@420 48e7efb5-ca39-0410-a469-dd3cf9ba447f

diff --git a/acmacro/gnome-common.m4 b/acmacro/gnome-common.m4
deleted file mode 100644 (file)
index 20302d1..0000000
--- a/acmacro/gnome-common.m4
+++ /dev/null
@@ -1,30 +0,0 @@
-# gnome-common.m4
-# 
-
-dnl GNOME_COMMON_INIT
-
-AC_DEFUN([GNOME_COMMON_INIT],
-[
-       AC_CACHE_VAL(ac_cv_gnome_aclocal_dir,
-       [ac_cv_gnome_aclocal_dir="$GNOME_COMMON_MACROS_DIR"])
-       AC_CACHE_VAL(ac_cv_gnome_aclocal_flags,
-       [ac_cv_gnome_aclocal_flags="$ACLOCAL_FLAGS"])
-       GNOME_ACLOCAL_DIR="$ac_cv_gnome_aclocal_dir"
-       GNOME_ACLOCAL_FLAGS="$ac_cv_gnome_aclocal_flags"
-       AC_SUBST(GNOME_ACLOCAL_DIR)
-       AC_SUBST(GNOME_ACLOCAL_FLAGS)
-
-       ACLOCAL="$ACLOCAL $GNOME_ACLOCAL_FLAGS"
-
-       AM_CONDITIONAL(INSIDE_GNOME_DOCU, false)
-])
-
-AC_DEFUN([GNOME_DEBUG_CHECK],
-[
-       AC_ARG_ENABLE(debug, [  --enable-debug turn on debugging [default=no]], enable_debug="$enableval", enable_debug=no)
-
-       if test x$enable_debug = xyes ; then
-           AC_DEFINE(GNOME_ENABLE_DEBUG,1,
-               [Enable additional debugging at the expense of performance and size])
-       fi
-])

diff --git a/acmacro/gtk-doc.m4 b/acmacro/gtk-doc.m4
new file mode 100644 (file)
index 0000000..af73800
--- /dev/null
+++ b/acmacro/gtk-doc.m4
@@ -0,0 +1,53 @@
+dnl -*- mode: autoconf -*-
+
+# serial 1
+
+dnl Usage:
+dnl   GTK_DOC_CHECK([minimum-gtk-doc-version])
+AC_DEFUN([GTK_DOC_CHECK],
+[
+  AC_BEFORE([AC_PROG_LIBTOOL],[$0])dnl setup libtool first
+  AC_BEFORE([AM_PROG_LIBTOOL],[$0])dnl setup libtool first
+  dnl for overriding the documentation installation directory
+  AC_ARG_WITH(html-dir,
+    AC_HELP_STRING([--with-html-dir=PATH], [path to installed docs]),,
+    [with_html_dir='${datadir}/gtk-doc/html'])
+  HTML_DIR="$with_html_dir"
+  AC_SUBST(HTML_DIR)
+
+  dnl enable/disable documentation building
+  AC_ARG_ENABLE(gtk-doc,
+    AC_HELP_STRING([--enable-gtk-doc],
+                   [use gtk-doc to build documentation [default=no]]),,
+    enable_gtk_doc=no)
+
+  have_gtk_doc=no
+  if test x$enable_gtk_doc = xyes; then
+    if test -z "$PKG_CONFIG"; then
+      AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
+    fi
+    if test "$PKG_CONFIG" != "no" && $PKG_CONFIG --exists gtk-doc; then
+      have_gtk_doc=yes
+    fi
+
+  dnl do we want to do a version check?
+ifelse([$1],[],,
+    [gtk_doc_min_version=$1
+    if test "$have_gtk_doc" = yes; then
+      AC_MSG_CHECKING([gtk-doc version >= $gtk_doc_min_version])
+      if $PKG_CONFIG --atleast-version $gtk_doc_min_version gtk-doc; then
+        AC_MSG_RESULT(yes)
+      else
+        AC_MSG_RESULT(no)
+        have_gtk_doc=no
+      fi
+    fi
+])
+    if test "$have_gtk_doc" != yes; then
+      enable_gtk_doc=no
+    fi
+  fi
+
+  AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
+  AM_CONDITIONAL(GTK_DOC_USE_LIBTOOL, test -n "$LIBTOOL")
+])