tools/cmake/Distrib.cmake

   1 #########################################
   2 ### Fill in the "make install" target ###
   3 #########################################
   4
   5 # doc
   6 file(MAKE_DIRECTORY ${CMAKE_HOME_DIRECTORY}/doc/html/)
   7 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/html/"
   8   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/html/)
   9 install(DIRECTORY "${CMAKE_HOME_DIRECTORY}/doc/HelloWorld/"
  10   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/HelloWorld/)
  11
  12 # binaries
  13 if(enable_smpi)
  14   install(PROGRAMS
  15     ${CMAKE_BINARY_DIR}/bin/smpicc
  16     ${CMAKE_BINARY_DIR}/bin/smpicxx
  17     ${CMAKE_BINARY_DIR}/bin/smpirun
  18     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  19   if(SMPI_FORTRAN)
  20     install(PROGRAMS
  21       ${CMAKE_BINARY_DIR}/bin/smpif90
  22       ${CMAKE_BINARY_DIR}/bin/smpiff
  23       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  24   endif()
  25 endif()
  26
  27 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/tesh
  28   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  29
  30 install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/graphicator
  31   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/)
  32
  33 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl
  34   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  35   RENAME simgrid-colorizer)
  36
  37 add_custom_target(simgrid-colorizer ALL
  38   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/colorize"
  39   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/MSG_visualization/colorize.pl ${CMAKE_BINARY_DIR}/bin/colorize
  40   )
  41
  42 install(PROGRAMS ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl
  43   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/bin/
  44   RENAME simgrid_update_xml)
  45
  46 add_custom_target(simgrid_update_xml ALL
  47   COMMENT "Install ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml"
  48   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/simgrid_update_xml.pl ${CMAKE_BINARY_DIR}/bin/simgrid_update_xml
  49   )
  50
  51 # libraries
  52 install(TARGETS simgrid
  53   DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  54
  55 if(enable_lib_static AND NOT WIN32)
  56   install(TARGETS simgrid_static
  57     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  58 endif()
  59
  60 if(enable_java)
  61   set(SIMGRID_JAR_TO_INSTALL "${SIMGRID_JAR}")
  62   install(TARGETS simgrid-java
  63       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/)
  64   install(FILES ${SIMGRID_JAR_TO_INSTALL}
  65       DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/java/
  66       RENAME simgrid.jar)
  67 endif()
  68
  69 # include files
  70 set(HEADERS
  71   ${headers_to_install}
  72   ${generated_headers_to_install}
  73   )
  74 foreach(file ${HEADERS})
  75   get_filename_component(location ${file} PATH)
  76   string(REPLACE "${CMAKE_CURRENT_BINARY_DIR}/" "" location "${location}")
  77   install(FILES ${file}
  78     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/${location})
  79 endforeach(file ${HEADERS})
  80
  81 # example files
  82 foreach(file ${examples_to_install})
  83   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/examples/" "" file ${file})
  84   get_filename_component(location ${file} PATH)
  85   install(FILES "examples/${file}"
  86     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/doc/simgrid/examples/${location})
  87 endforeach(file ${examples_to_install})
  88
  89 # bindings cruft
  90
  91 if(HAVE_LUA)
  92   file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/lib/lua/5.1")
  93   add_custom_target(simgrid_lua ALL
  94     DEPENDS simgrid
  95     ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
  96     )
  97   add_custom_command(
  98     OUTPUT ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
  99     COMMAND ${CMAKE_COMMAND} -E create_symlink ../../libsimgrid.${LIB_EXE} ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 100     )
 101   install(FILES ${CMAKE_BINARY_DIR}/lib/lua/5.1/simgrid.${LIB_EXE}
 102     DESTINATION $ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/lib/lua/5.1
 103     )
 104 endif()
 105
 106 ###########################################
 107 ### Fill in the "make uninstall" target ###
 108 ###########################################
 109
 110 add_custom_target(uninstall
 111   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/doc/simgrid
 112   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall doc ok"
 113   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/libsimgrid*
 114   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid*
 115   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall lib ok"
 116   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicc
 117   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpicxx
 118   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpiff
 119   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpif90
 120   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/smpirun
 121   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/tesh
 122   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid-colorizer
 123   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/simgrid_update_xml
 124   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/bin/graphicator
 125   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall bin ok"
 126   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/instr
 127   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/msg
 128   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simdag
 129   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/smpi
 130   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simix
 131   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/surf
 132   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/xbt
 133   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/mc
 134   COMMAND ${CMAKE_COMMAND} -E   remove_directory ${CMAKE_INSTALL_PREFIX}/include/simgrid
 135   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid.h
 136   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/simgrid_config.h
 137   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/include/xbt.h
 138   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall include ok"
 139   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/simgrid_update_xml.1
 140   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/tesh.1
 141   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpicc.1
 142   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpicxx.1
 143   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpirun.1
 144   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpiff.1
 145   COMMAND ${CMAKE_COMMAND} -E   remove -f ${CMAKE_INSTALL_PREFIX}/share/man/man1/smpif90.1
 146
 147
 148   COMMAND ${CMAKE_COMMAND} -E   echo "uninstall man ok"
 149   WORKING_DIRECTORY "${CMAKE_INSTALL_PREFIX}"
 150   )
 151
 152 if(HAVE_LUA)
 153   add_custom_command(TARGET uninstall
 154     COMMAND ${CMAKE_COMMAND} -E echo "uninstall binding lua ok"
 155     COMMAND ${CMAKE_COMMAND} -E remove -f ${CMAKE_INSTALL_PREFIX}/lib/lua/5.1/simgrid.${LIB_EXE}
 156     WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}/"
 157     )
 158 endif()
 159
 160 ################################################################
 161 ## Build a sain "make dist" target to build a source package ###
 162 ##   containing only the files that I explicitely state      ###
 163 ##   (instead of any cruft laying on my disk as CPack does)  ###
 164 ################################################################
 165
 166 # This is the complete list of what will be added to the source archive
 167 set(source_to_pack
 168   ${headers_to_install}
 169   ${source_of_generated_headers}
 170   ${BINDINGS_SRC}
 171   ${JEDULE_SRC}
 172   ${JMSG_C_SRC}
 173   ${JMSG_JAVA_SRC}
 174   ${JSURF_SWIG_SRC}
 175   ${JSURF_SWIG_SRC_EXTRA}
 176   ${JSURF_C_SRC}
 177   ${LUA_SRC}
 178   ${MC_SRC_BASE}
 179   ${MC_SRC}
 180   ${MC_SIMGRID_MC_SRC}
 181   ${MSG_SRC}
 182   ${S4U_SRC}
 183   ${NS3_SRC}
 184   ${RNGSTREAM_SRC}
 185   ${SIMDAG_SRC}
 186   ${SIMGRID_SRC}
 187   ${SIMIX_SRC}
 188   ${SMPI_SRC}
 189   ${SURF_SRC}
 190   ${TRACING_SRC}
 191   ${XBT_RL_SRC}
 192   ${XBT_SRC}
 193   ${EXTRA_DIST}
 194   ${CMAKE_SOURCE_FILES}
 195   ${EXAMPLES_CMAKEFILES_TXT}
 196   ${TESHSUITE_CMAKEFILES_TXT}
 197   ${TOOLS_CMAKEFILES_TXT}
 198   ${DOC_FIGS}
 199   ${DOC_IMG}
 200   ${DOC_SOURCES}
 201   ${DOC_TOOLS}
 202   ${PLATFORMS_EXAMPLES}
 203   ${README_files}
 204   ${bin_files}
 205   ${examples_src}
 206   ${tesh_files}
 207   ${teshsuite_src}
 208   ${testsuite_src}
 209   ${tools_src}
 210   ${txt_files}
 211   ${xml_files}
 212   )
 213
 214 ##########################################
 215 ### Fill in the "make dist-dir" target ###
 216 ##########################################
 217
 218 add_custom_target(dist-dir
 219   COMMENT "Generating the distribution directory"
 220   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 221   COMMAND ${CMAKE_COMMAND} -E remove ${PROJECT_NAME}-${release_version}.tar.gz
 222   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}
 223   COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/doc/html/
 224   COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_HOME_DIRECTORY}/doc/html/ ${PROJECT_NAME}-${release_version}/doc/html/
 225   )
 226 add_dependencies(dist-dir maintainer_files)
 227
 228 set(dirs_in_tarball "")
 229 foreach(file ${source_to_pack})
 230   #message(${file})
 231   # This damn prefix is still set somewhere (seems to be in subdirs)
 232   string(REPLACE "${CMAKE_HOME_DIRECTORY}/" "" file "${file}")
 233
 234   # Create the directory on need
 235   get_filename_component(file_location ${file} PATH)
 236   string(REGEX MATCH ";${file_location};" OPERATION "${dirs_in_tarball}")
 237   if(NOT OPERATION)
 238     set(dirs_in_tarball "${dirs_in_tarball};${file_location};")
 239     add_custom_command(
 240       TARGET dist-dir
 241       COMMAND ${CMAKE_COMMAND} -E make_directory ${PROJECT_NAME}-${release_version}/${file_location}/
 242       )
 243   endif()
 244
 245   # Actually copy the file
 246   add_custom_command(
 247     TARGET dist-dir
 248     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/${file} ${PROJECT_NAME}-${release_version}/${file_location}
 249     )
 250 endforeach(file ${source_to_pack})
 251
 252 add_custom_command(
 253   TARGET dist-dir
 254   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_HOME_DIRECTORY}/tools/cmake/scripts/Makefile.default ${PROJECT_NAME}-${release_version}/Makefile
 255   COMMAND ${CMAKE_COMMAND} -E echo "${GIT_VERSION}" > ${PROJECT_NAME}-${release_version}/.gitversion
 256   )
 257
 258 ######################################
 259 ### Fill in the "make dist" target ###
 260 ######################################
 261
 262 add_custom_target(dist
 263   COMMENT "Removing the distribution directory"
 264   DEPENDS ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 265   COMMAND ${CMAKE_COMMAND} -E echo ${PROJECT_NAME}-${release_version} > ${CMAKE_BINARY_DIR}/VERSION
 266   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 267   )
 268
 269 add_custom_command(
 270   OUTPUT ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 271   COMMENT "Compressing the archive from the distribution directory"
 272   COMMAND ${CMAKE_COMMAND} -E tar cf ${PROJECT_NAME}-${release_version}.tar ${PROJECT_NAME}-${release_version}/
 273   COMMAND gzip -9v ${PROJECT_NAME}-${release_version}.tar
 274   COMMAND ${CMAKE_COMMAND} -E remove_directory ${PROJECT_NAME}-${release_version}/
 275   )
 276 add_dependencies(dist dist-dir)
 277
 278 if(NOT enable_maintainer_mode)
 279   add_custom_target(echo-dist
 280     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 281     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: Distrib is generated without option maintainer mode "
 282     COMMAND ${CMAKE_COMMAND} -E echo "WARNING: ----------------------------------------------------"
 283     )
 284   add_dependencies(dist echo-dist)
 285 endif()
 286
 287 ###########################################
 288 ### Fill in the "make distcheck" target ###
 289 ###########################################
 290
 291 set(CMAKE_BINARY_TEST_DIR ${CMAKE_BINARY_DIR})
 292
 293 # Allow to test the "make dist"
 294 add_custom_target(distcheck
 295   COMMAND ${CMAKE_COMMAND} -E echo "XXX compare archive with git repository"
 296   COMMAND ${CMAKE_HOME_DIRECTORY}/tools/internal/check_dist_archive -batch ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz
 297
 298   COMMAND ${CMAKE_COMMAND} -E echo "XXX remove old copy"
 299   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 300
 301   COMMAND ${CMAKE_COMMAND} -E echo "XXX Untar distrib"
 302   COMMAND ${CMAKE_COMMAND} -E tar xf ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}.tar.gz ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 303
 304   COMMAND ${CMAKE_COMMAND} -E echo "XXX create build and install subtrees"
 305   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 306   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 307
 308   COMMAND ${CMAKE_COMMAND} -E echo "XXX Configure"
 309   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build
 310   ${CMAKE_COMMAND}
 311   -DCMAKE_INSTALL_PREFIX=${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst
 312   ..
 313   COMMAND ${CMAKE_COMMAND} -E echo "XXX Build"
 314   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM}
 315
 316   COMMAND ${CMAKE_COMMAND} -E echo "XXX Test"
 317   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ctest --output-on-failure
 318
 319   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install"
 320   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 321   COMMAND ${CMAKE_COMMAND} -E create_symlink
 322   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgrid.so
 323   ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_inst/lib/libsimgridtest.so
 324
 325   COMMAND ${CMAKE_COMMAND} -E echo "XXX Install with documentation"
 326   COMMAND ${CMAKE_COMMAND} -E chdir ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}/_build ${CMAKE_MAKE_PROGRAM} install
 327
 328   COMMAND ${CMAKE_COMMAND} -E echo "XXX Remove temp directories"
 329   COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_BINARY_TEST_DIR}/${PROJECT_NAME}-${release_version}
 330   )
 331 add_dependencies(distcheck dist)
 332
 333 #######################################
 334 ### Fill in the "make check" target ###
 335 #######################################
 336
 337 if(enable_memcheck)
 338   add_custom_target(check
 339     COMMAND ctest -D ExperimentalMemCheck
 340     )
 341 else()
 342   add_custom_target(check
 343     COMMAND make test
 344     )
 345 endif()
 346
 347 #######################################
 348 ### Fill in the "make xxx-clean" target ###
 349 #######################################
 350
 351 add_custom_target(maintainer-clean
 352   COMMAND ${CMAKE_COMMAND} -E remove -f src/config_unit.c
 353   COMMAND ${CMAKE_COMMAND} -E remove -f src/cunit_unit.c
 354   COMMAND ${CMAKE_COMMAND} -E remove -f src/dict_unit.c
 355   COMMAND ${CMAKE_COMMAND} -E remove -f src/dynar_unit.c
 356   COMMAND ${CMAKE_COMMAND} -E remove -f src/ex_unit.c
 357   COMMAND ${CMAKE_COMMAND} -E remove -f src/set_unit.c
 358   COMMAND ${CMAKE_COMMAND} -E remove -f src/simgrid_units_main.c
 359   COMMAND ${CMAKE_COMMAND} -E remove -f src/swag_unit.c
 360   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_sha_unit.c
 361   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_str_unit.c
 362   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_strbuff_unit.c
 363   COMMAND ${CMAKE_COMMAND} -E remove -f src/xbt_synchro_unit.c
 364   WORKING_DIRECTORY "${CMAKE_HOME_DIRECTORY}"
 365   )
 366
 367 if(WIN32)
 368   find_program(NSIS_PROGRAM NAMES makensi)
 369   message(STATUS "nsis: ${NSIS_PROGRAM}")
 370
 371   if(NSIS_PROGRAM)
 372     ADD_CUSTOM_TARGET(nsis
 373       COMMENT "Generating the SimGrid installer for Windows..."
 374       DEPENDS simgrid simgrid graphicator simgrid-colorizer simgrid_update_xml
 375       COMMAND ${NSIS_PROGRAM} simgrid.nsi
 376       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/
 377     )
 378   endif()
 379 endif()
 380
 381 include(CPack)