Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
After extensible reading in automake info files the AC_DEFINE is not used for definin...
[simgrid.git] / configure.ac
1 dnl Copyright (C) 2004-2007. The SimGrid team. All rights reserved.
2
3 dnl This file is part of the SimGrid project. This is free software:
4 dnl You can redistribute and/or modify it under the terms of the
5 dnl GNU LGPL (v2.1) licence.
6
7 ######################
8 ## Setup the autotools
9 ##
10
11 AC_PREREQ(2.59)
12 AC_INIT([simgrid],[3.3-svn],[simgrid-devel@lists.gforge.inria.fr])
13 AC_CONFIG_SRCDIR([include/gras.h])
14 AC_CONFIG_HEADERS([src/gras_config.h])
15 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
16
17 AC_REVISION($Revision$)
18 AC_CANONICAL_TARGET
19 AC_LANG([C])
20 AM_PROG_GCJ
21
22 AM_INIT_AUTOMAKE([gnu -Wno-portability])
23 AC_CONFIG_MACRO_DIR(acmacro) 
24 ACLOCAL="$ACLOCAL -I acmacro"
25
26 dnl Next few lines is a hack to prevent libtool checking for F77
27 m4_undefine([AC_PROG_F77])
28 m4_defun([AC_PROG_F77],[])
29
30 dnl We do build a proper DLL when using win32
31 AC_LIBTOOL_WIN32_DLL
32 AC_PROG_LIBTOOL
33
34 ###############
35 ## SVN version check
36 ##
37 if test -e .svn ; then
38   VERSION="$VERSION-r`svnversion`"
39   PACKAGE_VERSION="$PACKAGE_VERSION-r`svnversion`"
40   PACKAGE_STRING="PACKAGE_STRING r`svnversion`"  
41 fi
42
43 ###############
44 ## System checks
45 ##
46 SG_CONFIGURE_PART([System checks...])
47 AC_PROG_CC(xlC gcc cc)
48 AM_SANITY_CHECK
49 AC_PROG_MAKE_SET
50 AC_CHECK_PRINTF_NULL
51 AC_CHECK_VA_COPY
52
53 # Checks for header files.
54 AC_HEADER_STDC
55 AC_HEADER_TIME
56 AC_CHECK_HEADERS([sys/socket.h \
57                   sys/stat.h \
58                   windows.h winsock.h winsock2.h \
59                   sys/time.h \
60                   errno.h unistd.h \
61                   execinfo.h\
62                   signal.h ])
63 AC_CHECK_FUNCS([gettimeofday usleep \
64                 getdtablesize \
65                 sysconf\
66                 readv\
67                 popen\
68                 signal\
69                 getline])
70                 
71 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
72 AC_FUNC_SNPRINTF
73 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
74 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
75 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
76
77 # Checks for typedefs, structures, and compiler characteristics.
78 AC_C_CONST
79 AC_C_INLINE
80 AC_TYPE_SIZE_T
81
82 ###################################
83 ## SimGrid and GRAS specific checks
84 ##
85
86 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
87 # Check architecture signature begin
88 GRAS_ARCH
89 # Check architecture signature end
90 GRAS_CHECK_STRUCT_COMPACTION
91
92
93 dnl ##
94 dnl ##  CONTEXT IMPLEMENTATION
95 dnl ##
96
97 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
98
99 dnl #
100 dnl #  1. determine possibilities
101 dnl #
102
103 dnl #  check for MCSC method (ucontexts)
104 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
105
106 dnl #  check for pthread method
107 AC_CHECK_HEADERS([pthread.h])
108 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
109
110 if test x$pthread = xyes ; then
111   AC_CHECK_LIB(pthread, sem_init, HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
112   if test ${HAVE_SEM_INIT} = yes ; then
113      AC_MSG_CHECKING(if sem_init is compilable)
114      AC_TRY_COMPILE([#include <semaphore.h>],
115                     [sem_t s; sem_init(&s);], HAVE_SEM_INIT=yes, HAVE_SEM_INIT=no)
116      if test ${HAVE_SEM_INIT} = yes ; then
117         AC_DEFINE([HAVE_SEM_INIT],1,[Define if sem_init() is avaible or not (part of XPG6 standard only)])
118         AC_MSG_RESULT(yes)
119      else
120         AC_MSG_RESULT(no)
121      fi
122   fi
123   AC_CHECK_LIB(pthread, sem_timedwait, HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
124   if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
125      AC_MSG_CHECKING(if sem_timedwait is compilable)
126      AC_TRY_COMPILE([#include <semaphore.h>],
127                     [sem_t *s; const struct timespec * t; sem_timedwait(s, t);], HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
128      if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
129         AC_DEFINE([HAVE_SEM_TIMEDWAIT],1,[Define if sem_timedwait() is avaible or not (part of XPG6 standard only)])
130         AC_MSG_RESULT(yes)
131      else
132         AC_MSG_RESULT(no)
133      fi
134   fi
135
136   AC_CHECK_LIB(pthread, pthread_mutex_timedlock, HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
137   if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
138      AC_MSG_CHECKING(if pthread_mutex_timedlock is compilable)
139      AC_TRY_COMPILE([#include <pthread.h>],
140                     [pthread_mutex_t s; const struct timespec t; sem_timedlock(&s, &t);], HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
141      if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
142         AC_DEFINE([HAVE_MUTEX_TIMEDLOCK],1,[Define if pthread_mutex_timedlock() is avaible or not (part of XPG6 standard only?)])
143         AC_MSG_RESULT(yes)
144      else
145         AC_MSG_RESULT(no)
146      fi
147   fi
148 fi
149
150 dnl #
151 dnl #  2. make a general decision
152 dnl #
153
154 if test ".$mcsc" = .yes; then
155    # ucontext found
156    mcsc=yes
157 elif test ".$pthread" = .yes; then
158    # ucontext not found, but pthread found
159    pthread=yes
160 else
161     ac_header=windows.h
162     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
163     if test `eval echo '${'$as_ac_Header'}'` = yes; then
164       windows_context=yes
165     else
166       AC_ERROR([no appropriate backend found])
167     fi
168 fi
169 AM_CONDITIONAL(IS_WINDOWS,test x$windows_context = xyes)
170
171
172 dnl #
173 dnl #  3. allow decision to be overridden by user
174 dnl #
175
176 AC_MSG_CHECKING(what kind of backend should we use)
177
178 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
179 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
180
181 AC_ARG_WITH(context,
182   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
183   with_context=auto)
184
185 if test "x$with_context$mcsc" = "xucontextno" ; then 
186   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
187 fi
188
189 case $with_context in
190  ucontext) ;;
191  pthread) ;;
192  pthreads) ;;
193  windows) ;;
194  auto) with_context=ucontext;;
195  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
196 esac
197
198 if test "x$with_context" = "xucontext" ; then
199   if test ".$mcsc" = .yes; then
200     AC_MSG_RESULT(found working ucontext. Great!)
201     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
202   else
203     if test ".$windows_context" = .yes ; then
204       AC_MSG_RESULT(use windows context portability layer.)
205       with_context=windows
206     else
207       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
208       with_context=pthread
209     fi
210   fi
211 fi
212
213 if test "x$with_context" = "xpthread"; then
214   if test x$pthread != xyes ; then # reuse previous checks
215     AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])
216   fi
217   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
218   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
219 fi
220 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
221
222 dnl #
223 dnl #  4. determine a few additional details
224 dnl #
225
226 if test "x$with_context" = "xucontext" ; then
227 dnl #  direction of stack grow
228   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
229   if test ".$ac_cv_check_stackgrowth" = ".down"; then
230       PTH_STACK_GROWTH="down"
231   else
232       PTH_STACK_GROWTH="up"
233   fi
234   AC_SUBST(PTH_STACK_GROWTH)
235   
236   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
237 fi
238
239 #########################################
240 ## Check for libraries extra-dependencies
241 ##
242
243 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
244
245 SIMGRID_DEP=""
246 SMPI_DEP=""
247 GRAS_DEP=""
248
249 if test xpthread=xyes ; then 
250   # if the pthreads are usable
251   if test "x$with_context" = "xpthread" ; then
252     # if we use them to implement the xbt_context
253     SIMGRID_DEP="-lpthread"
254   fi
255   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
256   if test "x$with_context" != "xwindows" ; then
257     GRAS_DEP="-lpthread"
258   fi
259 fi
260
261 #########################################
262 ## Build optional modules (gtnets)
263 ##
264 gtnets=no
265 AC_ARG_WITH(gtnets,
266   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
267   gtnets_path="$withval",gtnets_path="no")
268 if test "x$gtnets_path" = "xno" ; then
269   AC_MSG_RESULT(Eventually you will come to GTNetS.)
270 else  
271   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
272   AC_MSG_CHECKING(for gtnets)
273   AC_DEFINE([HAVE_GTNETS], 1, [Indicates that we have GTNETS support])
274   AM_CONDITIONAL(HAVE_GTNETS, test "x$gtnets" != "xno")
275   AC_LANG_PUSH([C++])  
276   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
277   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
278   LDFLAGS_SAV=$LDFLAGS  
279   CPPFLAGS_SAV=$CPPFLAGS
280   CPPFLAGS+=$GTNETS_CPPFLAGS
281   LDFLAGS+=$GTNETS_LDFLAGS
282   AC_TRY_LINK([ #include <simulator.h>
283               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
284   CPPFLAGS=$CPPFLAGS_SAV
285   LDFLAGS=$LDFLAGS_SAV
286   AC_LANG_POP([C++])  
287 fi
288
289 if test "x$gtnets" = "xyes" ; then
290   AC_MSG_RESULT(Enabling GTNETS support.)
291   LDFLAGS+="-lgtnets -L$gtnets_path/lib"
292   CPPFLAGS+="-I$gtnets_path/include -I$gtnets_path/include/gtnets -DHAVE_GTNETS"
293 fi
294
295
296
297
298
299 #########################################
300 ## Build optional modules (csdp)
301 ##
302 csdp=no
303 AC_ARG_WITH(csdp,
304   AS_HELP_STRING([--with-csdp], [Path to csdp installation (default to empty, i.e. not using csdp)]),
305   csdp_path="$withval",csdp_path="no")
306   AC_MSG_CHECKING(for CSDP option:)
307 if test "x$csdp_path" = "xno" ; then
308   AC_MSG_RESULT(no, eventually you will come to csdp.)
309 else  
310   AC_MSG_RESULT(***** You have decided to use csdp. Let's check whether it works or not *****)
311   AC_MSG_CHECKING(for csdp)
312   CSDP_LDFLAGS="-L$csdp_path/lib -lsdp -llapack -lblas -lm"
313   CSDP_CPPFLAGS="-I$csdp_path/include -I$csdp_path/include/csdp"
314
315   AC_CHECK_LIB(sdp,easy_sdp, csdp_lib=yes, csdp_lib=no,$CSDP_LDFLAGS)
316   
317   CPPFLAGS_SAV=$CPPFLAGS
318   CPPFLAGS+=$CSDP_CPPFLAGS
319   AC_CHECK_HEADER(declarations.h, csdp_header=yes, csdp_header=no, [])
320   CPPFLAGS=$CPPFLAGS_SAV
321
322   
323
324   if test "x$csdp_lib = xyes" -a "x$csdp_header = xyes" ; then
325      csdp=yes;
326   else 
327      csdp=no;
328   fi
329   if test "x$csdp" = xyes; then 
330     AM_CPPFLAGS="$AM_CPPFLAGS $CSDP_CPPFLAGS -DHAVE_SDP"
331     SIMGRID_DEP="$SIMGRID_DEP $CSDP_LDFLAGS"
332     AC_MSG_RESULT(Found working sdp library.)
333     AC_DEFINE([HAVE_SDP], 1, [Indicates whether we have the CSDP library or not])
334   else
335     AC_MSG_RESULT(Could not find any working sdp library.)
336   fi;
337 fi
338 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
339
340 AC_SUBST([SIMGRID_DEP])
341 AC_SUBST([SMPI_DEP])
342
343 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
344 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
345
346 AC_MSG_CHECKING(for extra dependencies of libgras)
347 case $host_os in
348   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
349             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
350             AC_DEFINE(CONTEXT_THREADS,1);;
351 esac
352
353
354
355 if test "x$GRAS_DEP" = x; then 
356    AC_MSG_RESULT(none)
357 else
358    AC_MSG_RESULT($GRAS_DEP)
359 fi
360 AC_SUBST([GRAS_DEP])
361
362 ##############################################
363 ## Enhance maintainer mode and SUBST variables
364 ## (must be placed after any compilation tests since our overprotective flags
365 ##  let some tests fail)
366
367 # Check whether we are doing a regular build or a GRAMINE (minimal) one
368 # Next line is modified by sed when building gramine source tree
369 gramine_mode=no
370 if test x$gramine_mode = xyes
371 then
372   USE_MAINTAINER_MODE=no
373 fi
374 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
375
376
377 AM_MAINTAINER_MODE
378 if test x$USE_MAINTAINER_MODE = xyes 
379 then
380    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
381    enable_compile_warnings=yes   
382 fi
383 SG_COMPILE_FLAGS
384
385 AC_SUBST([CFLAGS])
386 AC_SUBST([CPPFLAGS])
387 AC_SUBST([LDFLAGS])
388 AC_SUBST([AM_CPPFLAGS])
389 AC_SUBST([abs_builddir])
390 AC_SUBST([abs_srcdir])
391 AC_SUBST([abs_top_builddir])
392 AC_SUBST([abs_top_srcdir])
393
394 ##############################################
395 ## Specific mode for build daemons.
396 ## (they compile the SVN without having the autotools installed)
397 AC_ARG_ENABLE(botbuild,
398               AS_HELP_STRING([--enable-botbuild], [Compilation mode for build daemons -- do not use it]),
399               botbuild=$enableval,botbuild=no)
400 AM_CONDITIONAL(BOTBUILD_MODE,test x$botbuild != xno)
401
402 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild != xyes ; then
403   echo "ERROR: "
404   echo "ERROR: You have to enable the maintainer mode to compile the SVN."
405   echo "ERROR: For this, just call configure this way:"
406   echo "ERROR:"
407   echo "ERROR: ./configure '--enable-maintainer-mode' $ac_configure_args"
408   echo "ERROR:"
409   exit 1
410 fi
411
412
413 SG_CONFIGURE_PART(Check for Java bindings...)
414 # Java cruft
415 AC_ARG_ENABLE(java,
416               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
417               disable_java=$enableval,disable_java=yes)
418 if test "x$disable_java" != "xyes" ; then
419    use_java="disabled by user"
420 else
421   AC_PATH_PROG([JAVAC], [javac], `which javac`)
422   AC_PATH_PROG([JAVA],  [java] , `which java`)
423   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
424   AC_CHECK_HEADERS(jni.h)
425   if test -n "$JAVAC"   \
426      && test -n "$JAVA" \
427      && test -n "$JAR"  \
428      && test "x$ac_cv_header_jni_h" = "xyes" ; then
429    
430      use_java="yes"
431      AC_DEFINE(HAVE_JAVA,1, [defines whether Java bindings must be compiled or not])
432   else   
433      use_java="no"
434   fi
435 fi
436 AC_MSG_RESULT(decide whether to compile java bindings... $use_java)
437 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
438
439
440 #####################
441 ## Check for programs
442 ##
443
444 SG_CONFIGURE_PART(Check for programs...)
445 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
446 WARNING="This file is generated, do not edit"
447 AC_SUBST(WARNING)
448
449
450 # Can we rebuild the parsers?
451 # We really want flex and refuse other lex. So, the parser is portable and
452 # does not induce extra lib dependency
453 AC_PROG_FLEX(2.5.30)
454                 
455 # Can we rebuild the xml-lexers from the XML specification?
456 # if not, simply touch the flex source files (which are distributed in
457 #  tarballs even if generated by flexml) and hope for the best.
458 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
459 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
460
461 if test x$USE_MAINTAINER_MODE = xyes 
462 then
463    # Check for doxygen when in maintainer mode since dist* targets fail
464    # without it
465    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
466    if test x$DOXYGEN = x ; then 
467      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
468    fi
469 fi
470
471 # Can we extract really usable backtraces? (also need the popen function)
472 AC_PATH_PROG(ADDR2LINE, addr2line)
473 if test x$ADDR2LINE != x ; then
474   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
475 fi
476
477 AC_SUBST(ac_configure_args)
478 AC_DEFINE_UNQUOTED(AC_CONFIGURE_ARGS,"$ac_configure_args",[Arguments passed to the configure script])
479 # Can we make status line about the compilation result?
480 dnl A C_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
481 build_id="$PACKAGE ver=$VERSION args=\"$ac_configure_args\""
482 AC_SUBST(build_id)
483
484 ###################
485 ## Makes the output
486 ##
487
488
489 #
490 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
491 #  src/amok/Makefile
492
493 SG_CONFIGURE_PART(Generating files...)
494
495 # Core of the libraries
496
497 AC_CONFIG_FILES([
498   Makefile
499   include/Makefile
500   src/Makefile
501   src/context_sysv_config.h
502 ])
503
504 # Tools being embeeded in gramine (stub generator)
505 AC_CONFIG_FILES([
506   tools/Makefile
507     tools/gras/Makefile
508     tools/tesh/Makefile
509 ])
510
511
512 # GRAMINE_CUT_BEGIN
513
514 # Tools NOT being embeeded in gramine
515 AC_CONFIG_FILES([
516   tools/graspe-slave
517 ],[
518     for file in                                                 \
519      tools/graspe-slave           tools/graspe-master           \
520      checkall                     examples/java/runtest         \
521     ; do                                                        \
522       test -e $file && chmod +x $file;                          \
523     done
524 ])
525
526 # Testsuite
527
528 AC_CONFIG_FILES([  
529   testsuite/Makefile
530   testsuite/run_tests    
531 ],[
532     for file in                                                 \
533      testsuite/run_tests                                        \
534     ; do                                                        \
535       test -e $file && chmod +x $file;                          \
536     done
537 ])
538
539 # Teshsuite (testsuite using tesh)
540 AC_CONFIG_FILES([  
541   teshsuite/Makefile
542 ])
543
544 # Documentation
545 AC_CONFIG_FILES([
546   doc/Makefile
547   doc/Doxyfile
548 ])
549
550 # Examples
551
552 #      examples/gras/p2p/Makefile
553 #      examples/gras/p2p/chord/Makefile
554 #      examples/gras/p2p/can/Makefile
555
556 AC_CONFIG_FILES([
557     examples/java/Makefile
558       examples/java/basic/Makefile
559       examples/java/comm_time/Makefile
560       examples/java/suspend/Makefile
561       examples/java/ping_pong/Makefile
562 ])
563
564 AC_CONFIG_FILES([
565   examples/Makefile 
566     examples/msg/Makefile
567     examples/simdag/Makefile
568     examples/gras/Makefile
569       examples/gras/ping/Makefile   
570       examples/gras/rpc/Makefile
571       examples/gras/spawn/Makefile
572       examples/gras/synchro/Makefile
573       examples/gras/timer/Makefile
574       examples/gras/properties/Makefile
575       examples/gras/chrono/Makefile
576       examples/gras/mutual_exclusion/simple_token/Makefile
577       examples/gras/mmrpc/Makefile
578       examples/gras/pmm/Makefile
579       examples/gras/all2all/Makefile
580     examples/amok/Makefile       
581 ])
582
583 AC_CONFIG_FILES([
584   src/smpi/smpicc
585   src/smpi/smpirun
586 ])
587
588 # GRAMINE_CUT_END
589
590 AC_OUTPUT
591
592 echo "
593
594 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
595
596         Compiler:        ${CC} (version: ${GCC_VERSION})
597         
598         CFlags:          ${CFLAGS}
599         CPPFlags:        ${CPPFLAGS}
600         LDFlags:         ${LDFLAGS}
601
602         Context backend: ${with_context}
603         Compile Java:    ${use_java}
604         
605         Maintainer mode: ${USE_MAINTAINER_MODE}
606
607 "
608 if test x$botbuild = xyes ; then
609   echo "        This is a bot build. Do not specify --enable-botbuild if you are not a bot."
610   echo
611 fi
612
613 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild = xyes ; then
614   echo "WARNING: "
615   echo "WARNING: You are compiling the SVN in botbuild mode. If you are not a daemon, don't do so. "
616   echo "WARNING: Remove the --enable-botbuild from your configure line, and add --enable-maintainer-mode instead."
617   echo "WARNING:"
618   echo "WARNING: You won't be able to build archives until then (make dist is likely to fail). "
619   echo "WARNING:"
620 fi
621
622 echo $build_id > stamp.configure
623
624 exit 0;