tools/cmake/Tests.cmake

   1 IF(enable_smpi AND NOT WIN32)
   2   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpicc)
   3   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpicxx)
   4   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpiff)
   5   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpif90)
   6   execute_process(COMMAND chmod a=rwx ${CMAKE_BINARY_DIR}/bin/smpirun)
   7 ENDIF()
   8
   9 SET(TESH_OPTION "--ignore-jenkins")
  10 SET(TESH_COMMAND ${CMAKE_BINARY_DIR}/bin/tesh)
  11 IF(CMAKE_HOST_WIN32)
  12   SET(TESH_OPTION ${TESH_OPTION} --timeout 50)
  13 ENDIF()
  14
  15 IF(enable_memcheck)
  16   INCLUDE(FindValgrind)
  17 ENDIF()
  18
  19 #some tests may take forever on non futexes systems, using busy_wait with n cores < n workers
  20 # default to posix for these tests if futexes are not supported
  21 IF(NOT HAVE_FUTEX_H)
  22   SET(CONTEXTS_SYNCHRO --cfg contexts/synchro:posix)
  23 ENDIF()
  24
  25 MACRO(ADD_TESH NAME)
  26   SET(ARGT ${ARGV})
  27   LIST(REMOVE_AT ARGT 0)
  28   IF(WIN32)
  29     STRING(REPLACE "§" "\;" ARGT "${ARGT}")
  30   ENDIF()
  31   if(TESH_WRAPPER)
  32     ADD_TEST(${NAME} ${TESH_COMMAND} --wrapper "${TESH_WRAPPER}" ${TESH_OPTION} ${ARGT})
  33   else()
  34     ADD_TEST(${NAME} ${TESH_COMMAND} ${TESH_OPTION} ${ARGT})
  35   endif()
  36 ENDMACRO()
  37
  38 MACRO(ADD_TESH_FACTORIES NAME FACTORIES)
  39   SET(ARGR ${ARGV})
  40   LIST(REMOVE_AT ARGR 0) # remove name
  41   FOREACH(I ${FACTORIES}) # remove all factories
  42     LIST(REMOVE_AT ARGR 0)
  43   ENDFOREACH()
  44   FOREACH(FACTORY ${FACTORIES})
  45     if ((${FACTORY} STREQUAL "thread" AND HAVE_THREAD_CONTEXTS) OR
  46         (${FACTORY} STREQUAL "boost" AND HAVE_BOOST_CONTEXTS) OR
  47         (${FACTORY} STREQUAL "raw" AND HAVE_RAW_CONTEXTS) OR
  48         (${FACTORY} STREQUAL "ucontext" AND HAVE_UCONTEXT_CONTEXTS))
  49       ADD_TESH("${NAME}-${FACTORY}" "--cfg" "contexts/factory:${FACTORY}" ${ARGR})
  50     ENDIF()
  51   ENDFOREACH()
  52 ENDMACRO()
  53
  54 IF(enable_java)
  55   IF(WIN32)
  56     SET(TESH_CLASSPATH "${CMAKE_BINARY_DIR}/examples/java/\;${CMAKE_BINARY_DIR}/teshsuite/java/\;${SIMGRID_JAR}")
  57     STRING(REPLACE "\;" "§" TESH_CLASSPATH "${TESH_CLASSPATH}")
  58   ELSE()
  59     SET(TESH_CLASSPATH "${CMAKE_BINARY_DIR}/examples/java/:${CMAKE_BINARY_DIR}/teshsuite/java/:${SIMGRID_JAR}")
  60   ENDIF()
  61 ENDIF()
  62
  63 IF(HAVE_MC)
  64   ADD_TESH_FACTORIES(mc-bugged1                "ucontext;raw" --setenv bindir=${CMAKE_BINARY_DIR}/examples/msg/mc --cd ${CMAKE_HOME_DIRECTORY}/examples/msg/mc bugged1.tesh)
  65   ADD_TESH_FACTORIES(mc-bugged2                "ucontext;raw" --setenv bindir=${CMAKE_BINARY_DIR}/examples/msg/mc --cd ${CMAKE_HOME_DIRECTORY}/examples/msg/mc bugged2.tesh)
  66   IF(HAVE_UCONTEXT_CONTEXTS AND PROCESSOR_x86_64) # liveness model-checking works only on 64bits (for now ...)
  67     ADD_TESH(mc-bugged1-liveness-ucontext         --setenv bindir=${CMAKE_BINARY_DIR}/examples/msg/mc --cd ${CMAKE_HOME_DIRECTORY}/examples/msg/mc bugged1_liveness.tesh)
  68     ADD_TESH(mc-bugged1-liveness-ucontext-sparse  --setenv bindir=${CMAKE_BINARY_DIR}/examples/msg/mc --cd ${CMAKE_HOME_DIRECTORY}/examples/msg/mc bugged1_liveness_sparse.tesh)
  69     ADD_TESH(mc-bugged1-liveness-visited-ucontext --setenv bindir=${CMAKE_BINARY_DIR}/examples/msg/mc --cd ${CMAKE_HOME_DIRECTORY}/examples/msg/mc bugged1_liveness_visited.tesh)
  70     ADD_TESH(mc-bugged1-liveness-visited-ucontext-sparse --setenv bindir=${CMAKE_BINARY_DIR}/examples/msg/mc --cd ${CMAKE_HOME_DIRECTORY}/examples/msg/mc bugged1_liveness_visited_sparse.tesh)
  71     IF(HAVE_C_STACK_CLEANER)
  72       # This test checks if the stack cleaner is making a difference:
  73       ADD_TEST(mc-bugged1-liveness-stack-cleaner ${CMAKE_HOME_DIRECTORY}/examples/msg/mc/bugged1_liveness_stack_cleaner ${CMAKE_HOME_DIRECTORY}/examples/msg/mc/ ${CMAKE_BINARY_DIR}/examples/msg/mc/)
  74     ENDIF()
  75   ENDIF()
  76 ENDIF()
  77
  78 IF(enable_smpi_MPICH3_testsuite AND SMPI_FORTRAN AND HAVE_THREAD_CONTEXTS)
  79   ADD_TEST(test-smpi-mpich3-thread-f77     ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_DIR}/teshsuite/smpi/mpich3-test/f77/ ${PERL_EXECUTABLE} ${CMAKE_HOME_DIRECTORY}/teshsuite/smpi/mpich3-test/runtests ${TESH_OPTION} -mpiexec=${CMAKE_BINARY_DIR}/smpi_script/bin/smpirun -srcdir=${CMAKE_HOME_DIRECTORY}/teshsuite/smpi/mpich3-test/f77/ -tests=testlist -privatization=${HAVE_PRIVATIZATION} -execarg=--cfg=contexts/stack_size:8000 -execarg=--cfg=contexts/factory:thread -execarg=--cfg=smpi/privatize-global-variables:${HAVE_PRIVATIZATION})
  80   SET_TESTS_PROPERTIES(test-smpi-mpich3-thread-f77 PROPERTIES PASS_REGULAR_EXPRESSION "tests passed!")
  81   ADD_TEST(test-smpi-mpich3-thread-f90     ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_DIR}/teshsuite/smpi/mpich3-test/f90/ ${PERL_EXECUTABLE} ${CMAKE_HOME_DIRECTORY}/teshsuite/smpi/mpich3-test/runtests ${TESH_OPTION} -mpiexec=${CMAKE_BINARY_DIR}/smpi_script/bin/smpirun -srcdir=${CMAKE_HOME_DIRECTORY}/teshsuite/smpi/mpich3-test/f90/ -tests=testlist -privatization=${HAVE_PRIVATIZATION} -execarg=--cfg=smpi/privatize-global-variables:${HAVE_PRIVATIZATION} -execarg=--cfg=contexts/factory:thread)
  82   SET_TESTS_PROPERTIES(test-smpi-mpich3-thread-f90 PROPERTIES PASS_REGULAR_EXPRESSION "tests passed!")
  83 ENDIF()
  84
  85 IF(HAVE_LUA)
  86   # Tests testing simulation from C but using lua for platform files. Executed like this
  87   # ~$ ./masterslave platform.lua deploy.lua
  88   ADD_TESH(lua-platform-masterslave                --setenv srcdir=${CMAKE_HOME_DIRECTORY}/teshsuite/lua --cd ${CMAKE_BINARY_DIR}/examples/lua ${CMAKE_HOME_DIRECTORY}/teshsuite/lua/lua_platforms.tesh)
  89   SET_TESTS_PROPERTIES(lua-platform-masterslave    PROPERTIES ENVIRONMENT "LUA_CPATH=${CMAKE_BINARY_DIR}/examples/lua/?.so")
  90 ENDIF()
  91
  92 ADD_TEST(testall                                 ${CMAKE_BINARY_DIR}/testall)