configure.ac

   1
   2 ######################
   3 ## Setup the autotools
   4 ##
   5
   6 AC_PREREQ(2.59)
   7 AC_INIT([simgrid],[3.3-cvs],[simgrid-devel@lists.gforge.inria.fr])
   8 AC_CONFIG_SRCDIR([include/gras.h])
   9 AC_CONFIG_HEADERS([src/gras_config.h])
  10 # A CI_PREREQ(2003.01.16) # We need a recent ACI when having sub-modules
  11
  12 AC_REVISION($Revision$)
  13 AC_CANONICAL_TARGET
  14 AC_LANG([C])
  15 AM_PROG_GCJ
  16
  17 AM_INIT_AUTOMAKE(gnu)
  18 AC_CONFIG_MACRO_DIR(acmacro)
  19 ACLOCAL="$ACLOCAL -I acmacro"
  20
  21 dnl Next few lines is a hack to prevent libtool checking for F77
  22 m4_undefine([AC_PROG_F77])
  23 m4_defun([AC_PROG_F77],[])
  24
  25 dnl We do build a proper DLL when using win32
  26 AC_LIBTOOL_WIN32_DLL
  27 AC_PROG_LIBTOOL
  28
  29 ###############
  30 ## System checks
  31 ##
  32 SG_CONFIGURE_PART(System checks...)
  33 AC_PROG_CC(xlC gcc cc)
  34 AM_SANITY_CHECK
  35 AC_PROG_MAKE_SET
  36 AC_CHECK_PRINTF_NULL
  37 AC_CHECK_VA_COPY
  38
  39 # Checks for header files.
  40 AC_HEADER_STDC
  41 AC_HEADER_TIME
  42 AC_CHECK_HEADERS([sys/socket.h \
  43                   sys/stat.h \
  44                   windows.h winsock.h winsock2.h \
  45                   sys/time.h \
  46                   errno.h unistd.h \
  47                   execinfo.h\
  48                   signal.h ])
  49 AC_CHECK_FUNCS([gettimeofday usleep \
  50                 getdtablesize \
  51                 sysconf\
  52                 readv\
  53                 popen\
  54                 signal\
  55                 getline])
  56
  57 # check for a working snprintf (or use xbt/snprintf.c, which comes from http://www.ijs.si/software/snprintf/)
  58 AC_FUNC_SNPRINTF
  59 # check for asprintf function familly (or request the replacements from xbt/snprintf.c)
  60 AC_CHECK_FUNC(  asprintf, :,   AC_DEFINE(NEED_ASPRINTF,  1,  enable the asprintf   replacement))
  61 AC_CHECK_FUNC( vasprintf, :,   AC_DEFINE(NEED_VASPRINTF, 1,  enable the vasprintf  replacement))
  62
  63 # Checks for typedefs, structures, and compiler characteristics.
  64 AC_C_CONST
  65 AC_C_INLINE
  66 AC_TYPE_SIZE_T
  67
  68 ###################################
  69 ## SimGrid and GRAS specific checks
  70 ##
  71
  72 SG_CONFIGURE_PART(Checking GRAS architecture signature...)
  73 # Check architecture signature begin
  74 GRAS_ARCH
  75 # Check architecture signature end
  76 GRAS_CHECK_STRUCT_COMPACTION
  77
  78
  79 dnl ##
  80 dnl ##  CONTEXT IMPLEMENTATION
  81 dnl ##
  82
  83 SG_CONFIGURE_PART([Checking for threads, contexts or assimilated...])
  84
  85 dnl #
  86 dnl #  1. determine possibilities
  87 dnl #
  88
  89 dnl #  check for MCSC method
  90 AC_CHECK_MCSC(mcsc=yes, mcsc=no)
  91
  92 dnl #  check for pthread method
  93 AC_CHECK_HEADERS([pthread.h])
  94 AC_CHECK_LIB(pthread,pthread_create,pthread=yes, pthread=no)
  95
  96 dnl #
  97 dnl #  2. make a general decision
  98 dnl #
  99
 100 if test ".$mcsc" = .yes; then
 101    mcsc=yes
 102 elif test ".$pthread" = .yes; then
 103    pthread=yes
 104 else
 105     ac_header=windows.h
 106     as_ac_Header=`echo "ac_cv_header_$ac_header" | $as_tr_sh`
 107     if test `eval echo '${'$as_ac_Header'}'` = yes; then
 108       windows_context=yes
 109     else
 110       AC_ERROR([no appropriate backend found])
 111     fi
 112 fi
 113
 114 dnl #
 115 dnl #  3. allow decision to be overridden by user
 116 dnl #
 117
 118 AC_MSG_CHECKING(what kind of backend should we use)
 119
 120 AC_ARG_WITH(pthread, [  --with-pthread   Use pthread instead of ucontext.],with_context=pthread)
 121 AC_ARG_WITH(pthread, [  --with-pthreads   Use pthread instead of ucontext.],with_context=pthread)
 122
 123 AC_ARG_WITH(context,
 124   [  --with-context=[ucontext/pthread]   Use either (System V) swapcontext or pthread [[default=auto]].],,
 125   with_context=auto)
 126
 127 if test "x$with_context$mcsc" = "xucontextno" ; then
 128   AC_MSG_ERROR([--with-context=ucontext specified but ucontext unusable. Relaunch configure without this argument.], 77)
 129 fi
 130
 131 case $with_context in
 132  ucontext) ;;
 133  pthread) ;;
 134  pthreads) ;;
 135  windows) ;;
 136  auto) with_context=ucontext;;
 137  *) AC_MSG_ERROR([--with-context must be either ucontext or pthread]) ;;
 138 esac
 139
 140 if test "x$with_context" = "xucontext" ; then
 141   if test ".$mcsc" = .yes; then
 142     AC_MSG_RESULT(found working ucontext. Great!)
 143     AC_DEFINE([CONTEXT_UCONTEXT],1,[Define if xbt contexts are based on ucontext or not])
 144   else
 145     if test ".$windows_context" = .yes ; then
 146       AC_MSG_RESULT(use windows context portability layer.)
 147       with_context=windows
 148     else
 149       AC_MSG_RESULT([[no working ucontext found. Try pthreads as a fallback]])
 150       with_context=pthread
 151     fi
 152   fi
 153 fi
 154
 155 if test "x$with_context" = "xpthreads"; then
 156   with_context=pthread
 157 fi
 158 if test "x$with_context" = "xpthread"; then
 159   AC_CHECK_HEADERS([pthread.h])
 160   AC_CHECK_LIB(pthread,pthread_create,,
 161     [AC_MSG_ERROR([[Cannot find pthreads (try --with-context=ucontext if you haven't already tried).]])])
 162   AC_DEFINE([CONTEXT_THREADS],1,[Define if xbt contexts are based on our threads implementation or not])
 163   AC_MSG_RESULT(You have pthreads. Let's use them.)
 164 fi
 165
 166 dnl #
 167 dnl #  4. determine a few additional details
 168 dnl #
 169
 170 if test "x$with_context" = "xucontext" ; then
 171 dnl #  direction of stack grow
 172   AC_CHECK_STACKGROWTH(PTH_STACKGROWTH)
 173   if test ".$ac_cv_check_stackgrowth" = ".down"; then
 174       PTH_STACK_GROWTH="down"
 175   else
 176       PTH_STACK_GROWTH="up"
 177   fi
 178   AC_SUBST(PTH_STACK_GROWTH)
 179
 180   AC_CHECK_STACKSETUP(makecontext, pth_skaddr_makecontext, pth_sksize_makecontext)
 181 fi
 182
 183 #########################################
 184 ## Check for libraries extra-dependencies
 185 ##
 186
 187 SG_CONFIGURE_PART(Checking extra libraries dependencies...)
 188
 189 SIMGRID_DEP=""
 190 GRAS_DEP=""
 191
 192 #########################################
 193 ## Build optional modules (gtnets)
 194 ##
 195 AC_ARG_WITH(gtnets,
 196   AS_HELP_STRING([--with-gtnets], [Path to GTNetS installation (default to empty, ie not using GTNetS)]),
 197   gtnets_path="$withval",gtnets_path="NO")
 198 if test "x$gtnets_path" = "xNO" ; then
 199   AC_MSG_RESULT(Eventually you will come to GTNetS.)
 200 else
 201   AC_MSG_RESULT(***** You have decided to use the experimental GTNetS. We hope you know what you're doing.. ****)
 202   AC_DEFINE(USE_GTNETS, 1, [Indicates whether we should use GTNetS or not])
 203   if ! test -e $gtnets_path ; then
 204     AC_MSG_ERROR(Provided path to GTNetS include files ($gtnets_path) do not exist!)
 205   fi
 206   GTNETS_CFLAGS=-I$gtnets_path/include
 207   AC_SUBST([GTNETS_CFLAGS])
 208   GTNETS_LDFLAGS=-L$gtnets_path/lib
 209   AC_SUBST([GTNETS_LDFLAGS])
 210   SIMGRID_DEP="$SIMGRID_DEP $GTNETS_LDFLAGS -lgtnets"
 211 fi
 212 AM_CONDITIONAL(USE_GTNETS,test "x$gtnets_path" != xNO)
 213
 214 if test xpthread=xyes ; then
 215   # if the pthreads are usable
 216   if test "x$with_context" = "xpthread" ; then
 217     # if we use them to implement the xbt_context
 218     SIMGRID_DEP="-lpthread"
 219   fi
 220   # we need them in any case for the gras lib (which is multithreaded), but on windows (of course)
 221   if test "x$with_context" != "xwindows" ; then
 222     GRAS_DEP="-lpthread"
 223   fi
 224 fi
 225
 226 AC_MSG_CHECKING(for csdp)
 227 sdp=no
 228 AC_CHECK_LIB(sdp,sdp,csdp=yes, csdp=no,-llapack -lblas -lm)
 229 if test "x$csdp" = xyes; then
 230   SIMGRID_DEP="$SIMGRID_DEP -lsdp -llapack -lblas -lm"
 231   AC_MSG_RESULT(Found working sdp library.)
 232   AC_DEFINE(HAVE_SDP, 1, [Indicates whether we have the CSDP library or not])
 233 else
 234   AC_MSG_RESULT(Could not find any working sdp library.)
 235 fi;
 236 AM_CONDITIONAL(HAVE_SDP,test x$csdp != xno)
 237
 238 AC_SUBST([SIMGRID_DEP])
 239
 240 AC_CHECK_LIB(nsl, gethostbyname, [GRAS_DEP="$GRAS_DEP -lnsl"])
 241 AC_CHECK_LIB(socket, connect,    [GRAS_DEP="$GRAS_DEP -lsocket"])
 242
 243 AC_MSG_CHECKING(for extra dependencies of libgras)
 244 case $host_os in
 245   *mingw* ) GRAS_DEP="$GRAS_DEP -lws2_32" ; SIMGRID_DEP="$SIMGRID_DEP -lws2_32";
 246             AC_SUBST(AM_CFLAGS,-DDLL_EXPORT)
 247             AC_DEFINE(CONTEXT_THREADS,1);;
 248 esac
 249
 250 if test "x$GRAS_DEP" = x; then
 251    AC_MSG_RESULT(none)
 252 else
 253    AC_MSG_RESULT($GRAS_DEP)
 254 fi
 255 AC_SUBST([GRAS_DEP])
 256
 257 ##############################################
 258 ## Enhance maintainer mode and SUBST variables
 259 ## (must be placed after any compilation tests since our overprotective flags
 260 ##  let some tests fail)
 261
 262 # Check whether we are doing a regular build or a GRAMINE (minimal) one
 263 # Next line is modified by sed when building gramine source tree
 264 gramine_mode=no
 265 if test x$gramine_mode = xyes
 266 then
 267   USE_MAINTAINER_MODE=no
 268 fi
 269 AM_CONDITIONAL(GRAMINE_MODE,test x$gramine_mode != xno)
 270
 271
 272 AM_MAINTAINER_MODE
 273 if test x$USE_MAINTAINER_MODE = xyes
 274 then
 275    # Maintainers have no choice ! I'm a BOFH, and I plainly assume. [Mt]
 276    enable_compile_warnings=yes
 277 fi
 278 SG_COMPILE_FLAGS
 279
 280 AC_SUBST(CFLAGS)
 281 AC_SUBST(CPPFLAGS)
 282 AC_SUBST(LDFLAGS)
 283 AC_SUBST([abs_builddir])
 284 AC_SUBST([abs_srcdir])
 285 AC_SUBST([abs_top_builddir])
 286 AC_SUBST([abs_top_srcdir])
 287
 288
 289
 290 SG_CONFIGURE_PART(Check for Java bindings...)
 291 # Java cruft
 292 AC_PATH_PROG([JAVAC], [javac], `which javac`)
 293 AC_PATH_PROG([JAVA],  [java] , `which java`)
 294 AC_PATH_PROG([JAR],   [jar]  , `which jar`)
 295 AC_CHECK_HEADERS(jni.h)
 296 AC_MSG_CHECKING(whether to compile java bindings)
 297 if test -n "$JAVAC"   \
 298    && test -n "$JAVA" \
 299    && test -n "$JAR"  \
 300    && test "x$ac_cv_header_jni_h" = "xyes" ; then
 301
 302    use_java="yes"
 303 else
 304    use_java="no"
 305 fi
 306 AC_MSG_RESULT($use_java)
 307 AM_CONDITIONAL(HAVE_JAVA,test "x$use_java" = "xyes")
 308
 309 #####################
 310 ## Check for programs
 311 ##
 312
 313 SG_CONFIGURE_PART(Check for programs...)
 314 AC_CHECK_PROG(BASH, bash, `which bash`, /bin/sh)
 315 WARNING="This file is generated, do not edit"
 316 AC_SUBST(WARNING)
 317
 318
 319 # Can we rebuild the parsers?
 320 # We really want flex and refuse other lex. So, the parser is portable and
 321 # does not induce extra lib dependency
 322 AC_PROG_FLEX(2.5.30)
 323
 324 # Can we rebuild the xml-lexers from the XML specification?
 325 # if not, simply touch the flex source files (which are distributed in
 326 #  tarballs even if generated by flexml) and hope for the best.
 327 AC_CHECK_PROG(FLEXML,flexml,`which flexml`,NOTFOUND)
 328 AM_CONDITIONAL(HAVE_FLEXML,test x$FLEXML != xNOTFOUND)
 329
 330 if test x$USE_MAINTAINER_MODE = xyes
 331 then
 332    # Check for doxygen when in maintainer mode since dist* targets fail
 333    # without it
 334    AC_PATH_PROG(DOXYGEN,doxygen,`which doxygen`)
 335    if test x$DOXYGEN = x ; then
 336      AC_MSG_ERROR([doxygen is mandatory in maintainer mode])
 337    fi
 338 fi
 339
 340 # Can we extract really usable backtraces? (also need the popen function)
 341 AC_PATH_PROG(ADDR2LINE, addr2line)
 342 if test x$ADDR2LINE != x ; then
 343   AC_DEFINE_UNQUOTED(ADDR2LINE,"$ADDR2LINE",[Path to the addr2line tool])
 344 fi
 345
 346 AC_SUBST(ac_configure_args)
 347 # Can we make status line about the compilation result?
 348 AC_CHECK_PROG(MD5SUM,md5sum,`which md5sum`)
 349 if test x$MD5SUM != xno ; then
 350   build_version=`find -name '*.[ch]' |grep -v src/ucontext_stack.h | grep -v src/gras_config.h |\
 351                  xargs cat| $MD5SUM | sed 's/ .*$//'`
 352 else
 353   build_version="no_md5sum_binary"
 354 fi
 355 build_id="$PACKAGE ver=$VERSION build=$build_version args=\"$ac_configure_args\""
 356 AC_SUBST(build_id)
 357
 358 ###################
 359 ## Makes the output
 360 ##
 361
 362
 363 #
 364 #      examples/gras/chord/Makefile  examples/gras/chord/test_sg examples/gras/chord/test_rl
 365 #  src/amok/Makefile
 366
 367 SG_CONFIGURE_PART(Generating files...)
 368
 369 # Core of the libraries
 370
 371 AC_CONFIG_FILES([
 372   Makefile
 373   include/Makefile
 374   src/Makefile
 375   src/ucontext_stack.h
 376 ])
 377
 378 # Tools being embeeded in gramine (stub generator)
 379 AC_CONFIG_FILES([
 380   tools/Makefile
 381     tools/gras/Makefile
 382     tools/tesh/Makefile
 383 ])
 384
 385
 386 # GRAMINE_CUT_BEGIN
 387
 388 # Tools NOT being embeeded in gramine
 389 AC_CONFIG_FILES([
 390   tools/graspe-slave
 391 ],[
 392     for file in                                                 \
 393      tools/graspe-slave           tools/graspe-master           \
 394     ; do                                                        \
 395       test -e $file && chmod +x $file;                          \
 396     done
 397 ])
 398
 399 # Testsuite
 400
 401 AC_CONFIG_FILES([
 402   testsuite/Makefile
 403   testsuite/run_tests
 404   testsuite/gras/trp_tcp_usage  testsuite/gras/trp_file_usage
 405 ],[
 406     for file in                                                 \
 407      testsuite/run_tests                                        \
 408      testsuite/gras/trp_tcp_usage testsuite/gras/trp_file_usage \
 409     ; do                                                        \
 410       test -e $file && chmod +x $file;                          \
 411     done
 412 ])
 413
 414 # Documentation
 415 AC_CONFIG_FILES([
 416   doc/Makefile
 417   doc/Doxyfile
 418 ])
 419
 420 # Examples
 421
 422 #      examples/gras/p2p/Makefile
 423 #      examples/gras/p2p/chord/Makefile
 424 #      examples/gras/p2p/can/Makefile
 425
 426
 427 AC_CONFIG_FILES([
 428   examples/Makefile
 429     examples/msg/Makefile
 430       examples/msg/basic.tesh         examples/msg/small_plat.tesh
 431       examples/msg/suspend.tesh       examples/msg/flexml_bypass.tesh
 432     examples/simdag/Makefile        examples/simdag/test_simdag
 433     examples/gras/Makefile
 434       examples/gras/ping/Makefile
 435       examples/gras/rpc/Makefile
 436       examples/gras/spawn/Makefile
 437       examples/gras/synchro/Makefile
 438       examples/gras/timer/Makefile
 439       examples/gras/chrono/Makefile
 440       examples/gras/mutual_exclusion/simple_token/Makefile
 441       examples/gras/mmrpc/Makefile
 442       examples/gras/pmm/Makefile
 443       examples/gras/all2all/Makefile
 444     examples/amok/Makefile
 445       examples/amok/bandwidth/Makefile examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl
 446       examples/amok/saturate/Makefile  examples/amok/saturate/test_sg  examples/amok/saturate/test_rl
 447     examples/java/Makefile
 448       examples/java/basic/Makefile
 449       examples/java/comm_time/Makefile
 450       examples/java/suspend/Makefile
 451       examples/java/ping_pong/Makefile
 452 ],[
 453     for file in                                                 \
 454      \
 455      examples/msg/run_msg_test                                  \
 456      examples/simdag/test_simdag                                \
 457      examples/amok/bandwidth/test_sg examples/amok/bandwidth/test_rl \
 458      examples/amok/saturate/test_sg  examples/amok/saturate/test_rl \
 459     ; do                                                        \
 460       test -e $file && chmod +x $file;                          \
 461     done
 462 ])
 463
 464
 465 # GRAMINE_CUT_END
 466
 467 AC_OUTPUT
 468
 469 echo "
 470
 471 Configuration of package \`${PACKAGE}' (version ${VERSION}) on $gras_arch_name (=$gras_arch):
 472
 473         Compiler:        ${CC} (version: ${GCC_VERSION})
 474
 475         CFlags:          ${CFLAGS}
 476         CPPFlags:        ${CPPFLAGS}
 477         LDFlags:         ${LDFLAGS}
 478
 479         Context backend: ${with_context}
 480 "
 481
 482 if test -e CVS && test x$USE_MAINTAINER_MODE != xyes ; then
 483   echo "WARNING:"
 484   echo "WARNING: you seem to compile the CVS version without the maintainer mode."
 485   echo "WARNING: You won't be able to build archives that way (make dist is likely to fail). "
 486   echo "WARNING: If you want to enable the maintainer mode, juste specify it like this:"
 487   echo "WARNING:"
 488   echo "WARNING: ./configure '--enable-maintainer-mode' $ac_configure_args"
 489   echo "WARNING:"
 490 fi
 491 echo $build_id > stamp.configure
 492
 493 exit 0;