Logo AND Algorithmique Numérique Distribuée

Public GIT Repository
Check for pthread_mutex_timedlock()
[simgrid.git] / configure.ac
1 dnl Copyright (C) 2004-2007. The SimGrid team. All rights reserved.
2
3 dnl This file is part of the SimGrid project. This is free software:
4 dnl You can redistribute and/or modify it under the terms of the
5 dnl GNU LGPL (v2.1) licence.
6
7 ######################
8 ## Setup the autotools
9 ##
10
11 AC_PREREQ(2.59)
12 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
13 AC_CONFIG_SRCDIR([include/gras.h])
14 AC_CONFIG_HEADERS([src/gras_config.h])
15 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
16
17 AC_REVISION($Revision$)
18 AC_CANONICAL_TARGET
19 AC_LANG([C])
20 AM_PROG_GCJ
21
22 AM_INIT_AUTOMAKE([gnu -Wno-portability])
23 AC_CONFIG_MACRO_DIR(acmacro) 
24 ACLOCAL="$ACLOCAL -I acmacro"
25
26 dnl Next few lines is a hack to prevent libtool checking for F77
27 m4_undefine([AC_PROG_F77])
28 m4_defun([AC_PROG_F77],[])
29
30 dnl We do build a proper DLL when using win32
31 AC_LIBTOOL_WIN32_DLL
32 AC_PROG_LIBTOOL
33
34 ###############
35 ## System checks
36 ##
37 SG_CONFIGURE_PART([System checks...])
38 AC_PROG_CC(xlC gcc cc)
39 AM_SANITY_CHECK
40 AC_PROG_MAKE_SET
41 AC_CHECK_PRINTF_NULL
42 AC_CHECK_VA_COPY
43
44 # Checks for header files.
45 AC_HEADER_STDC
46 AC_HEADER_TIME
47 AC_CHECK_HEADERS([sys/socket.h \
48                   sys/stat.h \
49                   windows.h winsock.h winsock2.h \
50                   sys/time.h \
51                   errno.h unistd.h \
52                   execinfo.h\
53                   signal.h ])
54 AC_CHECK_FUNCS([gettimeofday usleep \
55                 getdtablesize \
56                 sysconf\
57                 readv\
58                 popen\
59                 signal\
60                 getline])
61                 
62 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
63 AC_FUNC_SNPRINTF
64 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
65 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
66 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
67
68 # Checks for typedefs, structures, and compiler characteristics.
69 AC_C_CONST
70 AC_C_INLINE
71 AC_TYPE_SIZE_T
72
73 ###################################
74 ## SimGrid and GRAS specific checks
75 ##
76
77 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
78 # Check architecture signature begin
79 GRAS_ARCH
80 # Check architecture signature end
81 GRAS_CHECK_STRUCT_COMPACTION
82
83
84 dnl ##
85 dnl ##  CONTEXT IMPLEMENTATION
86 dnl ##
87
88 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
89
90 dnl #
91 dnl #  1. determine possibilities
92 dnl #
93
94 dnl #  check for MCSC method (ucontexts)
95 AC_CHECK_MCSC(mcsc=yes, mcsc=no) 
96
97 dnl #  check for pthread method
98 AC_CHECK_HEADERS([pthread.h])
99 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
100
101 if test x$pthread = xyes ; then
102   AC_CHECK_LIB(pthread, sem_timedwait, HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
103   if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
104      AC_MSG_CHECKING(if sem_timedwait is compilable)
105      AC_TRY_COMPILE([#include <semaphore.h>],
106                     [sem_t *s; const struct timespec * t; sem_timedwait(s, t);], HAVE_SEM_TIMEDWAIT=yes, HAVE_SEM_TIMEDWAIT=no)
107      if test ${HAVE_SEM_TIMEDWAIT} = yes ; then
108         AC_DEFINE([HAVE_SEM_TIMEDWAIT],1,[Define if sem_timedwait() is avaible or not (part of XPG6 standard only)])
109         AC_MSG_RESULT(yes)
110      else
111         AC_MSG_RESULT(no)
112      fi
113   fi
114
115   AC_CHECK_LIB(pthread, pthread_mutex_timedlock, HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
116   if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
117      AC_MSG_CHECKING(if pthread_mutex_timedlock is compilable)
118      AC_TRY_COMPILE([#include <pthread.h>],
119                     [pthread_mutex_t s; const struct timespec t; sem_timedlock(&s, &t);], HAVE_MUTEX_TIMEDLOCK=yes, HAVE_MUTEX_TIMEDLOCK=no)
120      if test ${HAVE_MUTEX_TIMEDLOCK} = yes ; then
121         AC_DEFINE([HAVE_MUTEX_TIMEDLOCK],1,[Define if pthread_mutex_timedlock() is avaible or not (part of XPG6 standard only?)])
122         AC_MSG_RESULT(yes)
123      else
124         AC_MSG_RESULT(no)
125      fi
126   fi
127 fi
128
129 dnl #
130 dnl #  2. make a general decision
131 dnl #
132
133 if test ".$mcsc" = .yes; then
134    # ucontext found
135    mcsc=yes
136 elif test ".$pthread" = .yes; then
137    # ucontext not found, but pthread found
138    pthread=yes
139 else
140     ac_header=windows.h
141     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
142     if test `eval echo '${'$as_ac_Header'}'` = yes; then
143       windows_context=yes
144     else
145       AC_ERROR([no appropriate backend found])
146     fi
147 fi
148 AM_CONDITIONAL(IS_WINDOWS,test x$windows_context = xyes)
149
150
151 dnl #
152 dnl #  3. allow decision to be overridden by user
153 dnl #
154
155 AC_MSG_CHECKING(what kind of backend should we use)
156
157 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
158 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
159
160 AC_ARG_WITH(context,
161   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
162   with_context=auto)
163
164 if test "x$with_context$mcsc" = "xucontextno" ; then 
165   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
166 fi
167
168 case $with_context in
169  ucontext) ;;
170  pthread) ;;
171  pthreads) ;;
172  windows) ;;
173  auto) with_context=ucontext;;
174  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
175 esac
176
177 if test "x$with_context" = "xucontext" ; then
178   if test ".$mcsc" = .yes; then
179     AC_MSG_RESULT(found working ucontext. Great!)
180     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
181   else
182     if test ".$windows_context" = .yes ; then
183       AC_MSG_RESULT(use windows context portability layer.)
184       with_context=windows
185     else
186       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
187       with_context=pthread
188     fi
189   fi
190 fi
191
192 if test "x$with_context" = "xpthread"; then
193   AC_CHECK_HEADERS([pthread.h])
194   if test x$pthread != xyes ; then
195     AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])
196   fi
197   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
198   AC_MSG_RESULT(You have pthreads and requested for them. Fine.)
199 fi
200 AM_CONDITIONAL(CONTEXT_THREADS,test "x$with_context" != xucontext)
201
202 dnl #
203 dnl #  4. determine a few additional details
204 dnl #
205
206 if test "x$with_context" = "xucontext" ; then
207 dnl #  direction of stack grow
208   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
209   if test ".$ac_cv_check_stackgrowth" = ".down"; then
210       PTH_STACK_GROWTH="down"
211   else
212       PTH_STACK_GROWTH="up"
213   fi
214   AC_SUBST(PTH_STACK_GROWTH)
215   
216   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
217 fi
218
219 #########################################
220 ## Check for libraries extra-dependencies
221 ##
222
223 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
224
225 SIMGRID_DEP=""
226 SMPI_DEP=""
227 GRAS_DEP=""
228
229 if test xpthread=xyes ; then 
230   # if the pthreads are usable
231   if test "x$with_context" = "xpthread" ; then
232     # if we use them to implement the xbt_context
233     SIMGRID_DEP="-lpthread"
234   fi
235   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
236   if test "x$with_context" != "xwindows" ; then
237     GRAS_DEP="-lpthread"
238   fi
239 fi
240
241 #########################################
242 ## Build optional modules (gtnets)
243 ##
244 gtnets=no
245 AC_ARG_WITH(gtnets,
246   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
247   gtnets_path="$withval",gtnets_path="no")
248 if test "x$gtnets_path" = "xno" ; then
249   AC_MSG_RESULT(Eventually you will come to GTNetS.)
250 else  
251   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. *****)
252   AC_MSG_CHECKING(for gtnets)
253   AC_LANG_PUSH([C++])  
254   GTNETS_LDFLAGS="-lgtnets -L$gtnets_path/lib"
255   GTNETS_CPPFLAGS="-I$gtnets_path/include -I$gtnets_path/include/gtnets"
256   LDFLAGS_SAV=$LDFLAGS  
257   CPPFLAGS_SAV=$CPPFLAGS
258   CPPFLAGS+=$GTNETS_CPPFLAGS
259   LDFLAGS+=$GTNETS_LDFLAGS
260   AC_TRY_LINK([ #include <simulator.h>
261               ], [Simulator s; s.RunUntilNextCompletion();], gtnets=yes, gtnets=no)
262   CPPFLAGS=$CPPFLAGS_SAV
263   LDFLAGS=$LDFLAGS_SAV
264   AC_LANG_POP([C++])  
265
266   if test "x$gtnets" = xyes ; then 
267     AM_CPPFLAGS="$AM_CPPFLAGS $GTNETS_CPPFLAGS"
268     SIMGRID_DEP="$SIMGRID_DEP $GTNETS_LDFLAGS"
269     AC_MSG_RESULT(Found working gtnets library.)
270     AC_DEFINE(HAVE_GTNETS, 1, [Indicates whether we have the GTNETS library or not])
271   else
272     AC_MSG_RESULT(Could not find any working gtnets library or not patched version, see config.log for details .)
273   fi
274 fi
275 AM_CONDITIONAL(HAVE_GTNETS,test "x$gtnets" != xno)
276
277 #########################################
278 ## Build optional modules (csdp)
279 ##
280 csdp=no
281 AC_ARG_WITH(csdp,
282   AS_HELP_STRING([--with-csdp], [Path to csdp installation (default to empty, i.e. not using csdp)]),
283   csdp_path="$withval",csdp_path="no")
284 if test "x$csdp_path" = "xno" ; then
285   AC_MSG_RESULT(Eventually you will come to csdp.)
286 else  
287   AC_MSG_RESULT(***** You have decided to use csdp. Let's check whether it works or not *****)
288   AC_MSG_CHECKING(for csdp)
289   CSDP_LDFLAGS="-L$csdp_path/lib -lsdp -llapack -lblas -lm"
290   CSDP_CPPFLAGS="-I$csdp_path/include -I$csdp_path/include/csdp"
291
292   AC_CHECK_LIB(sdp,easy_sdp, csdp_lib=yes, csdp_lib=no,$CSDP_LDFLAGS)
293   
294   CPPFLAGS_SAV=$CPPFLAGS
295   CPPFLAGS+=$CSDP_CPPFLAGS
296   AC_CHECK_HEADER(declarations.h, csdp_header=yes, csdp_header=no, [])
297   CPPFLAGS=$CPPFLAGS_SAV
298
299   
300
301   if test "x$csdp_lib = xyes" -a "x$csdp_header = xyes" ; then
302      csdp=yes;
303   else 
304      csdp=no;
305   fi
306   if test "x$csdp" = xyes; then 
307     AM_CPPFLAGS="$AM_CPPFLAGS $CSDP_CPPFLAGS"
308     SIMGRID_DEP="$SIMGRID_DEP $CSDP_LDFLAGS"
309     AC_MSG_RESULT(Found working sdp library.)
310     AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
311   else
312     AC_MSG_RESULT(Could not find any working sdp library.)
313   fi;
314 fi
315 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
316
317 AC_SUBST([SIMGRID_DEP])
318 AC_SUBST([SMPI_DEP])
319
320 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
321 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
322
323 AC_MSG_CHECKING(for extra dependencies of libgras)
324 case $host_os in
325   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
326             AM_CPPFLAGS="$AM_CPPFLAGS -DDLL_EXPORT"
327             AC_DEFINE(CONTEXT_THREADS,1);;
328 esac
329
330
331
332 if test "x$GRAS_DEP" = x; then 
333    AC_MSG_RESULT(none)
334 else
335    AC_MSG_RESULT($GRAS_DEP)
336 fi
337 AC_SUBST([GRAS_DEP])
338
339 ##############################################
340 ## Enhance maintainer mode and SUBST variables
341 ## (must be placed after any compilation tests since our overprotective flags
342 ##  let some tests fail)
343
344 # Check whether we are doing a regular build or a GRAMINE (minimal) one
345 # Next line is modified by sed when building gramine source tree
346 gramine_mode=no
347 if test x$gramine_mode = xyes
348 then
349   USE_MAINTAINER_MODE=no
350 fi
351 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
352
353
354 AM_MAINTAINER_MODE
355 if test x$USE_MAINTAINER_MODE = xyes 
356 then
357    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
358    enable_compile_warnings=yes   
359 fi
360 SG_COMPILE_FLAGS
361
362 AC_SUBST([CFLAGS])
363 AC_SUBST([CPPFLAGS])
364 AC_SUBST([LDFLAGS])
365 AC_SUBST([AM_CPPFLAGS])
366 AC_SUBST([abs_builddir])
367 AC_SUBST([abs_srcdir])
368 AC_SUBST([abs_top_builddir])
369 AC_SUBST([abs_top_srcdir])
370
371 ##############################################
372 ## Specific mode for build daemons.
373 ## (they compile the SVN without having the autotools installed)
374 AC_ARG_ENABLE(botbuild,
375               AS_HELP_STRING([--enable-botbuild], [Compilation mode for build daemons -- do not use it]),
376               botbuild=$enableval,botbuild=no)
377 AM_CONDITIONAL(BOTBUILD_MODE,test x$botbuild != xno)
378
379 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild != xyes ; then
380   echo "ERROR: "
381   echo "ERROR: You have to enable the maintainer mode to compile the SVN."
382   echo "ERROR: For this, just call configure this way:"
383   echo "ERROR:"
384   echo "ERROR: ./configure '--enable-maintainer-mode' $ac_configure_args"
385   echo "ERROR:"
386   exit 1
387 fi
388
389
390 SG_CONFIGURE_PART(Check for Java bindings...)
391 # Java cruft
392 AC_ARG_ENABLE(java,
393               AS_HELP_STRING([--disable-java], [To not compile the Java bindings even if the tools are found]),
394               disable_java=$enableval,disable_java=yes)
395 AC_MSG_CHECKING(whether to compile java bindings)
396 if test "x$disable_java" != "xyes" ; then
397    use_java="disabled by user"
398 else
399   AC_PATH_PROG([JAVAC], [javac], `which javac`)
400   AC_PATH_PROG([JAVA],  [java] , `which java`)
401   AC_PATH_PROG([JAR],   [jar]  , `which jar`)
402   AC_CHECK_HEADERS(jni.h)
403   if test -n "$JAVAC"   \
404      && test -n "$JAVA" \
405      && test -n "$JAR"  \
406      && test "x$ac_cv_header_jni_h" = "xyes" ; then
407    
408      use_java="yes"
409   else   
410      use_java="no"
411   fi
412 fi
413 AC_MSG_RESULT($use_java)
414 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
415
416 #####################
417 ## Check for programs
418 ##
419
420 SG_CONFIGURE_PART(Check for programs...)
421 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
422 WARNING="This file is generated, do not edit"
423 AC_SUBST(WARNING)
424
425
426 # Can we rebuild the parsers?
427 # We really want flex and refuse other lex. So, the parser is portable and
428 # does not induce extra lib dependency
429 AC_PROG_FLEX(2.5.30)
430                 
431 # Can we rebuild the xml-lexers from the XML specification?
432 # if not, simply touch the flex source files (which are distributed in
433 #  tarballs even if generated by flexml) and hope for the best.
434 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
435 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
436
437 if test x$USE_MAINTAINER_MODE = xyes 
438 then
439    # Check for doxygen when in maintainer mode since dist* targets fail
440    # without it
441    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
442    if test x$DOXYGEN = x ; then 
443      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
444    fi
445 fi
446
447 # Can we extract really usable backtraces? (also need the popen function)
448 AC_PATH_PROG(ADDR2LINE, addr2line)
449 if test x$ADDR2LINE != x ; then
450   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
451 fi
452
453 AC_SUBST(ac_configure_args)
454 # Can we make status line about the compilation result?
455 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
456 if test x$MD5SUM != xno ; then
457   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\ 
458                  xargs cat| $MD5SUM | sed 's/ .*$//'`
459 else 
460   build_version="no_md5sum_binary"
461 fi
462 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
463 AC_SUBST(build_id)
464
465 ###################
466 ## Makes the output
467 ##
468
469
470 #
471 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
472 #  src/amok/Makefile
473
474 SG_CONFIGURE_PART(Generating files...)
475
476 # Core of the libraries
477
478 AC_CONFIG_FILES([
479   Makefile
480   include/Makefile
481   src/Makefile
482   src/ucontext_stack.h
483 ])
484
485 # Tools being embeeded in gramine (stub generator)
486 AC_CONFIG_FILES([
487   tools/Makefile
488     tools/gras/Makefile
489     tools/tesh/Makefile
490 ])
491
492
493 # GRAMINE_CUT_BEGIN
494
495 # Tools NOT being embeeded in gramine
496 AC_CONFIG_FILES([
497   tools/graspe-slave
498 ],[
499     for file in                                                 \
500      tools/graspe-slave           tools/graspe-master           \
501     ; do                                                        \
502       test -e $file && chmod +x $file;                          \
503     done
504 ])
505
506 # Testsuite
507
508 AC_CONFIG_FILES([  
509   testsuite/Makefile
510   testsuite/run_tests    
511 ],[
512     for file in                                                 \
513      testsuite/run_tests                                        \
514     ; do                                                        \
515       test -e $file && chmod +x $file;                          \
516     done
517 ])
518
519 # Teshsuite (testsuite using tesh)
520 AC_CONFIG_FILES([  
521   teshsuite/Makefile
522 ])
523
524 # Documentation
525 AC_CONFIG_FILES([
526   doc/Makefile
527   doc/Doxyfile
528 ])
529
530 # Examples
531
532 #      examples/gras/p2p/Makefile
533 #      examples/gras/p2p/chord/Makefile
534 #      examples/gras/p2p/can/Makefile
535
536 AC_CONFIG_FILES([
537     examples/java/Makefile
538       examples/java/basic/Makefile
539       examples/java/comm_time/Makefile
540       examples/java/suspend/Makefile
541       examples/java/ping_pong/Makefile
542 ])
543
544 AC_CONFIG_FILES([
545   examples/Makefile 
546     examples/msg/Makefile
547     examples/simdag/Makefile
548     examples/gras/Makefile
549       examples/gras/ping/Makefile   
550       examples/gras/rpc/Makefile
551       examples/gras/spawn/Makefile
552       examples/gras/synchro/Makefile
553       examples/gras/timer/Makefile
554       examples/gras/chrono/Makefile
555       examples/gras/mutual_exclusion/simple_token/Makefile
556       examples/gras/mmrpc/Makefile
557       examples/gras/pmm/Makefile
558       examples/gras/all2all/Makefile
559     examples/amok/Makefile       
560 ])
561
562 AC_CONFIG_FILES([
563   src/smpi/smpicc
564   src/smpi/smpirun
565 ])
566
567 # GRAMINE_CUT_END
568
569 AC_OUTPUT
570
571 echo "
572
573 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
574
575         Compiler:        ${CC} (version: ${GCC_VERSION})
576         
577         CFlags:          ${CFLAGS}
578         CPPFlags:        ${CPPFLAGS}
579         LDFlags:         ${LDFLAGS}
580
581         Context backend: ${with_context}
582         Compile Java:    ${use_java}
583         
584         Maintainer mode: ${USE_MAINTAINER_MODE}
585
586 "
587 if test x$botbuild = xyes ; then
588   echo "        This is a bot build. Do not specify --enable-botbuild if you are not a bot."
589   echo
590 fi
591
592 if test -e .svn && test x$USE_MAINTAINER_MODE != xyes && test x$botbuild = xyes ; then
593   echo "WARNING: "
594   echo "WARNING: You are compiling the SVN in botbuild mode. If you are not a daemon, don't do so. "
595   echo "WARNING: Remove the --enable-botbuild from your configure line, and add --enable-maintainer-mode instead."
596   echo "WARNING:"
597   echo "WARNING: You won't be able to build archives until then (make dist is likely to fail). "
598   echo "WARNING:"
599 fi
600
601 echo $build_id > stamp.configure
602
603 exit 0;