tools/cmake/Java.cmake

   1 ##
   2 ## The Cmake definitions for the use of Java (and Scala)
   3 ##   This file is loaded only if the Java option is activated
   4 ##
   5
   6 find_package(Java 1.7 COMPONENTS Runtime Development)
   7 if (NOT ${Java_FOUND})
   8   message(FATAL_ERROR "Java not found (need at least Java7). Please install the JDK or disable that option")
   9 endif()
  10 set(Java_FOUND 1)
  11 include(UseJava)
  12
  13 find_package(JNI REQUIRED)
  14 message("-- [Java] JNI found: ${JNI_FOUND}")
  15 message("-- [Java] JNI include dirs: ${JNI_INCLUDE_DIRS}")
  16
  17 if(WIN32)
  18   execute_process(COMMAND         java -d64 -version
  19                   OUTPUT_VARIABLE JVM_IS_64_BITS)
  20   if("${JVM_IS_64_BITS}" MATCHES "Error")
  21     message(fatal_error "SimGrid can only use Java 64 bits")
  22   endif()
  23 endif()
  24
  25 # find_package(SWIG)
  26 # if(${SWIG_FOUND})
  27 #   include(UseSWIG)
  28 #   message("-- [Java] Swig found: version ${SWIG_VERSION}")
  29 # else()
  30 #   message("-- [Java] Swig NOT FOUND. That's fine unless you work on this part yourself.")
  31 # endif()
  32 #mark_as_advanced(SWIG_EXECUTABLE)
  33
  34 # Rules to build libsimgrid-java
  35 ################################
  36
  37 add_library(simgrid-java SHARED ${JMSG_C_SRC})
  38 set_target_properties(simgrid-java PROPERTIES VERSION          ${libsimgrid-java_version})
  39 set_target_properties(simgrid-java PROPERTIES SKIP_BUILD_RPATH ON)
  40
  41 target_link_libraries(simgrid-java simgrid)
  42
  43 get_target_property(COMMON_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  44 if (COMMON_INCLUDES)
  45   set_target_properties(simgrid-java PROPERTIES
  46     INCLUDE_DIRECTORIES "${COMMON_INCLUDES};${JNI_INCLUDE_DIRS}")
  47 else()
  48   set_target_properties(simgrid-java PROPERTIES
  49     INCLUDE_DIRECTORIES "${JNI_INCLUDE_DIRS}")
  50 endif()
  51
  52 get_target_property(CHECK_INCLUDES simgrid-java INCLUDE_DIRECTORIES)
  53 message("-- [Java] simgrid-java includes: ${CHECK_INCLUDES}")
  54
  55 # Rules to build simgrid.jar
  56 ############################
  57
  58 ## Files to include in simgrid.jar
  59 ##
  60 set(SIMGRID_JAR "${CMAKE_BINARY_DIR}/simgrid.jar")
  61 set(MANIFEST_IN_FILE "${CMAKE_HOME_DIRECTORY}/src/bindings/java/MANIFEST.in")
  62 set(MANIFEST_FILE "${CMAKE_BINARY_DIR}/src/bindings/java/MANIFEST.MF")
  63
  64 set(LIBSIMGRID_SO
  65   libsimgrid${CMAKE_SHARED_LIBRARY_SUFFIX})
  66 set(LIBSIMGRID_JAVA_SO
  67   ${CMAKE_SHARED_LIBRARY_PREFIX}simgrid-java${CMAKE_SHARED_LIBRARY_SUFFIX})
  68
  69 ## Here is how to build simgrid.jar
  70 ##
  71 if(CMAKE_VERSION VERSION_LESS "2.8.12")
  72   set(CMAKE_JAVA_TARGET_OUTPUT_NAME simgrid)
  73   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC})
  74 else()
  75   add_jar(simgrid-java_jar ${JMSG_JAVA_SRC} OUTPUT_NAME simgrid)
  76 endif()
  77
  78 add_dependencies(simgrid-java_jar simgrid-java)
  79 add_dependencies(simgrid-java_jar simgrid)
  80
  81 if (enable_documentation)
  82   add_custom_command(
  83     TARGET simgrid-java_jar POST_BUILD
  84     COMMENT "Add the documentation into simgrid.jar..."
  85     DEPENDS ${MANIFEST_IN_FILE}
  86             ${CMAKE_HOME_DIRECTORY}/COPYING
  87             ${CMAKE_HOME_DIRECTORY}/ChangeLog
  88             ${CMAKE_HOME_DIRECTORY}/NEWS
  89             ${CMAKE_HOME_DIRECTORY}/LICENSE-LGPL-2.1
  90
  91     COMMAND ${CMAKE_COMMAND} -E copy ${MANIFEST_IN_FILE} ${MANIFEST_FILE}
  92     COMMAND ${CMAKE_COMMAND} -E echo "Specification-Version: \\\"${SIMGRID_VERSION_MAJOR}.${SIMGRID_VERSION_MINOR}.${SIMGRID_VERSION_PATCH}\\\"" >> ${MANIFEST_FILE}
  93     COMMAND ${CMAKE_COMMAND} -E echo "Implementation-Version: \\\"${GIT_VERSION}\\\"" >> ${MANIFEST_FILE}
  94
  95     COMMAND ${Java_JAVADOC_EXECUTABLE} -quiet -d doc/javadoc -sourcepath ${CMAKE_HOME_DIRECTORY}/src/bindings/java/ org.simgrid.msg org.simgrid.trace
  96
  97     COMMAND ${JAVA_ARCHIVE} -uvmf ${MANIFEST_FILE} ${SIMGRID_JAR} doc/javadoc
  98     COMMAND ${JAVA_ARCHIVE} -uvf  ${SIMGRID_JAR} -C ${CMAKE_HOME_DIRECTORY} COPYING -C ${CMAKE_HOME_DIRECTORY} ChangeLog -C ${CMAKE_HOME_DIRECTORY} LICENSE-LGPL-2.1 -C ${CMAKE_HOME_DIRECTORY} NEWS
  99   )
 100 endif()
 101
 102 ###
 103 ### Pack the java libraries into the jarfile if asked to do so
 104 ###
 105
 106 if(enable_lib_in_jar)
 107
 108
 109   set(SG_SYSTEM_NAME ${CMAKE_SYSTEM_NAME})
 110
 111   if(${SG_SYSTEM_NAME} MATCHES "kFreeBSD")
 112     set(SG_SYSTEM_NAME GNU/kFreeBSD)
 113   endif()
 114
 115   set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR})
 116   if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "^i[3-6]86$")
 117     set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/x86)
 118   endif()
 119   if(  (${CMAKE_SYSTEM_PROCESSOR} MATCHES "x86_64") OR
 120        (${CMAKE_SYSTEM_PROCESSOR} MATCHES "AMD64")     )
 121     set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/amd64)
 122   endif()
 123   if(${CMAKE_SYSTEM_PROCESSOR} MATCHES "armv7l")
 124     set(JAVA_NATIVE_PATH NATIVE/${SG_SYSTEM_NAME}/arm) # Default arm (soft-float ABI)
 125   endif()
 126
 127   add_custom_command(
 128     TARGET simgrid-java_jar POST_BUILD
 129     COMMENT "Add the native libs into simgrid.jar..."
 130     DEPENDS simgrid simgrid-java ${JAVALIBS}
 131
 132     COMMAND ${CMAKE_COMMAND} -E make_directory   ${JAVA_NATIVE_PATH}
 133
 134     COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_SO}      ${JAVA_NATIVE_PATH}/${LIBSIMGRID_SO}
 135     COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_BINARY_DIR}/lib/${LIBSIMGRID_JAVA_SO} ${JAVA_NATIVE_PATH}/${LIBSIMGRID_JAVA_SO}
 136     # There is no way to disable the dependency of mingw-64 on that lib, unfortunately nor to script cmake -E properly
 137     # So let's be brutal and copy it in any case (even on non-windows builds) from the location where chocolatey installs it.
 138     # The copy is only expected to work on the appveyor builder, but that's all we need right now
 139     # since our users are directed to download that file as nightly build.
 140     COMMAND ${CMAKE_COMMAND} -E copy_if_different C:/tools/mingw64/bin/libwinpthread-1.dll  ${JAVA_NATIVE_PATH}/libwinpthread-1.dll || true
 141
 142     COMMAND ${JAVA_ARCHIVE} -uvf ${SIMGRID_JAR}  ${JAVA_NATIVE_PATH}
 143
 144     COMMAND ${CMAKE_COMMAND} -E echo "-- Cmake put the native code in ${JAVA_NATIVE_PATH}"
 145     COMMAND "${Java_JAVA_EXECUTABLE}" -classpath "${SIMGRID_JAR}" org.simgrid.NativeLib
 146   )
 147
 148 endif(enable_lib_in_jar)
 149
 150 include_directories(${JNI_INCLUDE_DIRS} ${JAVA_INCLUDE_PATH} ${JAVA_INCLUDE_PATH2})