tools/cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 install(DIRECTORY "${CMAKE_BINARY_DIR}/doc/html/" DESTINATION ${CMAKE_INSTALL_DOCDIR}/html/ OPTIONAL)
   7
   8 # binaries
   9 if(enable_smpi)
  10   install(PROGRAMS
  11     ${CMAKE_BINARY_DIR}/bin/smpicc
  12     ${CMAKE_BINARY_DIR}/bin/smpicxx
  13     ${CMAKE_BINARY_DIR}/bin/smpirun
  14     DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  15   if(SMPI_FORTRAN)
  16     install(PROGRAMS
  17       ${CMAKE_BINARY_DIR}/bin/smpif90
  18       ${CMAKE_BINARY_DIR}/bin/smpiff
  19       DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  20     install(PROGRAMS
  21       ${CMAKE_BINARY_DIR}/include/smpi/mpi.mod
  22       DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/smpi/)
  23   endif()
  24 endif()
  25
  26 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh DESTINATION ${CMAKE_INSTALL_BINDIR}/)
  27
  28 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  29   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  30   RENAME simgrid_update_xml)
  31
  32 add_custom_target(simgrid_update_xml ALL
  33   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  34   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml)
  35
  36 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py
  37   DESTINATION ${CMAKE_INSTALL_BINDIR}/
  38   RENAME simgrid_convert_TI_traces)
  39
  40 add_custom_target(simgrid_convert_TI_traces ALL
  41     COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces"
  42     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_convert_TI_traces.py ${CMAKE_BINARY_DIR}/bin/simgrid_convert_TI_traces)
  43
  44 # libraries
  45 install(TARGETS simgrid DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  46 if("${CMAKE_SYSTEM}" MATCHES "Linux")
  47   install(TARGETS sthread DESTINATION ${CMAKE_INSTALL_LIBDIR}/)
  48 endif()
  49
  50 # pkg-config files
  51 configure_file("${CMAKE_HOME_DIRECTORY}/tools/pkg-config/simgrid.pc.in"
  52   "${PROJECT_BINARY_DIR}/simgrid.pc" @ONLY)
  53 install(FILES "${PROJECT_BINARY_DIR}/simgrid.pc" DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
  54
  55 # include files
  56 foreach(file ${headers_to_install} ${generated_headers_to_install})
  57   get_filename_component(location ${file} PATH)
  58   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  59   string(REGEX REPLACE "^include/" "" location "${location}")
  60   string(REGEX REPLACE "^include$" "" location "${location}")
  61   # message("installing '${file}' into '${CMAKE_INSTALL_INCLUDEDIR}/${location}'")
  62   install(FILES ${file} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${location})
  63 endforeach()
  64
  65 # example files
  66 foreach(file ${examples_to_install})
  67   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  68   get_filename_component(location ${file} PATH)
  69   # message("DOC installing 'examples/${file}' into '${CMAKE_INSTALL_DOCDIR}/examples/${location}'")
  70   install(FILES "examples/${file}"
  71     DESTINATION ${CMAKE_INSTALL_DOCDIR}/examples/${location})
  72 endforeach(file ${examples_to_install})
  73
  74 ################################################################
  75 ## Build a sane "make dist" target to build a source package ###
  76 ##    containing only the files that I explicitly state      ###
  77 ##   (instead of any cruft laying on my disk as CPack does)  ###
  78 ################################################################
  79
  80 # This is the complete list of what will be added to the source archive
  81 set(source_to_pack
  82   ${headers_to_install}
  83   ${source_of_generated_headers}
  84   ${MC_SRC_BASE}
  85   ${MC_SRC}
  86   ${MC_SIMGRID_MC_SRC}
  87   ${S4U_SRC}
  88   ${NS3_SRC}
  89   ${PLUGINS_SRC}
  90   ${DAG_SRC}
  91   ${SIMGRID_SRC}
  92   ${SMPI_SRC}
  93   ${KERNEL_SRC}
  94   ${TRACING_SRC}
  95   ${XBT_RL_SRC}
  96   ${XBT_SRC}
  97   ${STHREAD_SRC}
  98   ${EXTRA_DIST}
  99   ${CMAKE_SOURCE_FILES}
 100   ${CMAKEFILES_TXT}
 101   ${DOC_SOURCES}
 102   ${DOC_TOOLS}
 103   ${PLATFORMS_EXAMPLES}
 104   ${README_files}
 105   ${bin_files}
 106   ${examples_src}
 107   ${tesh_files}
 108   ${teshsuite_src}
 109   ${tools_src}
 110   ${txt_files}
 111   ${xml_files}
 112   )
 113 list(SORT source_to_pack)
 114 list(REMOVE_DUPLICATES source_to_pack)
 115
 116 ##########################################
 117 ### Fill in the "make dist-dir" target ###
 118 ##########################################
 119
 120 add_custom_target(dist-dir
 121   COMMENT "Generating the distribution directory"
 122   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 123   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 124   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 125   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 126   )
 127 add_dependencies(dist-dir maintainer_files)
 128
 129 set(dirs_in_tarball "")
 130 foreach(file ${source_to_pack})
 131   #message(${file})
 132   # This damn prefix is still set somewhere (seems to be in subdirs)
 133   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 134
 135   # Prepare the list of files to include in the python sdist, one per line
 136   set(PYTHON_SOURCES "${PYTHON_SOURCES}\ninclude ${file}")
 137
 138   # Create the directory on need
 139   get_filename_component(file_location ${file} PATH)
 140   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 141   if(NOT OPERATION)
 142     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 143     add_custom_command(
 144       TARGET dist-dir
 145       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/)
 146   endif()
 147
 148   # Actually copy the file
 149   add_custom_command(
 150     TARGET dist-dir
 151     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location})
 152 endforeach(file ${source_to_pack})
 153 configure_file("${CMAKE_HOME_DIRECTORY}/MANIFEST.in.in" "${CMAKE_BINARY_DIR}/MANIFEST.in" @ONLY IMMEDIATE)
 154 unset(PYTHON_SOURCES)
 155
 156
 157 add_custom_command(
 158   TARGET dist-dir
 159   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion)
 160
 161 ##########################################################
 162 ### Link all sources to the bindir if srcdir != bindir ###
 163 ##########################################################
 164 add_custom_target(hardlinks
 165    COMMENT "Making the source files available from the bindir"
 166 )
 167 if (NOT ${CMAKE_SOURCE_DIR} STREQUAL ${CMAKE_BINARY_DIR})
 168   foreach(file ${source_to_pack})
 169     #message(${file})
 170     # This damn prefix is still set somewhere (seems to be in subdirs)
 171     string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 172
 173     # Create the directory on need
 174     get_filename_component(file_location ${file} PATH)
 175     string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_bindir}")
 176     if(NOT OPERATION)
 177       set(dirs_in_tarball "${dirs_in_bindir};${file_location};")
 178       add_custom_command(
 179         TARGET hardlinks
 180         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/${file_location}/)
 181     endif()
 182
 183     # Actually copy the file
 184     add_custom_command(
 185       TARGET hardlinks
 186       COMMAND if test -f ${CMAKE_HOME_DIRECTORY}/${file} \; then rm -f ${CMAKE_BINARY_DIR}/${file}\; ln ${CMAKE_HOME_DIRECTORY}/${file} ${CMAKE_BINARY_DIR}/${file_location}\; fi
 187     )
 188   endforeach(file ${source_to_pack})
 189 endif()
 190
 191
 192 ######################################
 193 ### Fill in the "make dist" target ###
 194 ######################################
 195
 196 add_custom_target(dist
 197   COMMENT "Removing the distribution directory"
 198   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 199   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 200   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 201
 202 add_custom_command(
 203   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 204   COMMENT "Compressing the archive from the distribution directory"
 205   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 206   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 207   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/)
 208 add_dependencies(dist dist-dir)
 209
 210 ###########################################
 211 ### Fill in the "make distcheck" target ###
 212 ###########################################
 213
 214 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 215
 216 # Allow to test the "make dist"
 217 add_custom_target(distcheck-archive
 218   COMMAND ${CMAKE_COMMAND} -E echo "XXX Compare archive with git repository"
 219   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/internal/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 220   )
 221 add_dependencies(distcheck-archive dist)
 222
 223 add_custom_target(distcheck-configure
 224   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove old copy"
 225   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 226
 227   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 228   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 229
 230   COMMAND ${CMAKE_COMMAND} -E echo "XXX Create build and install subtrees"
 231   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 232   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 233
 234   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 235   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 236           ${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst -Denable_lto=OFF ..
 237
 238   COMMAND ${CMAKE_COMMAND} -E echo "XXX Check generated files -- please copy new version if they are different"
 239   COMMAND ${CMAKE_COMMAND} -E compare_files ${CMAKE_HOME_DIRECTORY}/MANIFEST.in ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build/MANIFEST.in
 240   )
 241 add_dependencies(distcheck-configure distcheck-archive)
 242
 243 add_custom_target(distcheck
 244   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 245   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4
 246
 247   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 248   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 249
 250   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build tests"
 251   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} -j 4 tests
 252
 253   COMMAND ${CMAKE_COMMAND} -E echo "XXX Run tests"
 254   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure -j 4
 255
 256   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 257   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 258   )
 259 add_dependencies(distcheck distcheck-configure)
 260
 261 #######################################
 262 ### Fill in the "make check" target ###
 263 #######################################
 264
 265 if(enable_memcheck)
 266   add_custom_target(check COMMAND ctest -D ExperimentalMemCheck)
 267 else()
 268   add_custom_target(check COMMAND make test)
 269 endif()
 270 add_dependencies(check tests)
 271
 272 include(CPack)